Списание ДС не делает движения по РН Расчёты с фондами по страховым взносам. Где в списании ДС указать что это уплата взносов в ПФР или ФСС?

ап

счет учета правильный стоит?

(2) Счёт правильный, но даже если в старых оплатах в Списаниях в демке меняю счёт на произвольный (например 62), то платёж отражается в РН как ПФР, т.е. не по счёту цепляется

мне кажется это в закрытии происходит.
Ибо в самом документе нет упомнинания движений по этому регистру

(4) // Движения по регистрам БЗКР
    Если Константы.ИспользоватьНачислениеЗарплаты.Получить() И ПроведеноБанком Тогда
        
        Если ХозяйственнаяОперация = Перечисления.ХозяйственныеОперации.ВыплатаЗарплатыПоЗарплатномуПроекту
            ИЛИ ХозяйственнаяОперация = Перечисления.ХозяйственныеОперации.ВыплатаЗарплатыНаЛицевыеСчета Тогда
            
            ДенежныеСредстваСервер.ЗарегистрироватьОплатуВедомостей(ЭтотОбъект, ДополнительныеСвойства, Отказ);
            ДенежныеСредстваСервер.РассчитатьИЗарегистрироватьУдержанныеНалоги(ДополнительныеСвойства, Движения, Отказ);
            
        ИначеЕсли ХозяйственнаяОперация = Перечисления.ХозяйственныеОперации.ПеречислениеВБюджет Тогда
            
            ДенежныеСредстваСервер.ЗарегистрироватьПеречислениеНалоговИВзносов(
                ЭтотОбъект,
                ДополнительныеСвойства.ТаблицыДляДвижений.ТаблицаВыплатыНалоговИВзносов,
                Отказ);
            
        КонецЕсли;
        
    КонецЕсли;

(5) +1
// Процедура выполняет регистрацию оплаты страховых взносов и НДФЛ в контуре учета зарплаты.
//
// Параметры:
//    Документ - ДокументОбъект.СписаниеБезналичныхДенежныхСредств, ДокументСсылка.СписаниеБезналичныхДенежныхСредств - документ
//    ТаблицаОтражения - ТаблицаЗначений - Таблица отражения в регламентированном учете.
//    Отказ - Булево - Признак отказа от записи движений.
//
Процедура ЗарегистрироватьПеречислениеНалоговИВзносов(Документ, ТаблицаОтражения, Отказ = Ложь) Экспорт
    
    Если ТаблицаОтражения.Количество() = 0 Тогда
        Возврат;
    КонецЕсли;
    
    Если ТипЗнч(Документ) = Тип("ДокументСсылка.СписаниеБезналичныхДенежныхСредств") Тогда
        Реквизиты = ОбщегоНазначения.ЗначенияРеквизитовОбъекта(Документ, "Ссылка, ДатаПроведенияБанком, Номер, Организация, ХозяйственнаяОперация, ПоказательОснования, ПоказательПериода");
    Иначе
        Реквизиты = Документ;
    КонецЕсли;
    
    Если Реквизиты.ХозяйственнаяОперация <> Перечисления.ХозяйственныеОперации.ПеречислениеВБюджет
        Или Не Константы.ИспользоватьНачислениеЗарплаты.Получить() Тогда
        Возврат;
    КонецЕсли;
    
    Запрос = Новый Запрос;
    Запрос.Текст =
    "ВЫБРАТЬ
    |    ТаблицаОтражения.СчетДт КАК СчетДт,
    |    ТаблицаОтражения.СубконтоДт1 КАК ВидПлатежа,
    |    ТаблицаОтражения.СубконтоДт2 КАК СубконтоДт2,
    |    ТаблицаОтражения.Сумма КАК Сумма
    |ПОМЕСТИТЬ ТаблицаОтражения
    |ИЗ
    |    &ТаблицаОтражения КАК ТаблицаОтражения
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ
    |    &МесяцНалоговогоПериода КАК МесяцНалоговогоПериода,
    |    ЗНАЧЕНИЕ(Справочник.ПодразделенияОрганизаций.ПустаяСсылка) КАК Подразделение,
    |    ТаблицаОтражения.Сумма КАК Сумма,
    |    &ПлатежноеПоручениеНомер КАК ПлатежноеПоручениеНомер,
    |    &ДатаДокумента КАК ПлатежноеПоручениеДата,
    |    ТаблицаОтражения.ВидПлатежа КАК ВидПлатежа,
    |    ТаблицаОтражения.СубконтоДт2 КАК НалоговыйОрган
    |ИЗ
    |    ТаблицаОтражения КАК ТаблицаОтражения,
    |    Документ.СписаниеБезналичныхДенежныхСредств КАК СписаниеБезналичныхДенежныхСредств
    |ГДЕ
    |    ТаблицаОтражения.СчетДт = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.НДФЛ)
    |    И СписаниеБезналичныхДенежныхСредств.Ссылка = &Ссылка
    |    И ТаблицаОтражения.ВидПлатежа В (&МассивНазначенийПлатежа)
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ
    |    &ДатаДокумента КАК Период,
    |    ВЫБОР
    |        КОГДА ТаблицаОтражения.СчетДт = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПФР_страх)
    |            ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыОбязательногоСтрахованияСотрудников.ПФРСтраховая)
    |        КОГДА ТаблицаОтражения.СчетДт = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПФР_нак)
    |            ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыОбязательногоСтрахованияСотрудников.ПФРНакопительная)
    |        КОГДА ТаблицаОтражения.СчетДт = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПФР_доп)
    |            ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыОбязательногоСтрахованияСотрудников.ДоплатаКПенсииЛетчикам)
    |        КОГДА ТаблицаОтражения.СчетДт = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПФР_доп_шахтеры)
    |            ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыОбязательногоСтрахованияСотрудников.ДоплатаКПенсииШахтерам)
    |        КОГДА ТаблицаОтражения.СчетДт = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПФР_доп_ВредныеУсловияТруда)
    |            ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыОбязательногоСтрахованияСотрудников.ПФРЗаЗанятыхНаПодземныхИВредныхРаботах)
    |        КОГДА ТаблицаОтражения.СчетДт = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПФР_доп_ТяжелыеУсловияТруда)
    |            ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыОбязательногоСтрахованияСотрудников.ПФРЗаЗанятыхНаТяжелыхИПрочихРаботах)
    |        КОГДА ТаблицаОтражения.СчетДт = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПФР_ОПС)
    |            ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыОбязательногоСтрахованияСотрудников.ПФРПоСуммарномуТарифу)
    |        КОГДА ТаблицаОтражения.СчетДт = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ФФОМС)
    |            ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыОбязательногоСтрахованияСотрудников.ФФОМС)
    |        КОГДА ТаблицаОтражения.СчетДт = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ТФОМС)
    |            ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыОбязательногоСтрахованияСотрудников.ТФОМС)
    |        КОГДА ТаблицаОтражения.СчетДт = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ФСС)
    |            ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыОбязательногоСтрахованияСотрудников.ФСС)
    |        КОГДА ТаблицаОтражения.СчетДт = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ФСС_НСиПЗ)
    |            ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыОбязательногоСтрахованияСотрудников.ФССНесчастныеСлучаи)
    |        ИНАЧЕ НЕОПРЕДЕЛЕНО
    |    КОНЕЦ КАК ВидОбязательногоСтрахованияСотрудников,
    |    ТаблицаОтражения.Сумма КАК Сумма,
    |    &ПлатежноеПоручениеНомер КАК ПлатежноеПоручениеНомер,
    |    &ДатаДокумента КАК ПлатежноеПоручениеДата,
    |    ИСТИНА КАК ЭтоСтраховыеВзносы,
    |    ДАТАВРЕМЯ(1, 1, 1) КАК ГодЗадолженностиПоЕСН,
    |    ТаблицаОтражения.ВидПлатежа КАК ВидПлатежа,
    |    ЗНАЧЕНИЕ(ВидДвиженияНакопления.Расход) КАК ВидДвижения
    |ИЗ
    |    ТаблицаОтражения КАК ТаблицаОтражения,
    |    Документ.СписаниеБезналичныхДенежныхСредств КАК СписаниеБезналичныхДенежныхСредств
    |ГДЕ
    |    СписаниеБезналичныхДенежныхСредств.Ссылка = &Ссылка
    |    И ВЫБОР
    |            КОГДА ТаблицаОтражения.СчетДт = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПФР_страх)
    |                ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыОбязательногоСтрахованияСотрудников.ПФРСтраховая)
    |            КОГДА ТаблицаОтражения.СчетДт = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПФР_нак)
    |                ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыОбязательногоСтрахованияСотрудников.ПФРНакопительная)
    |            КОГДА ТаблицаОтражения.СчетДт = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПФР_доп)
    |                ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыОбязательногоСтрахованияСотрудников.ДоплатаКПенсииЛетчикам)
    |            КОГДА ТаблицаОтражения.СчетДт = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПФР_доп_шахтеры)
    |                ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыОбязательногоСтрахованияСотрудников.ДоплатаКПенсииШахтерам)
    |            КОГДА ТаблицаОтражения.СчетДт = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПФР_доп_ВредныеУсловияТруда)
    |                ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыОбязательногоСтрахованияСотрудников.ПФРЗаЗанятыхНаПодземныхИВредныхРаботах)
    |            КОГДА ТаблицаОтражения.СчетДт = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПФР_доп_ТяжелыеУсловияТруда)
    |                ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыОбязательногоСтрахованияСотрудников.ПФРЗаЗанятыхНаТяжелыхИПрочихРаботах)
    |            КОГДА ТаблицаОтражения.СчетДт = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПФР_ОПС)
    |                ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыОбязательногоСтрахованияСотрудников.ПФРПоСуммарномуТарифу)
    |            КОГДА ТаблицаОтражения.СчетДт = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ФФОМС)
    |                ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыОбязательногоСтрахованияСотрудников.ФФОМС)
    |            КОГДА ТаблицаОтражения.СчетДт = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ТФОМС)
    |                ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыОбязательногоСтрахованияСотрудников.ТФОМС)
    |            КОГДА ТаблицаОтражения.СчетДт = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ФСС)
    |                ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыОбязательногоСтрахованияСотрудников.ФСС)
    |            КОГДА ТаблицаОтражения.СчетДт = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ФСС_НСиПЗ)
    |                ТОГДА ЗНАЧЕНИЕ(Перечисление.ВидыОбязательногоСтрахованияСотрудников.ФССНесчастныеСлучаи)
    |            ИНАЧЕ НЕОПРЕДЕЛЕНО
    |        КОНЕЦ <> НЕОПРЕДЕЛЕНО
    |    И ТаблицаОтражения.ВидПлатежа В (&МассивНазначенийПлатежа)";
    
    МассивНазначенийПлатежа = Новый Массив;
    МассивНазначенийПлатежа.Добавить(Перечисления.ВидыПлатежейВГосБюджет.Налог);
    МассивНазначенийПлатежа.Добавить(Перечисления.ВидыПлатежейВГосБюджет.НалогСам);
    МассивНазначенийПлатежа.Добавить(Перечисления.ВидыПлатежейВГосБюджет.НалогАкт);
    
    МесяцНалоговогоПериода = МесяцНалоговогоПериода(Реквизиты.ПоказательОснования, Реквизиты.ПоказательПериода);
    
    Запрос.УстановитьПараметр("ТаблицаОтражения",       ТаблицаОтражения);
    Запрос.УстановитьПараметр("Ссылка",                 Реквизиты.Ссылка);
    Запрос.УстановитьПараметр("ДатаДокумента",          Реквизиты.ДатаПроведенияБанком);
    Запрос.УстановитьПараметр("МесяцНалоговогоПериода", МесяцНалоговогоПериода);
    Запрос.УстановитьПараметр("ПлатежноеПоручениеНомер",ПрефиксацияОбъектовКлиентСервер.ПолучитьНомерНаПечать(Реквизиты.Номер, Истина, Истина));
    Запрос.УстановитьПараметр("МассивНазначенийПлатежа",МассивНазначенийПлатежа);
    
    Результат = Запрос.ВыполнитьПакет();
    
    ПеречисленныйНалог = Результат[1].Выгрузить();
    РасчетыСФондом = Результат[2].Выгрузить();
    
    Если ПеречисленныйНалог.Количество() > 0 Или РасчетыСФондом.Количество() > 0 Тогда
        
        Если ТипЗнч(Документ) = Тип("ДокументСсылка.СписаниеБезналичныхДенежныхСредств") Тогда
            ДокументОбъект = Реквизиты.Ссылка.ПолучитьОбъект();
        Иначе
            ДокументОбъект = Документ;
        КонецЕсли;
        
        Если ЗначениеЗаполнено(МесяцНалоговогоПериода) И ПеречисленныйНалог.Количество() > 0 Тогда
            НалоговыйОрган = ПеречисленныйНалог[0].НалоговыйОрган;
            УчетНДФЛ.СформироватьПеречисленныйНалог(ДокументОбъект.Ссылка, ДокументОбъект.Движения, Отказ, ДокументОбъект.Организация, ДокументОбъект.ДатаПроведенияБанком, ПеречисленныйНалог, , НалоговыйОрган, Истина);
        КонецЕсли;
        
        Если РасчетыСФондом.Количество() > 0 Тогда
            УчетСтраховыхВзносов.СформироватьРасчетыСФондом(ДокументОбъект.Движения, Отказ, ДокументОбъект.Организация, РасчетыСФондом, Истина);
        КонецЕсли;
        
    КонецЕсли;
    
КонецПроцедуры

(6) Взносы начислены, счёт заполнен, но всё равно не учитывает, что ещё заполнить?
http://i026.radikal.ru/1609/79/f5117d64535d.jpg

http://s019.radikal.ru/i608/1609/c2/b4d12725f5a7.jpg

(7) отладчик украли ?