v7: Вывести список в семерке

(6) Непонято, что-же тебе надо? Может это поможет, юзаю уже давно:
//===========================================
//Установление автоширины колонок таблицы
Процедура АвтоШиринаКолонок(Таб,НачКол,НачСтр)
    // Проходим по столбцам таблицы,
    Для НомерКол=НачКол По Таб.ШиринаТаблицы() Цикл
        // затем спускаемся по текущему столбу по ячейкам (по строкам),
        // и максимизируем ширину каждой ячейки в текущем столбце
        МаксШирина=0;
        Для НомерСтр=НачСтр По Таб.ВысотаТаблицы() Цикл
            ТекШирина =Таб.Область(НомерСтр,НомерКол).ШиринаСтолбца();         // Ширина текущего столбца
              ТекДлина  =СтрДлина(СокрЛП(Таб.Область(НомерСтр,НомерКол).Текст)); // Размер текста в ячейке
            МаксШирина=Макс(МаксШирина,ТекШирина,ТекДлина);
        КонецЦикла;
        Таб.Область(,НомерКол).ШиринаСтолбца(МаксШирина);
    КонецЦикла;
КонецПроцедуры

//=====================================
Процедура ВывестиТЗ(ТЗ, Знач ИмяТЗ, Итог=0, ВКонец=0)
    Перем Таб,Длина,Заголовок,Ширина, СписокПолей;
    //Если ПустоеЗначение(ТЗ) = 1 Тогда
    //    Сообщить("Ошибка вызова процедуры ВывестиТЗ: пустое значение ТЗ "+ИмяТЗ);
    //    Возврат;
    //КонецЕсли;
    ИмяТЗ = СокрЛП(ИмяТЗ);
    Если ТипЗначенияСтр(ТЗ) <> "ТаблицаЗначений" Тогда
        Сообщить("Ошибка вызова процедуры ВывестиТЗ: тип значения ТЗ "+ИмяТЗ+" = "+ТипЗначенияСтр(ТЗ));
        Возврат;
    КонецЕсли;
    Если ТЗ.КоличествоКолонок() = 0 Тогда
        Сообщить("Ошибка вызова процедуры ВывестиТЗ: в ТЗ "+ИмяТЗ+" не заданы колонки");
        Возврат;
    КонецЕсли;
    Если ТЗ.КоличествоСтрок() = 0 Тогда
        // Сообщить("Ошибка процедуры вызова ВывестиТЗ: пустая ТЗ "+ИмяТЗ);
        Возврат;
    КонецЕсли;
    СписокПолей = "";
    Таб = СоздатьОбъект("Таблица");
    Таб.ИсходнаяТаблица("ВыводТЗ");
    //! Сначала выведем заголовки столбцов
    Для Кол = 1 По ТЗ.КоличествоКолонок() Цикл
        ТЗ.ПолучитьПараметрыКолонки(Кол,,Длина,,Заголовок,Ширина);
        Значение = Заголовок;
        Если Кол=1 Тогда
            Таб.ВывестиСекцию("Строка|Столбец");
            СписокПолей = Заголовок;
        Иначе
            Таб.ПрисоединитьСекцию("Строка|Столбец");
            СписокПолей = СписокПолей +"," + Заголовок;
        КонецЕсли;
    КонецЦикла;
    //! Вывод содержимого таблицы
    Для Стр = 1 По ТЗ.КоличествоСтрок() Цикл
        Для Кол = 1 По ТЗ.КоличествоКолонок() Цикл
            Значение = ТЗ.ПолучитьЗначение(Стр, Кол);
            Если Кол=1 Тогда
                Таб.ВывестиСекцию("Строка|Столбец");
            Иначе
                Таб.ПрисоединитьСекцию("Строка|Столбец");
            КонецЕсли;
        КонецЦикла;
    КонецЦикла;
    Если Итог = 1 Тогда
        ТЗИтог = СоздатьОбъект("ТаблицаЗначений");
        ТЗИтог.Загрузить(ТЗ);
        ТЗИтог.НоваяКолонка("_123_");
        ТЗИтог.Заполнить(123,,,"_123_");
        ТЗИтог.Свернуть("_123_",СписокПолей);
        ТЗИтог.УдалитьКолонку("_123_");
        Для Стр = 1 По ТЗИтог.КоличествоСтрок() Цикл // Несмотря на то, что в ТЗИтог д.б. одна строка
            // Для начала убедимся, что в колонке если числовые значения
            Для Кол = 1 По ТЗИтог.КоличествоКолонок() Цикл
                Значение = ТЗИтог.ПолучитьЗначение(Стр, Кол);
                Если СтрЧислоВхождений(Значение, ".") > 1 Тогда
                    // Обычно это Дата
                    Значение = "";
                Иначе
                    ЗначТест = Число(Значение);
                    Если ПустоеЗначение(ЗначТест) = 1 Тогда
                        Значение = "";
                    Иначе
                        Значение = ЗначТест; // Чисто число!
                        Прервать;
                    КонецЕсли;
                КонецЕсли;
            КонецЦикла;
            Если Значение = "" Тогда
                // В строке нет чисел - итог считать не по чем!
                Продолжить;
            КонецЕсли;
            Для Кол = 1 По ТЗИтог.КоличествоКолонок() Цикл
                Значение = ТЗИтог.ПолучитьЗначение(Стр, Кол);
                Если СтрЧислоВхождений(Значение, ".") > 1 Тогда
                    // Обычно это Дата
                    Значение = "";
                Иначе
                    ЗначТест = Число(Значение);
                    Если ПустоеЗначение(ЗначТест) = 1 Тогда
                        Значение = "";
                    Иначе
                        Значение = ЗначТест; // Чисто число!
                    КонецЕсли;
                КонецЕсли;
                Если Кол=1 Тогда
                    Таб.ВывестиСекцию("Итог|Столбец");
                Иначе
                    Таб.ПрисоединитьСекцию("Итог|Столбец");
                КонецЕсли;
            КонецЦикла;
        КонецЦикла;
    КонецЕсли;
    АвтоШиринаКолонок(Таб,1,1);
    Таб.ТолькоПросмотр(1);
    Таб.Опции(,,1,,ИмяТЗ,ИмяТЗ);
    Таб.ПараметрыСтраницы(2);
    Таб.Показать(ИмяТЗ,"");
КонецПроцедуры  // ВывестиТЗ(..)