Здравствуйте,
проблема в следующем: в оборотно-сальдовой ведомости увидела, что проводки есть, но нет регистратора-документа. вместо ссылки выходит "Объект не найден". Как правильно нужно поступить в данной ситуации?
Можно ли как-нибудь удалить проводки?
Спасибо

так же как и с обычным документом.

(1) Как?
Документа ведь нет

делаешь набор записей, отбор на битую ссылку и НаборЗаписей.Записать()

(0) ТИИ

(2)Документа нет,а ссылка есть

я такое через свою консоль запросов с произвольным кодом делаю

(4) Что такиое ТИИ

Книга знаний: Пустые ссылки

Ниже дана программа для удаления записей регистров, у которых регистратор - битая ссылка, т.е. не существует в базе.

Процедура УдалениеБитыхСсылок(ИмяРегистра,ТипРегистра,ТипРегистраЗ)
    МенеджерРегистра = ТипРегистра[ИмяРегистра];
    
    Запрос = Новый Запрос("
    |ВЫБРАТЬ Регистратор
    |ИЗ "+ТипРегистраЗ+"."+ИмяРегистра+"
    |ГДЕ Регистратор.Ссылка ЕСТЬ NULL И НЕ Регистратор = &ПустаяСсылкаДокумента");
    Запрос.УстановитьПараметр("ПустаяСсылкаДокумента",Неопределено);
    
    Выборка = Запрос.Выполнить().Выбрать();
    Пока Выборка.Следующий() Цикл
        Набор = ТипРегистра[ИмяРегистра].СоздатьНаборЗаписей();
        Набор.Отбор.Регистратор.Установить(Выборка.Регистратор);
        Набор.Записать();
        ОбработкаПрерыванияПользователя();
        Состояние(""+ТипРегистра+" "+ИмяРегистра);
    КонецЦикла;
КонецПроцедуры


Процедура КнопкаВыполнитьНажатие(Кнопка)

    Для Каждого пРегистр из Метаданные.РегистрыСведений Цикл
        Подчинен        =    (пРегистр.РежимЗаписи = Метаданные.СвойстваОбъектов.РежимЗаписиРегистра.ПодчинениеРегистратору);
        Если Подчинен Тогда
            УдалениеБитыхСсылок(пРегистр.Имя,РегистрыСведений,"РегистрСведений")
        КонецЕсли;    
    КонецЦикла;
  
    Для Каждого пРегистр из Метаданные.РегистрыБухгалтерии Цикл
        УдалениеБитыхСсылок(пРегистр.Имя,РегистрыБухгалтерии,"РегистрБухгалтерии")
    КонецЦикла;
    
    Для Каждого пРегистр из Метаданные.РегистрыРасчета Цикл
        УдалениеБитыхСсылок(пРегистр.Имя,РегистрыРасчета,"РегистрРасчета")
    КонецЦикла;

    Для Каждого пРегистр из Метаданные.РегистрыНакопления Цикл
        УдалениеБитыхСсылок(пРегистр.Имя,РегистрыНакопления,"РегистрНакопления")
    КонецЦикла;
    
КонецПроцедуры

или если обработкой, то сделай запрос с поиском битых регистраторов, потом их перебирай и очищай

(6) ПОдскажи, как это сделать, пожалуйста

(7) Тестирование и исправление. В Конфигураторе делается.

(10)Вот , делай как в  (8)

(8) Спасибо! и всем спасибо, попробую :)

Закрываю тему, спасибо!

(13)Только долбавь в запрос РАЗЛИЧНЫЕ, чтобы все движения не тянул

(15) спасибо :)