Процедура МодификацияСправочника()
    Спр=СоздатьОбъект("Справочник.Номенклатура");
    Спр.ВыбратьЭлементы();
    ТЗ.ВыбратьСтроки();
    НомСтр=0;
    Пока ТЗ.ПолучитьСтроку()=1 Цикл
        НомСтр=НомСтр+1;
        Подчинение=ТЗ.ПолучитьЗначение(НомСтр,1);
        Код=ТЗ.ПолучитьЗначение(НомСтр,2);
        Наименование=ТЗ.ПолучитьЗначение(НомСтр,3);
        Если Спр.НайтиПоКоду(Код,0)=0 Тогда
            Если Спр.НайтиПоКоду(Подчинение,0)=1 Тогда
                Родитель=Спр;
            КонецЕсли;
            Гр=СоздатьОбъект("Справочник.Номенклатура");
            Гр.НоваяГруппа();
            Гр.УстановитьАтрибут("Код",Код);
            Гр.УстановитьАтрибут("Наименование",Наименование);
            Гр.УстановитьАтрибут("Родитель",Родитель);
            Гр.Записать();    
        Иначе
            Спр.УстановитьАтрибут("Наименование",Наименование);
            Спр.УстановитьАтрибут("Родитель",Родитель);
            Спр.Записать();
            Если Спр.НайтиПоКоду(Подчинение,0)=1 Тогда
                Родитель=Спр.ТекущийЭлемент();
            КонецЕсли;
        КонецЕсли
    КонецЦикла;
КонецПроцедуры

На этапе Спр.УстановитьАтрибут("Родитель",Родитель) возникает эта ошибка, хотя несколькими строками ранее, когда устанавливал Родителя создаваемой группе никакой ошибки не выдавалось - всё установилось нормально.

потому что не определен вообще этот Родитель.

      Иначе
            Спр.УстановитьАтрибут("Наименование",Наименование);
            Спр.УстановитьАтрибут("Родитель",Родитель);


где определяешь? В каком месте?

(1) Я специально перед определением устанавливаю, потому что если после поставить - тогда Спр начинает выдавать только Родителя вместо всех элементов. Проверил - поставил Сообщить(Родитель) перед его определением - выдаёт всё верно.

Попробуй .ТекущийЭлемент()...

(3) Пробовал - тогда если Родителя получать перед определением - выдаются все элементы, если после - нормально, только родитель, но тогда я не смогу обратиться к элементу чтобы его атрибут установить, т.к. Спр после определения Родителя возвращает тоже Родителя вместо элемента.

а тут зачем

        Подчинение=ТЗ.ПолучитьЗначение(НомСтр,1);
        Код=ТЗ.ПолучитьЗначение(НомСтр,2);
        Наименование=ТЗ.ПолучитьЗначение(НомСтр,3);


мы и так по тз бежим

        Подчинение=ТЗ.Подчинение;
        Код=ТЗ.Код;
        Наименование=ТЗ.Наименование;

или конкретно по номеру колонки нужно?

(5) Я в ТЗ идентификаторов не устанавливал - она у меня выгружается из ecxel, так что по номеру обращаюсь

Проблему с обращением к элементу решил с помощью ещё одного позиционирования. Теперь и Родитель устанавливается после его определения, и ТекущийЭлемент убрал, но ошибка осталась!
Пока ТЗ.ПолучитьСтроку()=1 Цикл
        НомСтр=НомСтр+1;
        Подчинение=ТЗ.ПолучитьЗначение(НомСтр,1);
        Код=ТЗ.ПолучитьЗначение(НомСтр,2);
        Наименование=ТЗ.ПолучитьЗначение(НомСтр,3);
        Если Спр.НайтиПоКоду(Код,0)=0 Тогда
            Если Спр.НайтиПоКоду(Подчинение,0)=1 Тогда
                Родитель=Спр;
            КонецЕсли;
            Гр=СоздатьОбъект("Справочник.Номенклатура");
            Гр.НоваяГруппа();
            Гр.УстановитьАтрибут("Код",Код);
            Гр.УстановитьАтрибут("Наименование",Наименование);
            Гр.УстановитьАтрибут("Родитель",Родитель);
            Гр.Записать();    
        Иначе
            //Спр.УстановитьАтрибут("Наименование",Наименование);
            //Спр.Записать();
            Если Спр.НайтиПоКоду(Подчинение,0)=1 Тогда
                Родитель=Спр;
            КонецЕсли;
            Тов=СоздатьОбъект("Справочник.Номенклатура");
            Если Тов.НайтиПоКоду(Код,0)=1 Тогда
                Товар=Тов;
            КонецЕсли;
            Товар.УстановитьАтрибут("Родитель",Родитель);
            Товар.Записать();
        КонецЕсли
    КонецЦикла;

По-прежнему - Неверный тип справочника! Причём для новых групп установить Родителя аналогичным образом удалось без всяких ошибок. Кто-нибудь знает почему так происходит и как с этим бороться?

Зачем .УстановитьАтрибут()????
Тут просто

спр.Родитель = Родитель;
спр.Записать();

и все....

(8) Так тоже делал - результат не меняется: Неверный тип справочника!

Пристально не смотрел
Но мне кардинально не нравится
Что внутри условия если родитель присваивается но только пр выполнении условия а ниже по тексту кода используется родитель - какое значение если условие не сработало?

И писать правильно
Родитель = спр.текущийэлемент();

(10) У меня с ТекущимЭлементом и было изначально (0), это уже тут насоветовали - поменял.
Если условие не сработает, значит нечего менять - по задумке должны переименовываться и переструктурироваться элементы справочника, коды которых соответствуют кодам из ТЗ.

Пока ...... Цикл
    Родитель = ПолучитьПустоеЗначение("Справочник.Номенклатура");
    Далее по тексту


Сделать для начала

(11)  не путай бодий дар и палец как говорится
У тебя родитель для текущей строки тз определяется каждый раз или может оставаться от предыдущей строки тз
?

(9) а родитель - точно папка????
А то может ты элемент справочника в родители суешь?
а туда только группу можно лепить

Для начала сделай (12)
И сюда доклад

(14)  угу, запросто
Проверки то нет что жто группа

(13) Каждый раз определяется по коду из столбца Подчинение

(14) Точно, это в ТЗ уже чётко установлено

(17)  тогда твой код однозначно кривой по логике построения

Если у тебя ВСЕГДА условие =1


            Если Спр.НайтиПоКоду(Подчинение,0)=1 Тогда
                Родитель=Спр;


ТО ЗАЧЕМ ПРОВЕРЯТЬ ЭТО УСЛОВИЕ?
Если не всегда условие=1 - то где ветка иначе?

(18) Все, что точно определено должно быть 100% проверено.
Перед тем как установить родителем - проверку делай на то, что элемент который будет родителем группа.

Если нет ветки Иначе
То внизу используемая переменная родитель - какое значение ДОЛЖНА ИМЕТЬ?

И если не группа пусть тебе сообщение выдаст - все увидишь. 99.99% что лепишь родителем элемент справочника. Чупа чупс ставлю.

Никому не кажется этот код немного странным?


Если Спр.НайтиПоКоду(Код,0)=0 Тогда
            Если Спр.НайтиПоКоду(Подчинение,0)=1 Тогда
                Родитель=Спр;
            КонецЕсли;


(23)  присоединяюсь к рекомендации

(20) Да, условие будет всегда 1. Я таким образом позиционируюсь на нужном элементе и получаю Родителя. Или можно ещё как-то?

Если условие ВСЕГДА =1
То нахрена это проверять?

И почему ты уверен что всегда?

(24) И что здесь странного? Сначала проверяется код элемента, потом код Родителя этого элемента.

(24)  да хз

(28)  херню городите
В части "этого элемента"

(26) ты ищешь в справочнике элемент по коду.
допустим ты его нашел. ТЫ уверен, что нашел группу? когда она была создана. Может элемент с этим кодом и не группа вовсе. Ты это не проверяешь..

а ведь кто не дает добавить

Если Родител.ЭтоГруппа() Тогда
         спр.родитель = родитель;
         спр.Записать();
Иначе
         Сообщить(Родитель.Код+"Нифига не группа");
КонецЕсли;

Вот три секунды а сколько пользы

Логика какаято типа
Если не нашли элемент по коду
То ищем группу по коду группы

(24) не странно

(28) http://pticyrus.info/wp-content/uploads/2012/01/101.jpg

Коряво, но не странно

Он предполагает, что в ТЗ в одной колонке коды элементов, а в другой коды их родителей

(27) Я же говорю, это не ради проверки, а для получения значения Родителя. А нет, не всегда - если группа первого уровня, кода в колонке Подчинение не будет, этот момент пропустил.

(33) там "Родитель" легко может быть пустое в случае когда 1-е условие выполнилось а второе нет

а дальше мы этого пустого пытаемся Гр.УстановитьАтрибут("Родитель",Родитель);

(с) Никогда не говори ВСЕГДА

Код ваще мутный
И в целом и в частностях

Следует
1. Найти группу по Подчинение
2. Создать группу если не найдена
3. Запомнить ссылку группы
4. Найти элемент (если не найден элемент то создать при необходимости)
5. В элемент присвоить родителя из п.3

ВСЕ

(33) А вот как раз пустое, насколько я помню и прокатит

(38)  я на это уже обратил внимание выше и при том коде что написан родитель может вообще из пред. Строки унаследоватьс

(40) Соглашусь - мутный

(36) Я это знаю, я сам загружаемую в ТЗ таблицу делал

(44)  короче склифасовский
Врубай скайп и тимвьювер
Будем писать под диктовку
Скайп zlopun

(41) да ну?


Процедура ПроверкаСообщить()
Сообщить(""+ТипаПустаяПеремнная);
КонецПроцедуры



где ТипаПустаяПеремнная нигде выше не присваивается

Я сегодня добрвй
Приехал с Родины

(40) Правильно, именно такую логику я хочу реализовать.

(46) не присвоенная переменная и пустая ссылка - это чуть разные понятия, или я не прав?

(48) а написал хрень полную

(47) А где Родина?

(49) Так у него выше Родитель скорее всего не элемент нужного справочника

(51) Брест

(45) Да ладно, сам уже додумаю, спасибо. Тут много чего посоветовали - буду исправлять...

(54) Удачи.
(53) Хорошего настроения на долго

Спр = СоздатьОбъект("Справочник.Номенклатура");
//
Пока ТЗ.ПолучитьСтроку()=1 Цикл

   Подчинение = ТЗ.ПолучитьЗначение(НомСтр,1);
   Код = ТЗ.ПолучитьЗначение(НомСтр,2);
   Наименование = ТЗ.ПолучитьЗначение(НомСтр,3);

   Если Спр.НайтиПоКоду(Подчинение,0)=0 Тогда
     Спр.НоваяГруппа();
     Спр.Код = Код;
     Спр.Наименование = Наименование;
     //Спр.Родитель = ... //непонятно в какую группу пихать текущую группу
     Спр.Записать();
   Иначе
     Если Спр.ЭтоГруппа()=0 Тогда
       Сообщить("ПРОПУЩЕНО: ошибка поиска группы "+Подчинение);
       Продолжить;
     КонецЕсли;  
   КонецЕсли;
   Родитель = Спр.ТекущийЭлемент();

   Если Спр.НайтиПоКоду(Код,0)=0 Тогда
      Сообщить("ПРОПУЩЕНО: не найден элемент по коду: "+Код);
      Продолжить;
   КонецЕсли;
   Спр.Родитель = Родитель;
   Спр.Записать();
КонецЦикла;

(10) (56) Нет, не так. Дело в том, что я неправильно ответил на (40) (невнимательно прочитал) - у меня логика на самом деле другая.
1. Проверить по коду элементов в ТЗ существуют ли они в Справочнике.
Если НЕТ:
2.Создать новые группы (т.к. новых товаров я в ТЗ не добавлял) и присвоить им Код и Наименование из ТЗ.
3. Найти в Справочнике группы по коду в колонке Подчинение из ТЗ, определить их как Родитель(находить Родителя нужно только после создания новых Групп (т.к. они тоже будут являться Родителем для др. элементов) - потому он у меня и определяется внутри условия).
Если ДА:
4. Найти в Справочнике элементы по коду в колонке Код из ТЗ и присвоить новые Наименование и Родителя.

(57) Описанная логика кривая, ибо
1. Проверить по коду элементов в ТЗ существуют ли они в Справочнике.
Если ДА:
4. Найти в Справочнике элементы по коду в колонке Код из ТЗ и присвоить новые Наименование и Родителя.

из п.1 "Проверить по коду элементов в ТЗ существуют ли они в Справочнике." и из п.4 "Найти в Справочнике элементы по коду в колонке Код из ТЗ" - это одно и то же, т.к. проверить без поиска нельзя.

вдобавок в п.4 в случае ЕСЛИ ДА - "новые наименование и родитель - ОНИ ОТКУДА? они - неопределены...

У вас проблемы с алгоритмикой...

(58) С алгоритмикой как раз всё хорошо, скорее проблемы с правильным пониманием работы методов - когда что на чём позиционируется, поэтому начал мудрить с этим поиском.
Сейчас переделал - всё работает как надо:
Процедура МодификацияСправочника()
    Спр=СоздатьОбъект("Справочник.Номенклатура");
    Спр.ВыбратьЭлементы();
    ТЗ.ВыбратьСтроки();
    НомСтр=0;
    Пока ТЗ.ПолучитьСтроку()=1 Цикл
        НомСтр=НомСтр+1;
        Подчинение=ТЗ.ПолучитьЗначение(НомСтр,1);
        Код=ТЗ.ПолучитьЗначение(НомСтр,2);
        Наименование=ТЗ.ПолучитьЗначение(НомСтр,3);
        Если Спр.НайтиПоКоду(Код,0)=0 Тогда
            Спр.НоваяГруппа();
            Спр.УстановитьАтрибут("Код",Код);
            Спр.УстановитьАтрибут("Наименование",Наименование);
            Спр.Записать();    
        Иначе
            Спр.УстановитьАтрибут("Наименование",Наименование);
            Спр.Записать();    
        КонецЕсли;
        Если Спр.НайтиПоКоду(Подчинение,0)=1 Тогда
            Родитель=Спр.ТекущийЭлемент();
        Иначе
            Родитель=ПолучитьПустоеЗначение("Справочник.Номенклатура")
        КонецЕсли;
        Если Спр.НайтиПоКоду(Код,0)=1 Тогда
            Спр.Родитель=Родитель;
            Спр.Записать();
        КонецЕсли;
    КонецЦикла;
КонецПроцедуры

+ (59) Ну и ошибка была в пустом значении поля Подчинение у групп 1-го уровня в ТЗ

(60) Попробуй нижележащий код. Он, по идее, должен давать точно тот же результат что и твой (это и есть твой код, причесанный):

    Спр = СоздатьОбъект("Справочник.Номенклатура");
    ТЗ.ВыбратьСтроки();
    Пока ТЗ.ПолучитьСтроку()=1 Цикл
        
        НомСтр = ТЗ.НомерСтроки;
        Подчинение = ТЗ.ПолучитьЗначение(НомСтр,1);
        Код = ТЗ.ПолучитьЗначение(НомСтр,2);
        Наименование = ТЗ.ПолучитьЗначение(НомСтр,3);
        
        Если Спр.НайтиПоКоду(Подчинение,0)=1 Тогда
            Родитель = Спр.ТекущийЭлемент();
        Иначе
            Родитель = ПолучитьПустоеЗначение("Справочник.Номенклатура")
        КонецЕсли;
        
        Если Спр.НайтиПоКоду(Код,0) = 0 Тогда
            Спр.НоваяГруппа();
            Спр.УстановитьАтрибут("Код",Код);
        Иначе
            Спр.Родитель=Родитель;
    КонецЕсли;
        Спр.УстановитьАтрибут("Наименование",Наименование);
        Спр.Записать();    
        
    КонецЦикла;

если все норм будет - тогда втыкай в код.. ;-)
успкхов!

(61) Да, вроде всё также, хотя пока не совсем понятно почему. Спасибо, буду разбираться...

все не читал, лень
сходу - группа?

(62) потому что тривиальная программистская логика
код
        Если Спр.НайтиПоКоду(Подчинение,0)=1 Тогда
            Родитель = Спр.ТекущийЭлемент();
        Иначе
            Родитель = ПолучитьПустоеЗначение("Справочник.Номенклатура")
        КонецЕсли;

никак НЕ СВЯЗАН с предыдущим куском кода. Сдвигаем этот код вверх, сразу после чтения данных из строки ТЗ

получается далее (кусок кода который РАЗДЕЛЯЛ этот код ушел наверх) осталось:

        Если Спр.НайтиПоКоду(Код,0)=0 Тогда
            Спр.НоваяГруппа();
            Спр.УстановитьАтрибут("Код",Код);
            Спр.УстановитьАтрибут("Наименование",Наименование);
            Спр.Записать();    
        Иначе
            Спр.УстановитьАтрибут("Наименование",Наименование);
            Спр.Записать();    
        КонецЕсли;
        Если Спр.НайтиПоКоду(Код,0)=1 Тогда
            Спр.Родитель=Родитель;
            Спр.Записать();
        КонецЕсли;

эти два блока если отрабатывают одно и то же, объединяем

        Если Спр.НайтиПоКоду(Код,0)=0 Тогда
            Спр.НоваяГруппа();
            Спр.УстановитьАтрибут("Код",Код);
            Спр.УстановитьАтрибут("Наименование",Наименование);
            Спр.Записать();    
        Иначе
            Спр.Родитель=Родитель;
            Спр.Записать();
Спр.УстановитьАтрибут("Наименование",Наименование);
            Спр.Записать();    
        КонецЕсли;

Упрощаем

Если Спр.НайтиПоКоду(Код,0)=0 Тогда
            Спр.НоваяГруппа();
            Спр.УстановитьАтрибут("Код",Код);
            Спр.УстановитьАтрибут("Наименование",Наименование);
            Спр.Записать();    
        Иначе
            Спр.Родитель=Родитель;
           Спр.УстановитьАтрибут("Наименование",Наименование);
            Спр.Записать();    
        КонецЕсли;

общий код выносим за пределы если

Если Спр.НайтиПоКоду(Код,0)=0 Тогда
   Спр.НоваяГруппа();
   Спр.УстановитьАтрибут("Код",Код);
Иначе
   Спр.Родитель=Родитель;
КонецЕсли;

Спр.УстановитьАтрибут("Наименование",Наименование);
Спр.Записать();

далее думаю понятно...
заметь - тупой рефакторинг кода, даже без вникания в логику. по простым формальным признакам.

(68) Да, да, всё правильно, я уже повтыкал в код и сам понял, то о чём Вы выше написали.

(69) Вот видишь - надо всего лишь подумать... а не тыкать клаву в диком митусении ;-)

Успехов!

Спасибо. Только в (61) не хватает Спр.Родитель=Родитель внутри Если Спр.НайтиПоКоду(Код,0) = 0 - это меня и смутило сразу, а потом уже и про рефакторинг заметил. Если не устанавливать родителя при создании новых групп, потом они не присвоятся. Ведь Иначе отрабатывает в этом же цикле ещё не созданные элементы.

(71) согласен, правильное замечание, тогда судя по всему - еще проще.. ;-)

    Спр = СоздатьОбъект("Справочник.Номенклатура");
    ТЗ.ВыбратьСтроки();
    Пока ТЗ.ПолучитьСтроку()=1 Цикл
        
        НомСтр = ТЗ.НомерСтроки;
        Подчинение = ТЗ.ПолучитьЗначение(НомСтр,1);
        Код = ТЗ.ПолучитьЗначение(НомСтр,2);
        Наименование = ТЗ.ПолучитьЗначение(НомСтр,3);
        
        Если Спр.НайтиПоКоду(Подчинение,0)=1 Тогда
            Родитель = Спр.ТекущийЭлемент();
        Иначе
            Родитель = ПолучитьПустоеЗначение("Справочник.Номенклатура")
        КонецЕсли;
        
        Если Спр.НайтиПоКоду(Код,0) = 0 Тогда
            Спр.НоваяГруппа();
            Спр.Код = Код;
        КонецЕсли;
        Спр.Родитель = Родитель;
        Спр.Наименование = Наименование;
        Спр.Записать();    
        
    КонецЦикла;