Пару товарищам было выдано - задание было простое, внешняя печатная форма к доку реализация товаров и услуг. Максимально упрощенная.
Просьба дать оценку. Причем, как мне кажется первый пытался списывать у второго.

Код 1.

Функция Печать() Экспорт
    
    ТабДокумент = ПечатьДокумента();
    
    Возврат ТабДокумент;
КонецФункции





Функция ПечатьДокумента() экспорт
// запрос на Заголовок    
    Запрос = Новый Запрос;
    Запрос.УстановитьПараметр("ТекущийДокумент", СсылкаНаОбъект);
    Запрос.Текст =
    "выбрать
    |    РеализацияТоваровУслуг.Номер,
    |    РеализацияТоваровУслуг.Дата,
    |    РеализацияТоваровУслуг.Контрагент как Покупатель,
    |   РеализацияТоваровУслуг.Организация,
    |    РеализацияТоваровУслуг.Организация как Поставщик
    |из
    |    Документ.РеализацияТоваровУслуг как РеализацияТоваровУслуг
    |где
    |    РеализацияТоваровУслуг.Ссылка = &ТекущийДокумент";

    Шапка = Запрос.Выполнить().Выбрать();
    Шапка.Следующий();    
    
    
// запрос на товары

    Запрос = Новый Запрос;
    Запрос.УстановитьПараметр("СсылкаНаДокумент", СсылкаНаОбъект);
    Запрос.Текст =
    "
    |   выбрать
    |    РеализацияТоваровУслугТовары.Номенклатура.Артикул как Артикул,
    |    РеализацияТоваровУслугТовары.Номенклатура.НаименованиеПолное как Товар,
    |    РеализацияТоваровУслугТовары.Количество/ЕдиницыИзмерения.Коэффициент как Мест,
    |    РеализацияТоваровУслугТовары.Номенклатура.ЕдиницаИзмеренияМест как ЕдиницаИзмеренияМест,
    |    РеализацияТоваровУслугТовары.Количество как Количество,
    |    РеализацияТоваровУслугТовары.ЕдиницаИзмерения
    | из
    |      Справочник.ЕдиницыИзмерения как ЕдиницыИзмерения
    |        Левое соединение Документ.РеализацияТоваровУслуг.Товары как РеализацияТоваровУслугТовары
    |        по (РеализацияТоваровУслугТовары.ЕдиницаИзмеренияМест = ЕдиницыИзмерения.Ссылка)
    | где
    |    РеализацияТоваровУслугТовары.Ссылка.Ссылка = &СсылкаНаДокумент";
    
    
    ЗапросТовары = Запрос.Выполнить().Выгрузить();

    ТабДокумент = Новый ТабличныйДокумент;

    Макет = ПолучитьМакет("РасходнаяНакладная");
    
    //шапка накладной
    ОбластьМакета = Макет.ПолучитьОбласть("ЗаголовокДокумента");
    ОбластьМакета.Параметры.НаименованиеДокумента = ОбщегоНазначения.СформироватьЗаголовокДокумента(Шапка, "Расходная накладная");
    ТабДокумент.Вывести(ОбластьМакета);

    //покупатель
    ОбластьМакета = Макет.ПолучитьОбласть("Покупатель");
    ОбластьМакета.Параметры.Покупатель = Шапка.Покупатель;
    ТабДокумент.Вывести(ОбластьМакета);
    
    // заголовок таблицы
    ОбластьМакета = Макет.ПолучитьОбласть("ЗаголовокТаблицы");
    ТабДокумент.Вывести(ОбластьМакета);
    
    // товары
     ОбластьМакета = Макет.ПолучитьОбласть("Строка");
     КоличествоСтрокТовары = ЗапросТовары.Количество();
     ИтогоМест = 0;
     ИтогоКоличество = 0;
     Для НомерСтрокиВыборки = 0 По КоличествоСтрокТовары-1 Цикл
        ВыборкаСтрок =  ЗапросТовары[НомерСтрокиВыборки];
        ИтогоМест = ИтогоМест + ВыборкаСтрок.Мест;
        ИтогоКоличество = ИтогоКоличество + ВыборкаСтрок.Количество;
        ОбластьМакета.Параметры.Заполнить(ВыборкаСтрок);
        ОбластьМакета.Параметры.НомерСтроки = НомерСтрокиВыборки + 1;
             Если  Окр(ВыборкаСтрок.Мест,0,0) <> ВыборкаСтрок.Мест тогда
                  ОбластьМакета.Параметры.Примечание = "Ящик неполный";
                  
            КонецЕсли;
     ТабДокумент.Вывести(ОбластьМакета);        
     КонецЦикла;        
            
    // итоги        
     ОбластьМакета = Макет.ПолучитьОбласть("Итоги");
     ОбластьМакета.Параметры.ИтогоМест = ИтогоМест;
     ОбластьМакета.Параметры.ИтогоКоличество = ИтогоКоличество;
     ТабДокумент.Вывести(ОбластьМакета);

    
    
    
    
    Возврат ТабДокумент;
КонецФункции    

Код 2.

Функция ПолучитьТовары()
    
    Запрос = Новый Запрос;
    Запрос.Текст =
    "ВЫБРАТЬ
    |    РеализацияТоваровУслугТовары.Номенклатура.Артикул КАК Артикул,
    |    РеализацияТоваровУслугТовары.Номенклатура.НаименованиеПолное КАК Товар,
    |    ЕдиницыИзмерения.Коэффициент КАК Коэффициент,
    |    РеализацияТоваровУслугТовары.Номенклатура.ЕдиницаИзмеренияМест КАК ЕдиницаИзмеренияМест,
    |    РеализацияТоваровУслугТовары.Количество КАК Количество,
    |    РеализацияТоваровУслугТовары.Количество / ЕдиницыИзмерения.Коэффициент КАК Мест,
    |    РеализацияТоваровУслугТовары.ЕдиницаИзмерения
    |ИЗ
    |    Справочник.ЕдиницыИзмерения КАК ЕдиницыИзмерения
    |        ЛЕВОЕ СОЕДИНЕНИЕ Документ.РеализацияТоваровУслуг.Товары КАК РеализацияТоваровУслугТовары
    |        ПО (РеализацияТоваровУслугТовары.ЕдиницаИзмеренияМест = ЕдиницыИзмерения.Ссылка)
    |ГДЕ
    |    РеализацияТоваровУслугТовары.Ссылка.Ссылка = &Док";

    Запрос.УстановитьПараметр("Док", СсылкаНаОбъект);
    ДанныеТовара = Запрос.Выполнить().Выгрузить();
    
    Возврат ДанныеТовара
КонецФункции    

// Внешняя функция печати
// Параметры
//  ИмяМакета  – Строка – имя формы печати
//
// Возвращаемое значение:
//   Булево   –Печать прошла успешно - Истина, иначе - Ложь
//
Функция Печать() Экспорт
    ТабДок = Новый ТабличныйДокумент;
    Макет = ПолучитьМакет("Макет");
    ОбластьЗаголовок   = Макет.ПолучитьОбласть("Заголовок");
    Док = СсылкаНаОбъект.ПолучитьОбъект();
    НомерДок  = Док.Номер;
    ДатаДок = Формат(Док.Дата,"ДЛФ=DD");
    ОбластьЗаголовок.Параметры.ЗаголовокПредставление = "Расходная накладная № " + НомерДок + " от " + ДатаДок;
    ОбластьЗаголовок.Параметры.Контрагент = Док.Контрагент.НаименованиеПолное;
    ТабДок.Вывести(ОбластьЗаголовок);
    
    ОбластьЗаголовокТаблицы   = Макет.ПолучитьОбласть("ЗаголовокТаблицы");
    ТабДок.Вывести(ОбластьЗаголовокТаблицы);
    ДанныеНоменклатуры = ПолучитьТовары();
    нс = 1;
    Для Каждого СтрТовар Из ДанныеНоменклатуры Цикл
            ОбластьСтрока   = Макет.ПолучитьОбласть("Строка");
            ОбластьСтрока.Параметры.Заполнить(СтрТовар);
            ОбластьСтрока.Параметры.нс = нс;
            Если  Окр(СтрТовар.Мест,0,0) <> СтрТовар.Мест тогда
                ОбластьСтрока.Параметры.Примечание = "Ящик неполный"
            КонецЕсли;
            ТабДок.Вывести(ОбластьСтрока);
            нс = нс + 1;
    КонецЦикла;    
    
    ОбластьИтого   = Макет.ПолучитьОбласть("Итого");
    ОбластьИтого.Параметры.ИтогоМест = ДанныеНоменклатуры.Итог("Мест") ;
    ОбластьИтого.Параметры.ИтогоКолво  = ДанныеНоменклатуры.Итог("Количество") ;
    ТабДок.Вывести(ОбластьИтого);


            
    Возврат ТабДок

КонецФункции // Печать()


Спасибо.

От же криво вставилось.

Зачем это все?

(2) Я не силен. Но мне надо дать оценку соискателям.

Имхо первый код более читабелен. И он "стандартный"

Запрос по товарам  некорректный и неоптимальный в обоих вариантах.

В коде варианта 2 присутствуют неявные запросы при заполнении шапки (Док.Контрагент.НаименованиеПолное), описание функции в комментариях не соответствует действительности (возвращает ТабличныйДокумент, а не Булево). Но код при этом чуть лучше структурирован, чем в портянке из 1. В варианте 1
непонятно, зачем нужна функция Печать() без параметров (рекомендуется к прочтению подход YAGNI).

Первый.

Во втором

// Параметры
//  ИмяМакета  – Строка – имя формы печати

//
// Возвращаемое значение:

//   Булево   –Печать прошла успешно - Истина, иначе - Ложь
//

Функция Печать() Экспорт




    Док = СсылкаНаОбъект.ПолучитьОбъект();
    НомерДок  = Док.Номер;
    ДатаДок = Формат(Док.Дата,"ДЛФ=DD");

Первый вариант получше, т.к. второй получает параметры шапки через точку от Документа - лишнии запросы к бд. Но данный тест не показателен.

(5) Запрос по товарам  некорректный и неоптимальный в обоих вариантах.

Можете более подробно расписать? Спасибо.

В коде варианта 2 присутствуют неявные запросы при заполнении шапки (Док.Контрагент.НаименованиеПолное)

Это уже не допустимо так писать в восьмой версии?

(3) "Я не силен. Но мне надо дать оценку соискателям."
Я немножко в осадке. Бывший зема : где гарантия, что оценка будет хоть что-то отражать?

(3) Не силен в чем?
Первый получает данные шапки одним запросом и работает с результатом выборки, второй каждый раз обращается Док.Номер, Док.Контрагент.НаименованиеПолное и т.д. - кто лучше очевидно. Далее работая с ТЧ оба зачем-то выгружают результат запроса в ТЗ вместо того, чтоб работать с выборкой запроса.
Комментарии к функции у второго тоже доставляют:
// Возвращаемое значение:
//   Булево   –Печать прошла успешно - Истина, иначе - Ложь
а в самой функции:
Возврат ТабДок

(4) А где критерии стандартности можно посмотреть, заинтересовало.

(9) Поэтому я у вас народ и спрашиваю. Вот лично мне код 2 понравился больше, а оно эвоно как, код 1 то лучше однако.

Тест не показателен, первый мог содрать структуру печатной формы с типовой, немного переделав,второй написал сам, хоть и чуть хуже

(10) второй каждый раз обращается Док.Номер, Док.Контрагент.НаименованиеПолное

Интересно, но там типа выше получен объект. А получается при Док.Номер, Док.Контрагент.НаименованиеПолное это отдельные запросы которые 1с сама генерирует однако? Думал ПолучитьОбъект сразу все притаскивает.

(12) Код 1 более привычен. Получается из-под конструктора печати, затем допиливается, если нужно, напильником.
По большому счету код 2 ничем не хуже. Замечание по поводу "Док.Контрагент.НаименованиеПолное" в данном случае необоснованно. Если бы нужно было получать несколько полей элемента справочника - тогда все так. Поскольку поле одно - количество обращений к базе будет одно. Хоть запросом, хоть через точку.

(13) Коли Вам не в тягость, может у Вас есть более показательный тест? Заранее благодарен.

У второго больше косяков, например
каждый раз зачем-то получает ОбластьСтрока   = Макет.ПолучитьОбласть("Строка");
также зачем-то получает объект Док = СсылкаНаОбъект.ПолучитьОбъект();


Теперь осталось первому дать написанное вторым и наоборот, чтобы нашли и объяснили ошибки, вот тут сразу станет все понятно с пониманием написания кода

(8) Писать допустимо, но не оптимально. А вот получать объект - явно лишнее.

P.S. И комментарии не соответствующие коду - совсем не хорошо.

(8) + В первом варианте, вместо обхода результатов запроса зачем-то используется цикл со счетчиком, кроме этого зачем-то два раза выбирается Организация, это было логично, если бы использовался метод - Заполнить для области табличного документа.
Во втором варианте тоже вместо обхода результата выборки она зачем-то выгружается  в ТЗ.
Ну остальное уже в других постах описали...

(15) В данном случае вообще неоптимально получать объект, т.к. изменять его не планируем. Нужно было запросом получить нужные поля для шапки

(0) бери обоих на испытательный срок... без вводных такие тесты - не показательны...

(8) >>Это уже не допустимо так писать в восьмой версии?
Так писать не оптимально, такая форма записи порождает запрос к БД. Если у вас будет реализована групповая печать этих документов, то такой код будет совсем "не айс".

первый лучше - косвенных запросов нет и запросами получается то и только то, что необходимо.

ПолучитьОбъект() читает и табличные части тоже, то есть данные по товарам читаются два раза. Да и обращение через точку - это плюс запрос.

Которого из них брать, по этому коду не скажешь. Вообще по коду такое решение нельзя принимать. Кто умнее, того и бери.

(14) Док.Контрагент.НаименованиеПолное получает неявно по ссылке весь объект Контрагент, от которого в Док только ссылка

Оба г., потому что писать отчеты надо на СКД. И объясните мне что там делает левое соединение справочника ЕдиницыИзмерения с табличной частью?

(25) Похоже оба соискателя решили топикстартера проверить на "левое соединение". ;)

(16)Тестовое мини-задание.



Есть справочники:

- Номенклатура

- Склады (содержит реквизит ТипРозничныхЦен(СправочникСсылка.ТипыЦенНосенклатуры))

- ТипыЦенНоменклатуры



Регистр Сведений: ЦеныНоменклатуры (Периодический, подчинен регистратору)

- Измерения:   Номенклатура, ТипЦен

- Ресурс: Цена



Регистр накопления: ТоварыНаСкладах(Остатки)

- Измерения: Склад, Номенклатура

- Ресурс: Количество



Задача: Написать запрос(отчет), который бы показывал остатки и цены номенклатуры в разрезе складов и номенклатуры. Так же необходимо, чтобы в этом отчете выводились нулевые остатки и цены.

(26) + Об этом в (8) написано.

(21) Они оба на испытательном, который подходит к концу. Аборигены в 1С как в апельсинах. Я так типа вообще гуру однако. Вот такой вариант придумал. Первый чисто на програ претендует, второй очень неплохой сисадмино, прог он так побочно. Если берем первого на прога, то второй в админы перейдет. Но первый УПП не знает, второй более - менее шарит.

(29)У вас весь отдел уволить надо

(25) Это не отчет, это внешняя печатная форма. Там СКД вроде не работает.
Узнают сколько бутылок в ящике, это коэффициент в единицах измерения.

(30) А нет отдела. ИТ инфраструктура в зачаточном состоянии, как-то работает и ладно.

(31) левое то соединение нафига? из Справочник.ЕдиницыИзмерения как ЕдиницыИзмерения никаких данных не используется

они похоже скопипастили запрос откуда-то

РеализацияТоваровУслугТовары.Ссылка.Ссылка
РеализацияТоваровУслугТовары.Ссылка.Ссылка.Ссылка.Ссылка.Ссылка.Ссылка.Ссылка

(31) ЛВЗ?

(27) Чето просто как-то, СКД один запрос. Вы если не против я попробу, а потом Вас позову глянуть чего это я сварганил.

Такая интересная тема получилась. Спасибо всем. Большое такое.

(0) Сравнивать код в печатной форме, да вам заняться больше нечем

(31) чой-то? СКД везде работает, даже с внешними источникам данных и с вызовом экспортных функций

(35)Нет, типовая УПП. Причем нафуя ее брали, им БП с головой. Работает с десяток бухов. Смотрят только проводки, где не сходится тупо операциями колбасят, и потом классика программа плохая.

(37) Ну первое что в голову пришло. Можете предложить что-то лучше?

(0)
это писал один и тот же человек

(41) или сдернуто с одного места и переделано, как курсовик с инета :)

+(41) либо второй писал видя первый код

(42) ;)) бинго

(33) Коэффициент получить.
Вот тута.   РеализацияТоваровУслугТовары.Количество/ЕдиницыИзмерения.Коэффициент как Мест,

(43) Второй написан раньше.

(38) Это как 1С далеко ушла та. Я в типовых такое не видел. На СКД печатаные формы доков еще не попадались. Надо будем в новых поискать однако.

(46) не существенно. в обоих вариантах одни и те же генетические ошибки. А если по мелочам, то в втором варианте, тоже свои плюсы есть

(31) Во-первых слева должна быть табличная часть, а во вторых соединение вообще там не нужно, ибо коэффициент и так уже есть в ЕдиницаИзмеренияМест.

(47) Лучше в интернете поищи, вот например: https://helpf.pro/faq/view/1400.html

(48)Вы же дружно зафукали второй.

(0) Оба варианта криво написаны. Дать еще одно контрольное задание.

(49) +1

(36) Тест простой, но в запросе будет видна работа с виртуальными таблицами, правильностью соединений, конструкция ЕстьNull и т.д.

(49)Так?
ВЫБРАТЬ
    Товары.Номенклатура.Артикул КАК Артикул,
    Товары.Номенклатура.НаименованиеПолное КАК Товар,
    Товары.Номенклатура.ЕдиницаИзмеренияМест КАК ЕдиницаИзмеренияМест,
    Товары.Количество КАК Количество,
    Товары.ЕдиницаИзмерения КАК ЕдиницаИзмерения,
    Товары.Номенклатура.ЕдиницаИзмеренияМест.Коэффициент КАК Коэффициент,
    Товары.Количество / Товары.Номенклатура.ЕдиницаИзмеренияМест.Коэффициент КАК Мест
ИЗ
    Документ.РеализацияТоваровУслуг.Товары КАК Товары
ГДЕ
    Товары.Ссылка.Ссылка = &Док

(54) Отлично. Спасибо.

(55) типа того
НО на больших объемах выборки, по феншую, надо все-таки левое соединение, план запроса оптимальнее получится

(0) Второй лучше.

(57) Дык сказали хрено оно тама.

(40) Устрой им экзамен. Скачай билеты по 1с, выбери из них вопросы в которых сам шаришь и протестируй своих подопечных.

(56) Для усложнения, можно попросить добавить отбор по номенклатуре и склада.

Не надо ничего усложнять. Из приведенного в (0) ясно, что второй код писал более опытный человек.

(0) Оба фигню написали, так как не соответсвует требованиям продсистемы Печать БСП:
http://its.1c.ru/db/bspdoc#content:446:1:issogl2_разработка_процедуры_печать
Для того, чтобы их поделку можно было использовать, как внешнюю печатную форму, эти требования должны выполняться.

Если выбирать из двух вариантов, то первый лучше.
Но оба почему-то делают отдельные запросы к шапке и к табличной части.
То есть групповая печать ими не рассматривается вообще? При печати сотни накладных будет выполнено 200 запросов.
За запросы в цикле вроде как бы расстрел без права переписки полагается.
Второй еще и объект тянет из базы зачем-то.

Если выбирать не из чего, то оставлять первого. Ибо второй вообще не понимает что делает.

(11) >> А где критерии стандартности можно посмотреть, заинтересовало.
http://its.1c.ru/db/bspdoc#content:427:1:issogl3_пример_внешняя_печатная_форма
http://its.1c.ru/db/bspdoc#content:446:1:issogl2_разработка_процедуры_печать

по 3 балла из 5 каждому

(0) задача делается очень быстро с помощью v8: Конструктор внешних печатных форм NEW (обычные и управляемые приложения)
считаю, что задача программиста в том числе уметь найти оптимальное решение по-максимуму используя имеющиеся в т.ч. чужие наработки.
решение в данном случае - погуглить, подумать, сделать

+ к (63) Ссылки почему-то криво вставились. Хвосты определились просто как кусок текста.

(27) >> чтобы в этом отчете выводились нулевые остатки и цены

Ну с нулевыми ценами понятно.
А что такое нулевые остатки? То есть предполагается, что вся номенклатура как она там есть в справочнике может присутствовать на каждом из складов? Какой в этом сокральный смысл? В 90% случаев набор номенклатуры обритающейся на каждом из складов довольно разный.

В любом случае ничего особо сложного в этом отчете нет.
Если группировку по номенклатуре сделать в строках, а по складам - в колонках, то даже симпатичненько может получиться (если только складов не слишком много).

> что задача программиста в том числе уметь найти оптимальное решение по-максимуму используя имеющиеся в т.ч. чужие наработки.

чужие проверять надо сверху донизу. на это тоже время надо. иногда сопоставимое с собственной писаниной

(63) Но оба почему-то делают отдельные запросы к шапке и к табличной части.

А как один засунуть? Сходу что не соображу.

Да вообще запрос в шапке возвращает одну строку. Ее так и гонять как выборку что ли?

(65) В топку такой конструктор. Ибо результат его работы не вписывается в актуальные версии БСП. А раз так, то чем он лучше встроенного в конфигуратор конструктора? Только наличием шаблона?

(69) Мне вот это сосем не нравится.
Шапка = Запрос.Выполнить().Выбрать();
ДанныеШапки = Шапка.Следующий();

(70) так-то у ТС УПП, так что шаблоны БСП для них неактуальны

>у ТС УПП

тогда накуа вообще вся эта затея с "конструкторами"

для обычных форм требований всего два - реквизит и экспортная функция. шаблон с авторегистрацией - добавить по вкусу

Может ТС нас разводит? Ему дали тестовое задание, а мы теперь ему решения предлагаем.

(71) ты что, это же стандарт от 1с во всех типовых

(74) Нет. Слово офицера. Я блин в коли веки, тут выполз в Интернете посидеть, да вот озадачили. Но я столько нового узнал. Спасибо.
Могу подписку притащить.

(10) Хм.. посмотрите в типовой отчет по отпускам или печать ведомости отпусков...  Цикли Если Истина ... ... прерва иначе выборка = запрос.выполнить; КонецЦикла

(75) Нихрена себе а в не 1С за это рукам бьют.
Линейкой.
Я вот наваял.
Функция ПолучитьШапку()
    Запрос = Новый Запрос;
    Запрос.Текст =
    "ВЫБРАТЬ
    |    РеализацияТоваровУслуг.Номер КАК Номер,
    |    РеализацияТоваровУслуг.Дата КАК Дата,
    |    РеализацияТоваровУслуг.Контрагент.НаименованиеПолное КАК Контрагент
    |ИЗ
    |    Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
    |ГДЕ
    |    РеализацияТоваровУслуг.Ссылка = &Док";
    
    Запрос.УстановитьПараметр("Док", СсылкаНаОбъект);
    Шапка = Запрос.Выполнить().Выбрать();
    ДанныеШапки = Шапка.Следующий();
    
    Возврат ДанныеШапки

КонецФункции    

Потом к ней пытаюсь обратится.

ДанныеШапки = ПолучитьШапку();
    НомерДок  = ДанныеШапки.Номер;
    ДатаДок = Формат(ДанныеШапки.Дата,"ДЛФ=DD");
    ОбластьЗаголовок.Параметры.ЗаголовокПредставление = "Расходная накладная № " + НомерДок + " от " + ДатаДок;
    ОбластьЗаголовок.Параметры.Контрагент = ДанныеШапки.Контрагент;
    ТабДок.Вывести(ОбластьЗаголовок);

И получаю облом.
Значение не является значением объектного типа (Номер)
НомерДок  = ДанныеШапки.Номер;

Обоих не брать :)

(79) Дык больше вариантов нету.

+79 чисто с практической стороны, ведь может быть такое, что в табличной части документа не будет указана ед.изм. в какой-нибудь строке. Тогда оба эти примера выведут на печать макеты без этих строк, т.к. левое соединение не сработает.

+81 а претенденты, явно видно, не умеет писать запросы без конструктора.

(82) Умение писать без конструктора - это уже почти сеньор

+82 в обоих случаях "РеализацияТоваровУслугТовары.Ссылка.Ссылка" - wtf.

Выгнать обоих на склад кладовщиками работать :)

(78) ДанныеШапки = Шапка.Следующий();
возвращает булево вообще-то :)

(78) Ты левй код написал. Следующий() возвращает булево

(82) Второй умеет, но ленится. Да и простой запрос быстрей мышкой наклацать.

(87) не умеет, по тексту запроса это выидно

(85) (86) Я догадаться. Вопрос как оно тама должно быть. В таблицу значений вы сами запретили выгружать однако.

(78) Вместо Возврат ДанныеШапки
напиши Возврат Шапка

(90) Дык это выборка будет. Потом опять. Шапка.Следующий(), но уже в основном коде.

(87) оба наклацали - ошибки детские.

Вы мне народ попроще, я полгода по другой специализации работал, плюс побили немного. Так что где-то туго на поворотах соображаю. Спасибо.

(92) Второй наклацал  - первый списал.

Интересно, те товарищи, которым было дадено задание наиписать ВПФ, мисту читают?
Вот будет прикольно если в эту ветку зайдут :)

Очевидно, что первый скопипастил код второго, но исправил некоторые косяки, типа сделал запрос к шапке вместо ПолучитьОбъект, вынес получение области макета за цикл. Даже, возможно, пытался сделать что-то (безуспешно, правда) с ужасным запросом к табличной части, судя по тому, что "выбрать" и "Левое соединение" маленькими буквами. Так что я за первого.

(69) Например, так:

ВЫБРАТЬ
  РеализацияТоваровУслугТовары.Ссылка КАК Накладная,
  РеализацияТоваровУслугТовары.Ссылка.Номер КАК Номер,
  РеализацияТоваровУслугТовары.Ссылка.Дата КАК Дата,
  РеализацияТоваровУслугТовары.Ссылка.Контрагент КАК Контрагент,
  РеализацияТоваровУслугТовары.Ссылка.Организация КАК Организация,
  РеализацияТоваровУслугТовары.НомерСтроки,
  РеализацияТоваровУслугТовары.Номенклатура,
  РеализацияТоваровУслугТовары.Количество,
  РеализацияТоваровУслугТовары.Цена,
  РеализацияТоваровУслугТовары.Сумма
ИЗ
  Документ.РеализацияТоваровУслуг.Товары КАК РеализацияТоваровУслугТовары
ИТОГИ
  МАКСИМУМ(Номер),
  МАКСИМУМ(Дата),
  МАКСИМУМ(Контрагент),
  МАКСИМУМ(Организация)
ПО
  Накладная

Потом делаем иерархическую выборку

  Шапка = Запрос.Выполнить().Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам, "Накладная");
  ПервыйДокумент = Истина;
  Пока Шапка.Следующий() Цикл
    Если Не ПервыйДокумент Тогда
              ТабличныйДокумент.ВывестиГоризонтальныйРазделительСтраниц();
    КонецЕсли;
    ПервыйДокумент = Ложь;
    //Выводим шапку;
    //Потом строки
    ОбходПоСтрокам = Шапка.Выбрать();
    Пока ОбходПоСтрокам.Следующий() Цикл
       //Выводим строки;
    КонецЦикла;
    //Выводим подвал;
  КонецЦикла;

(95) Второй точно, это мой племяшь. Под мной иногда вопросы задает.

(81) За такие запросы надо обеих по рукам линейкой

(8) я смотрю, тут уже ответили ))
Лично я бы оставил второго за то, что он получение таблицы товаров вынес отдельной функцией. И долго учил, учил, учил.

(91) Точней сказать запись выборки.

(100) кармически более правильно обучить )) А экономически - пожалуй, найти уже опытного.

У обеих затребовать объяснение зачем регулярно делать дефрагментацию индексов БД.
Исходя из ответов принять решение.

(97) тебе надо максимум по всем полям шапки делать, а их можеть быть под сотню

(98) так с этого надо было начинать
http://s1.funon.cc/img/orig/201407/12/53c0de1f41db6.jpg

(97) Я вот этого финта не понял. В чем фишка?

ПервыйДокумент = Истина;
  Пока Шапка.Следующий() Цикл
    Если Не ПервыйДокумент Тогда
              ТабличныйДокумент.ВывестиГоризонтальныйРазделительСтраниц();
    КонецЕсли;
    ПервыйДокумент = Ложь;

(0)  Чтобы принять решение кого из них оставить "в программистах" - нужно посмотреть, как они решают разные задачки.  Внешняя печ.форма - не показатель.

(51) я не фукал. они одинаковы

(87) >> Второй умеет

Судя по абсолютно детским и грубым ошибкам, я в этом сильно сомневаюсь.

Я бы брал первого. Даже если предположить, что он всё списал со второго. Он исправил явные грубейшие ошибки (типа получения объекта).

И повторюсь: Второй явно не понимает смысла того, что он делает. Сначала лепит запрос и выборку, а потом тянет сам объект..... Вот спрашивается нафуя? Либо откажись от выборки, либо не тяни объект.

PS Кстати не понимаю почему этот факт (получение объекта) ни у кого не вызывает возмущения. Как и то, что второй постоянно лепит неявные запросы к базе Док.Контрагент.НаименованиеПолное.
На сертификационных экзаменах на спеца (которые все тут считают бессмыслеными) за такое незачет ставят.
Или народ уже настолько привык хавнокодить, что просто не обращает на такие "мелочи" внимания?....

(106) Групповая печать документов.
Лучше, когда два документа печатаются на двух разных листа (через горизонтальный разделитель), чем на одном ))))

(106) В выборку может попасть не один документ, если печатаем не первый документ - надо его печатать на след.листе, для этого он выводит разделитель.
У него кстати фраза "ГДЕ" отсутствует, так что поосторожней с этим кодом, а то запустишь на печать все 10 000 документов реализации, ну или сколько там их у вас есть :)

(109) Согласен, с получением объекта это явно что-то не то.
Но блин, каждый раз все запросами оформлять тоже как-то, ну не знаю.
Я вот грешен, все через точку таскаю. Ну не тормозить и ладно, зато удобно. На больших объемах конечно себе такого не позволяю однако.

(105) Я беспристрастен, и вообще я админом устраивал. А оно вона как. Ну уйдет в другую контору, на крайняк на полигон прапором посажу.

(111) >> У него кстати фраза "ГДЕ"

У него пример на коленке в конструкторе слепленный и ни в коем случае не претендующий на законченность )))

А так да. Должно бытье ГДЕ РеализацияТоваровУслугТовары.Ссылка В (&МассивСсылок)

(114) Ну вот! Другое дело :)

(3) запастить попкорном и соискателей в банку, не?)

пригласить сразу 2х и устроить соревнование )))

(114) Я просто предупредил ТС-а, вдруг он не глядя "воткнет" твой запрос в ВПФ и напечатает ее. Обидеть никого не не хотел есичио :)

Обоих в сад.
1. Условие на .Ссылка.Ссылка
2. Соединение в запросах кривое (левое от справочника единицы измерения, превращенное условием во внутреннее)
3. Двойная точка.

(101) Ну все равно это набор данных будет, который в цикле перебирать или явно переходить надо.

(112) >> Я вот грешен, все через точку таскаю. Ну не тормозить и ладно, зато удобно

1С тоже этим грешит.
Но зачем самому себе гадить?
А потом все удивляются, что пользователи жалуются на тормоза этой вашей 1С.

(117) >> и устроить соревнование

отжимания, приседания, подтягивания, стрельба?...
Или сразу - кто лучше пол в серверной вымоет?

бери двух на по полЗП, через три месяца выживет сильнейший или один сразу свалит )

(122) По шахбоксу

кстати
РеализацияТоваровУслугТовары.Количество/ЕдиницыИзмерения.Коэффициент

нет проверки на 0 и НУЛЛ
теоритически может ошибку выбить

(116) (117) (122) Я это если чего за своего то по любому подпишушь, а так как на моей стороне куча тяжелого вооружения и миста - результат очевиден.
Шутка.

(123) Ну так вот три месяца прошло, никто не свалил. Один ленивый, другому некуда.

Самое главное, что вкуса нет. А это уже не исправить.

(125) Это кстати да. Косяк.

(127) ленивого оставляй

Я повторюсь(78), но меня реально заинтересовала, как такую хрень по 1С правильно написать?
Я вот наваял.

Функция ПолучитьШапку()
    Запрос = Новый Запрос;
    Запрос.Текст =
    "ВЫБРАТЬ
    |    РеализацияТоваровУслуг.Номер КАК Номер,
    |    РеализацияТоваровУслуг.Дата КАК Дата,
    |    РеализацияТоваровУслуг.Контрагент.НаименованиеПолное КАК Контрагент
    |ИЗ
    |    Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
    |ГДЕ
    |    РеализацияТоваровУслуг.Ссылка = &Док";
    
    Запрос.УстановитьПараметр("Док", СсылкаНаОбъект);
    Шапка = Запрос.Выполнить().Выбрать();
    ДанныеШапки = Шапка.Следующий();
    
    Возврат ДанныеШапки

КонецФункции    


Потом к ней пытаюсь обратится.

ДанныеШапки = ПолучитьШапку();
    НомерДок  = ДанныеШапки.Номер;
    ДатаДок = Формат(ДанныеШапки.Дата,"ДЛФ=DD");
    ОбластьЗаголовок.Параметры.ЗаголовокПредставление = "Расходная накладная № " + НомерДок + " от " + ДатаДок;
    ОбластьЗаголовок.Параметры.Контрагент = ДанныеШапки.Контрагент;
    ТабДок.Вывести(ОбластьЗаголовок);


И получаю облом.
Значение не является значением объектного типа (Номер)
НомерДок  = ДанныеШапки.Номер;

(128) Мыж тупые ремесленники.

(131) Тебе же объяснили уже 5 раз

(132) тогда в (0) супер офигительные специалисты. 1й- знает глобальные общие процедуры, а 2й - умеет пользоваться конструктором запросов

(120) Нет, это будет одна запись из выборки, перебирать ничего не надо, можно сразу читать реквизиты.

(133) Простите контуженого, не доходит. Ты на пальцах покажи.

(136) Напиши Возврат Шапка, вместо Возврат ДанныеШапки

(137)Может
Возврат  Шапка.Следующий();

Шапка это выборка же.

(136)

    Шапка = Запрос.Выполнить().Выбрать();
    Если Шапка.Следующий() тогда
        Возврат Шапка;
    Иначе
        Возврат Неопределено;
    конецесли;
    
Шапка.Следующий() - позиционирует указатель на первой строке (в данном случае)

(138) Если так напишешь опять получишь ошибку. Метод "Следующий" вернет булевское значение.
Шапка это действительно выборка, точней сказать указатель на текущую запись выборки.

(140)Ага, кажется начинает доходить Шапка это выборка(типа курсор как в БД), а метод Шапка.Следующий() установка на первую запись.
И на выходе у меня выборка с установкой на первую запись.
Я правильно понял?

(138) как совет - в отдельную процедуру выноси только текст запроса... т.е. назови функциию "ПолучитьТекстЗапрос()" и верни только текст, так код будет более читаемей и ошибок будет меньше

Вот типа по феншую.
Но теперь с итогами засада.
Функция ПолучитьШапку()
    Запрос = Новый Запрос;
    Запрос.Текст =
    "ВЫБРАТЬ
    |    РеализацияТоваровУслуг.Номер КАК Номер,
    |    РеализацияТоваровУслуг.Дата КАК Дата,
    |    РеализацияТоваровУслуг.Контрагент.НаименованиеПолное КАК Контрагент
    |ИЗ
    |    Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
    |ГДЕ
    |    РеализацияТоваровУслуг.Ссылка = &Док";
    
    Запрос.УстановитьПараметр("Док", СсылкаНаОбъект);
    Шапка = Запрос.Выполнить().Выбрать();
    ДанныеШапки = Шапка.Следующий();
    
    Возврат Шапка

КонецФункции    

Функция ПолучитьТовары()
    
    Запрос = Новый Запрос;
    Запрос.Текст =
    "ВЫБРАТЬ
    |    Товары.Номенклатура.Артикул КАК Артикул,
    |    Товары.Номенклатура.НаименованиеПолное КАК Товар,
    |    Товары.Номенклатура.ЕдиницаИзмеренияМест КАК ЕдиницаИзмеренияМест,
    |    Товары.Количество КАК Количество,
    |    Товары.ЕдиницаИзмерения КАК ЕдиницаИзмерения,
    |    Товары.Количество / Товары.Номенклатура.ЕдиницаИзмеренияМест.Коэффициент КАК Мест
    |ИЗ
    |    Документ.РеализацияТоваровУслуг.Товары КАК Товары
    |ГДЕ
    |    Товары.Ссылка.Ссылка = &Док";

    Запрос.УстановитьПараметр("Док", СсылкаНаОбъект);
    ДанныеТовара = Запрос.Выполнить().Выбрать();
    
    Возврат ДанныеТовара
КонецФункции    

// Внешняя функция печати
Функция Печать() Экспорт
    ТабДок = Новый ТабличныйДокумент;
    Макет = ПолучитьМакет("Макет");
    ОбластьЗаголовок   = Макет.ПолучитьОбласть("Заголовок");
    ДанныеШапки = ПолучитьШапку();
    НомерДок  = ДанныеШапки.Номер;
    ДатаДок = Формат(ДанныеШапки.Дата,"ДЛФ=DD");
    ОбластьЗаголовок.Параметры.ЗаголовокПредставление = "Расходная накладная № " + НомерДок + " от " + ДатаДок;
    ОбластьЗаголовок.Параметры.Контрагент = ДанныеШапки.Контрагент;
    ТабДок.Вывести(ОбластьЗаголовок);
    
    ОбластьЗаголовокТаблицы   = Макет.ПолучитьОбласть("ЗаголовокТаблицы");
    ТабДок.Вывести(ОбластьЗаголовокТаблицы);
    ОбластьСтрока   = Макет.ПолучитьОбласть("Строка");
    ДанныеНоменклатуры = ПолучитьТовары();
    нс = 1;
    Пока ДанныеНоменклатуры.Следующий() Цикл
            ОбластьСтрока.Параметры.Заполнить(ДанныеНоменклатуры);
            ОбластьСтрока.Параметры.нс = нс;
            Если  Окр(ДанныеНоменклатуры.Мест,0,0) <> ДанныеНоменклатуры.Мест тогда
                ОбластьСтрока.Параметры.Примечание = "Ящик неполный"
            КонецЕсли;
            ТабДок.Вывести(ОбластьСтрока);
            нс = нс + 1;
    КонецЦикла;    
    
    ОбластьИтого   = Макет.ПолучитьОбласть("Итого");
    //ОбластьИтого.Параметры.ИтогоМест = ДанныеНоменклатуры.Итог("Мест") ;
    //ОбластьИтого.Параметры.ИтогоКолво  = ДанныеНоменклатуры.Итог("Количество") ;
    ТабДок.Вывести(ОбластьИтого);


            
    Возврат ТабДок

КонецФункции // Печать()

Их я так понимаю теперь надо в запрос пихать?

(141) Да, да все правильно, только все же не вся выборка, а одна запись из этой выборки.

(144) Ага все таки не классический курс БД. Ты смотри как интересно 1с это реализовали.

(145) Если хочешь с итогами - сделай как в (97) написано, прямо в функции печать, без "ПолучитьШапку()" и "ПолучитьТовары()"

вот текст сгенеренный стандартным конструктором печати:
Процедура Печать(ТабДок, Ссылка) Экспорт
    //{{_КОНСТРУКТОР_ПЕЧАТИ(Печать)
    Макет = Документы.ПоступлениеТоваровУслуг.ПолучитьМакет("Печать");
    Запрос = Новый Запрос;
    Запрос.Текст =
    "ВЫБРАТЬ
    |    ПоступлениеТоваровУслуг.Валюта,
    |    ПоступлениеТоваровУслуг.Дата,
    |    ПоступлениеТоваровУслуг.Контрагент,
    |    ПоступлениеТоваровУслуг.Номер,
    |    ПоступлениеТоваровУслуг.Склад,
    |    ПоступлениеТоваровУслуг.Товары.(
    |        НомерСтроки,
    |        Товар,
    |        ЕдиницаИзмерения,
    |        Количество,
    |        Цена,
    |        Сумма
    |    )
    |ИЗ
    |    Документ.ПоступлениеТоваровУслуг КАК ПоступлениеТоваровУслуг
    |ГДЕ
    |    ПоступлениеТоваровУслуг.Ссылка В (&Ссылка)";
    Запрос.Параметры.Вставить("Ссылка", Ссылка);
    Выборка = Запрос.Выполнить().Выбрать();

    ОбластьЗаголовок = Макет.ПолучитьОбласть("Заголовок");
    Шапка = Макет.ПолучитьОбласть("Шапка");
    ОбластьТоварыШапка = Макет.ПолучитьОбласть("ТоварыШапка");
    ОбластьТовары = Макет.ПолучитьОбласть("Товары");
    ТабДок.Очистить();

    ВставлятьРазделительСтраниц = Ложь;
    Пока Выборка.Следующий() Цикл
        Если ВставлятьРазделительСтраниц Тогда
            ТабДок.ВывестиГоризонтальныйРазделительСтраниц();
        КонецЕсли;

        ТабДок.Вывести(ОбластьЗаголовок);

        Шапка.Параметры.Заполнить(Выборка);
        ТабДок.Вывести(Шапка, Выборка.Уровень());

        ТабДок.Вывести(ОбластьТоварыШапка);
        ВыборкаТовары = Выборка.Товары.Выбрать();
        Пока ВыборкаТовары.Следующий() Цикл
            ОбластьТовары.Параметры.Заполнить(ВыборкаТовары);
            ТабДок.Вывести(ОбластьТовары, ВыборкаТовары.Уровень());
        КонецЦикла;

        ВставлятьРазделительСтраниц = Истина;
    КонецЦикла;
    //}}
КонецПроцедуры

от себя ниче не добавлял, только мышкой поклацал

(146) Да вроде все хорошо. Но вот
ИТОГИ
  МАКСИМУМ(Номер),
  МАКСИМУМ(Дата),
  МАКСИМУМ(Контрагент),
  МАКСИМУМ(Организация)
ПО

Это сейчас запрос мелкий, а что в большом будет. Агрегатные функции как никак, тож ресурсы требуют.

Меня всегда учили лучше несколько небольших простых запросов, чем один большой комбайн.

(148) Можно и без агрегатов сделать - отсортировать по номеру документа и самому отслеживать изменение номера, если изменился значит выводим разделитель и печатаем шапку иначе печатаем ТЧ документа. Ну соответственно при печати первого дока разделитель выводить не тнужно.

(84) "Выгнать обоих на склад кладовщиками работать :)"
Склады - это отстойники ресурсов, материальных и человеческих...

(147) А прикольно, вложенный запрос.

(147) это хороший код или плохой?

>Меня всегда учили лучше несколько небольших простых запросов, чем один большой комбайн.

тогда надо думать об их согласованности

(149) А можно открыть типовую и посмотреть как делается там

(151) Попробуй в конфигураторе правой кнопкой мыши нажать на каком-нить документе и выбрать конструкторы-конструктор печати и потом далее, далее, далее....

запрос из (0) надо заюзать в Как быстро найти неоптимальности в запросе (волшебная консоль запросов)

(154) Можно и типовую. Вот тока в учебных целях лучше как попроще.

(154) В типовых как только не делается. На любой вкус пример найти думается можно.
(155) Я в курсе где конструктор, прикольно он запрос то делает.

(158) кого выгнал-то?

(0) оба плохие

(157) Но при  этом ты начинаешь за тему "как правильно"

(161) Как правильно - это спорный вопрос. В (149) я на правоту ни разу не претендую. Этот способ ничуть не хуже типового, где данные для печати пихают сначала в структуру, причем отдельно результат запроса по шапке, отдельно по строкам, а потом обходя шапки всех документов "выдирают" строки текущего дока из другой выборки (а точнее из тз в которую выкатывается выборка).
Опять же я не говорю что какой-то способ лучше, а какой-то хуже, они просто разные, вот тока в типовой мозги сломаешь пока докопаешься где надо исправить, чтобы что-то добавить/убавить.

Все надо заканчивать. Вот такую я хрень родил.
Но работает зараза.

Функция ПолучитьШапку()
    Запрос = Новый Запрос;
    Запрос.Текст =
    "ВЫБРАТЬ
    |    РеализацияТоваровУслуг.Номер КАК Номер,
    |    РеализацияТоваровУслуг.Дата КАК Дата,
    |    РеализацияТоваровУслуг.Контрагент.НаименованиеПолное КАК Контрагент
    |ИЗ
    |    Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
    |ГДЕ
    |    РеализацияТоваровУслуг.Ссылка = &Док";
    
    Запрос.УстановитьПараметр("Док", СсылкаНаОбъект);
    Шапка = Запрос.Выполнить().Выбрать();
    Шапка.Следующий();
    
    Возврат Шапка

КонецФункции    

Функция ПолучитьТовары()
    
    Запрос = Новый Запрос;
    Запрос.Текст =
    "ВЫБРАТЬ
    |    Товары.Номенклатура.Артикул КАК Артикул,
    |    Товары.Номенклатура.НаименованиеПолное КАК Товар,
    |    Товары.Номенклатура.ЕдиницаИзмеренияМест КАК ЕдиницаИзмеренияМест,
    |    Товары.Количество КАК Количество,
    |    Товары.ЕдиницаИзмерения КАК ЕдиницаИзмерения,
    |    Товары.Количество / Товары.Номенклатура.ЕдиницаИзмеренияМест.Коэффициент КАК Мест
    |ИЗ
    |    Документ.РеализацияТоваровУслуг.Товары КАК Товары
    |ГДЕ
    |    Товары.Ссылка.Ссылка = &Док
    |ИТОГИ
    |    СУММА(Количество),
    |    СУММА(Мест)
    |ПО
    |    Товары.Ссылка";

    Запрос.УстановитьПараметр("Док", СсылкаНаОбъект);
    ДанныеТовара = Запрос.Выполнить().Выбрать();
    
    Возврат ДанныеТовара
КонецФункции    

// Внешняя функция печати
Функция Печать() Экспорт
    ТабДок = Новый ТабличныйДокумент;
    Макет = ПолучитьМакет("Макет");
    ОбластьЗаголовок   = Макет.ПолучитьОбласть("Заголовок");
    ДанныеШапки = ПолучитьШапку();
    НомерДок  = ДанныеШапки.Номер;
    ДатаДок = Формат(ДанныеШапки.Дата,"ДЛФ=DD");
    ОбластьЗаголовок.Параметры.ЗаголовокПредставление = "Расходная накладная № " + НомерДок + " от " + ДатаДок;
    ОбластьЗаголовок.Параметры.Контрагент = ДанныеШапки.Контрагент;
    ТабДок.Вывести(ОбластьЗаголовок);
    
    ОбластьЗаголовокТаблицы   = Макет.ПолучитьОбласть("ЗаголовокТаблицы");
    ТабДок.Вывести(ОбластьЗаголовокТаблицы);
    ОбластьСтрока   = Макет.ПолучитьОбласть("Строка");
    ДанныеНоменклатуры = ПолучитьТовары();
    нс = 0;
    Пока ДанныеНоменклатуры.Следующий() Цикл
            Если нс = 0 Тогда
                ИтогоМест = ДанныеНоменклатуры.Мест;
                ИтогоКолво = ДанныеНоменклатуры.Количество;
            Иначе    
                ОбластьСтрока.Параметры.Заполнить(ДанныеНоменклатуры);
                ОбластьСтрока.Параметры.нс = нс;
                Если  Окр(ДанныеНоменклатуры.Мест,0,0) <> ДанныеНоменклатуры.Мест тогда
                    ОбластьСтрока.Параметры.Примечание = "Ящик неполный"
                КонецЕсли;
                ТабДок.Вывести(ОбластьСтрока);
            КонецЕсли;
            нс = нс + 1;
    КонецЦикла;    
    
    ОбластьИтого   = Макет.ПолучитьОбласть("Итого");
    ОбластьИтого.Параметры.ИтогоМест =  ИтогоМест;
    ОбластьИтого.Параметры.ИтогоКолво  = ИтогоКолво ;
    ТабДок.Вывести(ОбластьИтого);

                
    Возврат ТабДок

КонецФункции // Печать()

(163) Это п..ц, товарищи

(164) я ж говорю - уволить всех, ...и расстрелять

(164) Не ругайся, лучше наставь человека на путь истинный.

(165) http://kotomatrix.ru/images/lolz/2009/03/12/UH.jpg

(164) Ну это мне скучно.
(165) Да не вопрос, я тебе хоть щас пулемет выдам.
(166) Я к вам попозже загляну. Хорошо мозги прочищаете.

(168) >>Я к вам попозже загляну.
http://risovach.ru/upload/2014/05/mem/nu-ty-eto-zovi-esli-chto_51215312_orig_.jpeg

(148) Не нравятся агрегатные функции, сделай пакетный запрос, который в первом запросе будет получать данные шапки, а во втором - данные табличных частей.
Вариантов много. В любом случае два запроса - это менее оптимально.

(170) Дык я не спорю. Я согласен.

Вот этот код особенно не нравится
   нс = 0;
    Пока ДанныеНоменклатуры.Следующий() Цикл
            Если нс = 0 Тогда
                ИтогоМест = ДанныеНоменклатуры.Мест;
                ИтогоКолво = ДанныеНоменклатуры.Количество;
            Иначе    

Если уж делаешь запрос с группирвокой, то лучше и выбирать по группировкам

(172) ему лишь бы работало. он же ремеслом это считает.
так что пофиг

(172) Ну прикольно же получилось.
(173) Ну да, обычная работа. Не типовые же пишут.

(173) Вообоще то тема изначальная про ОЦЕНИТЕ

Иначе и код претендентов работал

(175) да это его "вояния"... делать видимо нефиг, решил что-то переписать

Очень интересная тема получилась. Мне понравилось, очень много нового узнал. Мозги прочистил. Спасибо большое.
Сейчас будет у нас небольшой отдых, я еще чего там найду. Приду научите уму разуму.

(177) Не что-то, а правильно. По рекомендации форума. Но да, занесло что-то.

(178) книжку лучше почитай. Карлсона, например.

(179) это не правильно, а на "отстань"

(181) Дык я и говорю, занесло меня.

http://cs9.pikabu.ru/post_img/2016/10/18/7/1476791738124916710.png

(163) Тут еще есть что оптимизировать и рефакторить, но для первого раза уже вполне достаточно. Можно остановиться, перевести дух, осмыслить.

ГДЕ
    |    Товары.Ссылка.Ссылка = &Док


однозначно прямо сейчас заменить на

ГДЕ
    |    Товары.Ссылка = &Док

А потом, по желанию, поразбираться с итогами в запросе и обходом их в выборке, пакетными запросами, в идеале - как все это в будущем завернуть на массовую печать.

Все понятно кроме одного! Как ТС, сам ничего толком не умея, инспектирует студентов???

(185) типа, как в анекдоте: "знал бы за что...", не?)