Сильно не пинать, только учусь.

Есть самописка на бсп на управляемых формах. лиентв настройках конфигурации Режим совместимости интерфейса стоит "Такси. Разрешить версия 8.2" (ставил также и просто "Такси" - результат не меняется). Но по умолчанию у всех пользователей открывается обычный интерфейс УФ.
Собственно вопрос: как установить интерфейс Такси по умолчанию у всех пользователей.

п.с. менять каждому юзеру интерфейс через Сервис-параметры не предлагать.

если бсп - скопируй настройку интерфейса всем пользователям

Процедура УстановитьРежимКомандногоИнтерфейса(Режим) Экспорт
    
    Если НЕ ОбщегоНазначенияПовтИсп.ДоступноИспользованиеРазделенныхДанных() Тогда
        Возврат;
    КонецЕсли;
    
    // Установка констант
    
    РежимТакси = ВРег(Режим) = ВРег("ИнтерфейсТакси");
    Режим82    = ВРег(Режим) = ВРег("ИнтерфейсВерсии82");
    
    Если НЕ РежимТакси
        И НЕ Режим82 Тогда
        Возврат;
    КонецЕсли;
    
    УстановитьПривилегированныйРежим(Истина);
    Константы.ИнтерфейсВерсии82.Установить(Режим82);
    
    // Установка настроек по умолчанию всем пользователям
    
    ВсеПользователи = ПользователиИнформационнойБазы.ПолучитьПользователей();
    Если ВсеПользователи.Количество() > 0 Тогда
        Для каждого ПользовательИБ Из ВсеПользователи Цикл
            ПользователиСлужебный.УстановитьНачальныеНастройки(ПользовательИБ.Имя);
        КонецЦикла;
    Иначе
        ПользователиСлужебный.УстановитьНачальныеНастройки("");
    КонецЕсли;

КонецПроцедуры

Процедура УстановитьНачальныеНастройки(Знач ИмяПользователя, Пользователь = Неопределено) Экспорт
    
    СистемнаяИнформация = Новый СистемнаяИнформация;
    
    ТекущийРежим = Метаданные.РежимСовместимостиИнтерфейса;
    Такси = (ТекущийРежим = Метаданные.СвойстваОбъектов.РежимСовместимостиИнтерфейса.Такси
        ИЛИ ТекущийРежим = Метаданные.СвойстваОбъектов.РежимСовместимостиИнтерфейса.ТаксиРазрешитьВерсия8_2);
    
    НастройкиКлиента = Новый НастройкиКлиентскогоПриложения;
    НастройкиКлиента.ОтображатьПанелиНавигацииИДействий = Ложь;
    НастройкиКлиента.ОтображатьПанельРазделов = Истина;
    НастройкиКлиента.РежимОткрытияФормПриложения = РежимОткрытияФормПриложения.Закладки;
    
    НастройкиТакси = Неопределено;
    НастройкиИнтерфейса = Новый НастройкиКомандногоИнтерфейса;
    
    Если Такси Тогда
        НастройкиКлиента.ВариантИнтерфейсаКлиентскогоПриложения = ВариантИнтерфейсаКлиентскогоПриложения.Такси;
        
        НастройкиИнтерфейса.ОтображениеПанелиРазделов = ОтображениеПанелиРазделов.КартинкаИТекст;
        
        НастройкиТакси = Новый НастройкиИнтерфейсаКлиентскогоПриложения;
        НастройкиСостава = Новый НастройкиСоставаИнтерфейсаКлиентскогоПриложения;
        ГруппаСлева = Новый ГруппаНастройкиСоставаИнтерфейсаКлиентскогоПриложения;
        ГруппаСлева.Добавить(Новый ЭлементНастройкиСоставаИнтерфейсаКлиентскогоПриложения("ПанельИнструментов"));
        ГруппаСлева.Добавить(Новый ЭлементНастройкиСоставаИнтерфейсаКлиентскогоПриложения("ПанельРазделов"));
        НастройкиСостава.Лево.Добавить(ГруппаСлева);
        НастройкиТакси.УстановитьСостав(НастройкиСостава);
    Иначе
        НастройкиИнтерфейса.ОтображениеПанелиРазделов = ОтображениеПанелиРазделов.Текст;
    КонецЕсли;
    
    НачальныеНастройки = Новый Структура;
    НачальныеНастройки.Вставить("НастройкиКлиента",    НастройкиКлиента);
    НачальныеНастройки.Вставить("НастройкиИнтерфейса", НастройкиИнтерфейса);
    НачальныеНастройки.Вставить("НастройкиТакси",      НастройкиТакси);
    НачальныеНастройки.Вставить("ЭтоВнешнийПользователь",
            ТипЗнч(Пользователь) = Тип("СправочникСсылка.ВнешниеПользователи")
        Или ТипЗнч(Пользователь) = Тип("СправочникОбъект.ВнешниеПользователи"));
    
    ПользователиПереопределяемый.ПриУстановкеНачальныхНастроек(НачальныеНастройки);
    
    Если НачальныеНастройки.НастройкиКлиента <> Неопределено Тогда
        ХранилищеСистемныхНастроек.Сохранить("Общее/НастройкиКлиентскогоПриложения", "",
            НачальныеНастройки.НастройкиКлиента, , ИмяПользователя);
    КонецЕсли;
    
    Если НачальныеНастройки.НастройкиИнтерфейса <> Неопределено Тогда
        ХранилищеСистемныхНастроек.Сохранить("Общее/ПанельРазделов/НастройкиКомандногоИнтерфейса", "",
            НачальныеНастройки.НастройкиИнтерфейса, , ИмяПользователя);
    КонецЕсли;
        
    Если НачальныеНастройки.НастройкиТакси <> Неопределено Тогда
        ХранилищеСистемныхНастроек.Сохранить("Общее/НастройкиИнтерфейсаКлиентскогоПриложения", "",
            НачальныеНастройки.НастройкиТакси, , ИмяПользователя);
    КонецЕсли;
        
КонецПроцедуры

(2) (3) в тайне надеялся что интерфейс по умолчанию можно задать какими-то настройками. Спасибо за код, буду пробовать.

если пишу конфу с нуля - он как-то сам такси по-умолчанию...