Хочу - при создании нового документа подсовывать одну форму, а при открытии существующего - другую
В ОбработкаПолученияФормы у меня все пусто, никаких признаков о том - открываемый объект новый или нет, нету
как выйти из положения?
зы: поиск пока ничего не дал

как вариант юзать костыль - при создании на сервере смотреть новый или нет объект, и закрывать эту форму и открывать другую...

(1) подумал уже об этом
но вдруг я как то не могу передать параметры в ОбработкаПолученияФормы

посмотри в упп в модуле менеджера РТиУ есть ОбработкаПолученияФормы

(3) нет под рукой
зато (1) работает, думаю меня это пока устроит

Еси в Параметры есть ключ - то это существующий объект...

Функция ПолучитьИмяФормыПоВидуОперации(ВидОперации) Экспорт
    
    Если ВидОперации = ПредопределенноеЗначение("Перечисление.ВидыОперацийРеализацияТоваров.ПродажаКомиссия") Тогда
        ИмяФормыПоВидуОперации = "Форма.ФормаДокументаУправляемая";
    ИначеЕсли ВидОперации = ПредопределенноеЗначение("Перечисление.ВидыОперацийРеализацияТоваров.АктВыполненныхРабот") Тогда
        ИмяФормыПоВидуОперации = "Форма.АктВыполненныхРабот";
    ИначеЕсли ВидОперации = ПредопределенноеЗначение("Перечисление.ВидыОперацийРеализацияТоваров.АктНаПередачуПрав") Тогда
        ИмяФормыПоВидуОперации = "Форма.АктНаПередачуПрав";
    Иначе
        ИмяФормыПоВидуОперации = "ФормаОбъекта";
    КонецЕсли;
    
    Возврат "Документ.РеализацияТоваровУслуг." + ИмяФормыПоВидуОперации;
    
КонецФункции

Процедура ОбработкаПолученияФормы(ВидФормы, Параметры, ВыбраннаяФорма, ДополнительнаяИнформация, СтандартнаяОбработка)
    
    Если ВидФормы <> "ФормаДокумента" И ВидФормы <> "ФормаОбъекта" Тогда
        Возврат;
    КонецЕсли;

    ВидОперации = Неопределено;

    Если Параметры.Свойство("Ключ") И ЗначениеЗаполнено(Параметры.Ключ) Тогда
        ВидОперации    = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(Параметры.Ключ, "ВидОперации");
    КонецЕсли;

    Если НЕ ЗначениеЗаполнено(ВидОперации) Тогда
        Если Параметры.Свойство("ЗначениеКопирования") И ЗначениеЗаполнено(Параметры.ЗначениеКопирования) Тогда
            ВидОперации = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(Параметры.ЗначениеКопирования, "ВидОперации");
        КонецЕсли;
    КонецЕсли;

    Если НЕ ЗначениеЗаполнено(ВидОперации) Тогда
        Если Параметры.Свойство("ЗначенияЗаполнения") И ТипЗнч(Параметры.ЗначенияЗаполнения) = Тип("Структура") Тогда
            Если Параметры.ЗначенияЗаполнения.Свойство("ВидОперации") Тогда
                ВидОперации    = Параметры.ЗначенияЗаполнения.ВидОперации;
            КонецЕсли;
        КонецЕсли;
    КонецЕсли;
    
    Если НЕ ЗначениеЗаполнено(ВидОперации) Тогда
        Если Параметры.Свойство("ВидОперации") Тогда
            ВидОперации    = Параметры.ВидОперации;
        КонецЕсли;
    КонецЕсли;
    
    СтандартнаяОбработка = Ложь;
    ВыбраннаяФорма = ПолучитьИмяФормыПоВидуОперации(ВидОперации);
    
КонецПроцедуры

о, спасибо )))