м...
Ну, например, есть счета у которых аналитика Подразделение, СтатьяЗатрат, НоменклатурнаяГруппа, и есть у которых Подразделение и СтатьяЗатрат.
Так вот, как мне запросом выбратьотдельно те и другие, при условии, что набор аналитики передаю в запрос в качестве значения параметра, и это значение - массив, элемент которого - элемент ПланаВидовХарактеристик.СубконтоХозрасчетное.

Что-то не соображу

Суммировать количество совпадений

2(1) хм... ну ок..., ща

ВЫБРАТЬ
    "Подразделение, Статья, Номенклатура" КАК ПризнакСчетовСАналитикой,
    ХозрасчетныйВидыСубконто.Ссылка,
    СУММА(1) КАК КоличествоВидованалитики
ПОМЕСТИТЬ СчетаУчетаСОднойИзТрехАналитик
ИЗ
    ПланСчетов.Хозрасчетный.ВидыСубконто КАК ХозрасчетныйВидыСубконто
ГДЕ
    ХозрасчетныйВидыСубконто.ВидСубконто В(&СписокВидовСубконтоСНоменклатурой)

СГРУППИРОВАТЬ ПО
    ХозрасчетныйВидыСубконто.Ссылка
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    "Подразделение, Статья" КАК ПризнакСчетовСАналитикой,
    ХозрасчетныйВидыСубконто.Ссылка,
    СУММА(1) КАК КоличествоВидованалитики
ПОМЕСТИТЬ СчетаУчетаСОднойИзДвухАналитик
ИЗ
    ПланСчетов.Хозрасчетный.ВидыСубконто КАК ХозрасчетныйВидыСубконто
ГДЕ
    ХозрасчетныйВидыСубконто.ВидСубконто В(&СписокВидовСубконтоБезНоменклатуры)

СГРУППИРОВАТЬ ПО
    ХозрасчетныйВидыСубконто.Ссылка
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    СчетаУчетаСОднойИзТрехАналитик.ПризнакСчетовСАналитикой,
    СчетаУчетаСОднойИзТрехАналитик.Ссылка
ПОМЕСТИТЬ СчетаСПолнымНаборомАналитики
ИЗ
    СчетаУчетаСОднойИзТрехАналитик КАК СчетаУчетаСОднойИзТрехАналитик
ГДЕ
    СчетаУчетаСОднойИзТрехАналитик.КоличествоВидованалитики = 3
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    СчетаУчетаСОднойИзДвухАналитик.ПризнакСчетовСАналитикой,
    СчетаУчетаСОднойИзДвухАналитик.Ссылка
ПОМЕСТИТЬ СчетаСДвумяАналитиками
ИЗ
    СчетаУчетаСОднойИзДвухАналитик КАК СчетаУчетаСОднойИзДвухАналитик
ГДЕ
    СчетаУчетаСОднойИзДвухАналитик.КоличествоВидованалитики = 2
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    СчетаСДвумяАналитиками.ПризнакСчетовСАналитикой,
    СчетаСДвумяАналитиками.Ссылка
ИЗ
    СчетаСДвумяАналитиками КАК СчетаСДвумяАналитиками
        ЛЕВОЕ СОЕДИНЕНИЕ СчетаСПолнымНаборомАналитики КАК СчетаСПолнымНаборомАналитики
        ПО СчетаСДвумяАналитиками.Ссылка = СчетаСПолнымНаборомАналитики.Ссылка
ГДЕ
    СчетаСПолнымНаборомАналитики.Ссылка ЕСТЬ NULL
======



Интересущие меня счета в двух ВТ - СчетаСПолнымНаборомАналитики и СчетаСДвумяАналитиками

Спасибо, получилось

м... правда в СчетаСДвумяАналитиками попадают счета у которых аналитика, например "Подразделения, <Тут Скажем Вообще какое-то левое Типа Сотрудник>, СтатьяЗатрат"

щас я подумаю, насколько они нужны в моей картине мира...

Ну наверное да, так может быть...
====

Еще прислали запрос, который возвращает счета с точным совпадением аналитики

ВЫБРАТЬ
    ХозрасчетныйВидыСубконто.Ссылка
ПОМЕСТИТЬ ВТВсеСчета
ИЗ
    ПланСчетов.Хозрасчетный.ВидыСубконто КАК ХозрасчетныйВидыСубконто
ГДЕ
    ХозрасчетныйВидыСубконто.ВидСубконто В(&ВидСубконто)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ХозрасчетныйВидыСубконто.Ссылка
ПОМЕСТИТЬ ВТНеНужныеСчета
ИЗ
    ПланСчетов.Хозрасчетный.ВидыСубконто КАК ХозрасчетныйВидыСубконто
ГДЕ
    ХозрасчетныйВидыСубконто.ВидСубконто В
                (ВЫБРАТЬ
                    ВидыСубконтоХозрасчетные.Ссылка
                ИЗ
                    ПланВидовХарактеристик.ВидыСубконтоХозрасчетные КАК ВидыСубконтоХозрасчетные
                ГДЕ
                    НЕ ВидыСубконтоХозрасчетные.Ссылка В (&ВидСубконто))
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ВТВсеСчета.Ссылка
ИЗ
    ВТВсеСчета КАК ВТВсеСчета
ГДЕ
    НЕ ВТВсеСчета.Ссылка В
                (ВЫБРАТЬ
                    ВТНеНужныеСчета.Ссылка
                ИЗ
                    ВТНеНужныеСчета КАК ВТНеНужныеСчета)
=====


В последнюю ВТ не попадают счета, описанные в (4)