Доброго.
А как бы мне сравнит начинку двух доков?
Интересует меня требование-накладная, чего списали в производство и отчет производства за смену материалы. Однако бухи косячат списывают одно, распределяют другое.
УПП 1,3. естественно.
Благодарствую.

запрос тебе поможет

(0) Ну чё там у хохлов, бизон?

(1) Ну дык это понятно. Как тама в две колонки вывести.

посмотри как в типовых сделан отчет по сравнению версий объектов

А зачем сравнивать документы, если всё что нужно можно посмотреть в отчетах? Например, банальный отчет по материалам в производстве: требование - приход, отчет производства-расход, колонка "Конечный остаток" - различие между этими документами.

Кстати: в отчете производства юзверы могут накосячить так, что три таблицы документа станут несогласованны и рассинхронизированы между собой. К сожалению, УПП позволяет списывать материалы на продукцию и заказы, не указанные в таблице "Продукция"и распределять то, чего нет в таблицах "Продукции" и "Материалы". Помню даже писал обработку, которая выявляет такие моменты.

(6) Предполагается, что к учету допускаются лица, прошедшие мед.осмотр, особенно психиатра-нарколога! ;)

Я в общем визуально нашел где косяк, в требовании у них одно в отчете распределяют другое. Но блин за месяц их доков много.
Я только три дня исправил, но минуса ушли.
Но блин глазами глядеть это чокнутся однако.
Как бы мне это отчетом поймать?
(5)А тама токо полуфабрикаты светится.
(7) Это не здесь, бух которого я надрессированный бодро удрал на стройку моста, бо тут ему денег зажали. На нового брали так, пришло всего два человека, один хоть немного знает бухию.
А племяшь тыж программист - разгребай. А я типа подписка у него. Щас у босса новая мулька еще на убунту перейти.
Ему до ноября бы дотянуть.

Сделали автоматом на событии - списали в ОПЗС, списалась ТН, расхождений по складам теперь ноль. Минуса на складе закрывают под  угрозой лишения премии (выпускают и перемещают сами). Приписки пропали, пересортица тоже, на складе остатки оперативно. Проблем с ТМЦ уже полгода нету - тьфу-тьфу.
А до этого были отчеты с расхождениями, отклонениями и т.д.

(8) "А тама токо полуфабрикаты светится." - а настройка в отчете зачем? Настрой, например, на группировку, типа,  "Заказ/Затрата/Регистратор"

(10) А нету такой настройки однако.

(9) Жажду подробностей.

(8) Это везде так!

(12) какие подробности?
стандартное заполнение ТЧ, привязка по документу-основанию

если самому лень думать на запросом, то можешь мой поковырять

ВЫБРАТЬ
    НезавершенноеПроизводствоБухгалтерскийУчет.Регистратор КАК ТН,
    НезавершенноеПроизводствоБухгалтерскийУчет.Затрата,
    СУММА(НезавершенноеПроизводствоБухгалтерскийУчет.Количество) КАК Количество,
    НезавершенноеПроизводствоБухгалтерскийУчет.НоменклатурнаяГруппа,
    НезавершенноеПроизводствоБухгалтерскийУчет.Подразделение,
    НезавершенноеПроизводствоБухгалтерскийУчет.СтатьяЗатрат
ПОМЕСТИТЬ НЗП
ИЗ
    РегистрНакопления.НезавершенноеПроизводствоБухгалтерскийУчет КАК НезавершенноеПроизводствоБухгалтерскийУчет
ГДЕ
    НезавершенноеПроизводствоБухгалтерскийУчет.Период МЕЖДУ НАЧАЛОПЕРИОДА(&Дата, МЕСЯЦ) И КОНЕЦПЕРИОДА(&Дата, МЕСЯЦ)
    И НезавершенноеПроизводствоБухгалтерскийУчет.Регистратор ССЫЛКА Документ.ТребованиеНакладная
    И НезавершенноеПроизводствоБухгалтерскийУчет.Организация = &Организация

СГРУППИРОВАТЬ ПО
    НезавершенноеПроизводствоБухгалтерскийУчет.Регистратор,
    НезавершенноеПроизводствоБухгалтерскийУчет.Затрата,
    НезавершенноеПроизводствоБухгалтерскийУчет.НоменклатурнаяГруппа,
    НезавершенноеПроизводствоБухгалтерскийУчет.Подразделение,
    НезавершенноеПроизводствоБухгалтерскийУчет.СтатьяЗатрат
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ВЗ.ОПЗС,
    ВЗ.Затрата,
    СУММА(ВЗ.Количество) КАК Количество,
    ВЗ.НоменклатурнаяГруппа,
    ВЗ.Подразделение,
    ВЗ.СтатьяЗатрат
ПОМЕСТИТЬ Затраты
ИЗ
    (ВЫБРАТЬ
        ЗатратыНаВыпускПродукцииБухгалтерскийУчет.Регистратор КАК ОПЗС,
        ЗатратыНаВыпускПродукцииБухгалтерскийУчет.Затрата КАК Затрата,
        СУММА(ЗатратыНаВыпускПродукцииБухгалтерскийУчет.Количество) КАК Количество,
        ЗатратыНаВыпускПродукцииБухгалтерскийУчет.НоменклатурнаяГруппа КАК НоменклатурнаяГруппа,
        ЗатратыНаВыпускПродукцииБухгалтерскийУчет.Подразделение КАК Подразделение,
        ЗатратыНаВыпускПродукцииБухгалтерскийУчет.СтатьяЗатрат КАК СтатьяЗатрат
    ИЗ
        РегистрНакопления.ЗатратыНаВыпускПродукцииБухгалтерскийУчет КАК ЗатратыНаВыпускПродукцииБухгалтерскийУчет
    ГДЕ
        ЗатратыНаВыпускПродукцииБухгалтерскийУчет.Период МЕЖДУ НАЧАЛОПЕРИОДА(&Дата, МЕСЯЦ) И КОНЕЦПЕРИОДА(&Дата, МЕСЯЦ)
        И ЗатратыНаВыпускПродукцииБухгалтерскийУчет.Регистратор ССЫЛКА Документ.ОтчетПроизводстваЗаСмену
        И ЗатратыНаВыпускПродукцииБухгалтерскийУчет.Организация = &Организация
    
    СГРУППИРОВАТЬ ПО
        ЗатратыНаВыпускПродукцииБухгалтерскийУчет.Регистратор,
        ЗатратыНаВыпускПродукцииБухгалтерскийУчет.Затрата,
        ЗатратыНаВыпускПродукцииБухгалтерскийУчет.НоменклатурнаяГруппа,
        ЗатратыНаВыпускПродукцииБухгалтерскийУчет.Подразделение,
        ЗатратыНаВыпускПродукцииБухгалтерскийУчет.СтатьяЗатрат
    
    ОБЪЕДИНИТЬ ВСЕ
    
    ВЫБРАТЬ
        ЗатратыНаВыпускПродукцииНаработкаБухгалтерскийУчет.Регистратор,
        ЗатратыНаВыпускПродукцииНаработкаБухгалтерскийУчет.Затрата,
        СУММА(ЗатратыНаВыпускПродукцииНаработкаБухгалтерскийУчет.Количество),
        ЗатратыНаВыпускПродукцииНаработкаБухгалтерскийУчет.НоменклатурнаяГруппа,
        ЗатратыНаВыпускПродукцииНаработкаБухгалтерскийУчет.Подразделение,
        ЗатратыНаВыпускПродукцииНаработкаБухгалтерскийУчет.СтатьяЗатрат
    ИЗ
        РегистрНакопления.ЗатратыНаВыпускПродукцииНаработкаБухгалтерскийУчет КАК ЗатратыНаВыпускПродукцииНаработкаБухгалтерскийУчет
    ГДЕ
        ЗатратыНаВыпускПродукцииНаработкаБухгалтерскийУчет.Период МЕЖДУ НАЧАЛОПЕРИОДА(&Дата, МЕСЯЦ) И КОНЕЦПЕРИОДА(&Дата, МЕСЯЦ)
        И ЗатратыНаВыпускПродукцииНаработкаБухгалтерскийУчет.Регистратор ССЫЛКА Документ.ОтчетПроизводстваЗаСмену
        И ЗатратыНаВыпускПродукцииНаработкаБухгалтерскийУчет.Организация = &Организация
    
    СГРУППИРОВАТЬ ПО
        ЗатратыНаВыпускПродукцииНаработкаБухгалтерскийУчет.Регистратор,
        ЗатратыНаВыпускПродукцииНаработкаБухгалтерскийУчет.Затрата,
        ЗатратыНаВыпускПродукцииНаработкаБухгалтерскийУчет.НоменклатурнаяГруппа,
        ЗатратыНаВыпускПродукцииНаработкаБухгалтерскийУчет.Подразделение,
        ЗатратыНаВыпускПродукцииНаработкаБухгалтерскийУчет.СтатьяЗатрат) КАК ВЗ

СГРУППИРОВАТЬ ПО
    ВЗ.ОПЗС,
    ВЗ.Затрата,
    ВЗ.НоменклатурнаяГруппа,
    ВЗ.Подразделение,
    ВЗ.СтатьяЗатрат
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    Затраты.ОПЗС КАК ОПЗС,
    Затраты.Затрата КАК ЗатратаОПзС,
    Затраты.НоменклатурнаяГруппа КАК НоменклатурнаяГруппаОПзС,
    Затраты.Подразделение КАК ПодразделениеОПЗС,
    Затраты.СтатьяЗатрат КАК СтатьяЗатратОПзС,
    Затраты.Количество КАК КоличествоОПзС,
    НЗП.Количество КАК КоличествоТН,
    НЗП.ТН КАК ТН,
    НЗП.Затрата КАК ЗатратаТН,
    НЗП.НоменклатурнаяГруппа КАК НоменклатурнаяГруппаТН,
    НЗП.Подразделение КАК ПодразделениеТН,
    НЗП.СтатьяЗатрат КАК СтатьяЗатратТН,
    НЗП.ТН.ДокументОснование КАК ДокументОснованиеТН
ИЗ
    НЗП КАК НЗП
        ПОЛНОЕ СОЕДИНЕНИЕ Затраты КАК Затраты
        ПО НЗП.ТН.ДокументОснование = Затраты.ОПЗС
            И НЗП.НоменклатурнаяГруппа = Затраты.НоменклатурнаяГруппа
            И НЗП.Затрата = Затраты.Затрата
            И НЗП.Подразделение = Затраты.Подразделение
            И НЗП.СтатьяЗатрат = Затраты.СтатьяЗатрат
ГДЕ
    НЕ ЕСТЬNULL(Затраты.Количество, 0) = ЕСТЬNULL(НЗП.Количество, 0)

УПОРЯДОЧИТЬ ПО
    ОПЗС,
    ТН
АВТОУПОРЯДОЧИВАНИЕ
;

////////////////////////////////////////////////////////////////////////////////
УНИЧТОЖИТЬ НЗП
;

////////////////////////////////////////////////////////////////////////////////
УНИЧТОЖИТЬ Затраты