Ребят, киньте плиз ссылку.
Видел отчет на СКД, где вытаскивается реестр документов, и к документу подставляется актуальная цена на его дату из регистра цен.

Нужно сравнить цены документов с актуальными ценами.
Не была закрыта ручная установка цен в доке. Хотим посмотреть, сколько было злоупотреблений и сколько мы на них потеряли

Я извратился вот так:


ВЫБРАТЬ
    РеализацияТоваровУслугТовары.Ссылка,
    РеализацияТоваровУслугТовары.Номенклатура,
    РеализацияТоваровУслугТовары.Цена
ПОМЕСТИТЬ ЦеныПродажи
ИЗ
    Документ.РеализацияТоваровУслуг.Товары КАК РеализацияТоваровУслугТовары
ГДЕ
    РеализацияТоваровУслугТовары.Ссылка.Дата МЕЖДУ &ДатаНачала И &ДатаОкончания
    И РеализацияТоваровУслугТовары.Ссылка.Проведен = ИСТИНА
    И РеализацияТоваровУслугТовары.Ссылка.Склад = &Склад
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    Цены.Период,
    Цены.Регистратор,
    Цены.НомерСтроки,
    Цены.Активность,
    Цены.ТипЦен,
    Цены.Номенклатура,
    Цены.ХарактеристикаНоменклатуры,
    Цены.Валюта,
    Цены.Цена,
    Цены.ЕдиницаИзмерения,
    Цены.ПроцентСкидкиНаценки,
    Цены.СпособРасчетаЦены
ПОМЕСТИТЬ Цены
ИЗ
    РегистрСведений.ЦеныНоменклатуры КАК Цены
ГДЕ
    Цены.Период <= &ДатаОкончания
    И Цены.ТипЦен = &ТипЦен
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ЦеныПродажи.Ссылка,
    ЦеныПродажи.Номенклатура,
    ЦеныПродажи.Цена,
    Цены.Период КАК ДатаРег,
    Цены.Цена КАК ЦенаРег
ПОМЕСТИТЬ РегДанные
ИЗ
    ЦеныПродажи КАК ЦеныПродажи
        ЛЕВОЕ СОЕДИНЕНИЕ Цены КАК Цены
        ПО ЦеныПродажи.Номенклатура = Цены.Номенклатура
            И ЦеныПродажи.Ссылка.Дата >= Цены.Период
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    РегДанные.Ссылка,
    РегДанные.Номенклатура,
    МАКСИМУМ(РегДанные.ДатаРег) КАК ДатаРег
ПОМЕСТИТЬ ДанныеЦен
ИЗ
    РегДанные КАК РегДанные

СГРУППИРОВАТЬ ПО
    РегДанные.Ссылка,
    РегДанные.Номенклатура
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ЦеныПродажи.Ссылка,
    ЦеныПродажи.Номенклатура,
    ЦеныПродажи.Цена,
    ДанныеЦен.ДатаРег
ПОМЕСТИТЬ СВОД
ИЗ
    ЦеныПродажи КАК ЦеныПродажи
        ЛЕВОЕ СОЕДИНЕНИЕ ДанныеЦен КАК ДанныеЦен
        ПО ЦеныПродажи.Ссылка = ДанныеЦен.Ссылка
            И ЦеныПродажи.Номенклатура = ДанныеЦен.Номенклатура
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    СВОД.Ссылка.Контрагент КАК Контрагент,
    СВОД.Ссылка.Автор КАК Автор,
    СВОД.Ссылка,
    СВОД.Номенклатура,
    СВОД.Цена КАК ЦенаДокумента,
    Цены.Цена КАК ЦенаРег,
    СВОД.ДатаРег,
    (ВЫРАЗИТЬ(Цены.Цена / СВОД.Цена - 1 КАК ЧИСЛО(19, 2))) * 100 КАК Процент,
    ВЫРАЗИТЬ(Цены.Цена - СВОД.Цена КАК ЧИСЛО(19, 2)) КАК Отклонение
ИЗ
    СВОД КАК СВОД
        ЛЕВОЕ СОЕДИНЕНИЕ Цены КАК Цены
        ПО СВОД.Номенклатура = Цены.Номенклатура
            И СВОД.ДатаРег = Цены.Период
ГДЕ
    СВОД.Цена <> Цены.Цена
ИТОГИ
    СУММА(Отклонение)
ПО
    ОБЩИЕ,
    Контрагент,
    Автор