БП 2.0: Вытащить номенклатуру без спецификации

1С v8

БП 2.0: Вытащить номенклатуру без спецификации - помогите с запросом

18.11.16

✎

23:10

Всем хороших выходных.

Помогите с тупым запросом (туплю не первый день :))) )

конфигурация типовая БП 2.0.

Справочник СпецификацииНоменклатуры подчинен Справочнику Номенклатура.

Как вытащить выборку элементов Номенклатуры, у которых нет элементов подчиненного справочника СпецификацииНоменклатуры???

1 kubik_live

18.11.16

✎

23:13

Выборку с элементами, содержащими Спецификацию, получается вытащить, а без Спецификации что-то не получается.

2 smartu

18.11.16

✎

23:32

выбираешь всю номенклатуру, потом выбираешь номенклатуру со спецификациями .. и соединяешь две таблицы

3 smartu

18.11.16

✎

23:50

ВЫБРАТЬ
    Номенклатура.Ссылка КАК Номенклатура
ПОМЕСТИТЬ вт_ВсяНоменклатура
ИЗ
    Справочник.Номенклатура КАК Номенклатура
ГДЕ
    Номенклатура.ЭтоГруппа = ЛОЖЬ
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    СпецификацииНоменклатурыВыходныеИзделия.Номенклатура КАК Номенклатура
ПОМЕСТИТЬ вт_ГотоваяПродукция
ИЗ
    Справочник.СпецификацииНоменклатуры.ВыходныеИзделия КАК СпецификацииНоменклатурыВыходныеИзделия

СГРУППИРОВАТЬ ПО
    СпецификацииНоменклатурыВыходныеИзделия.Номенклатура
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    вт_ВсяНоменклатура.Номенклатура
ИЗ
    вт_ВсяНоменклатура КАК вт_ВсяНоменклатура
        ЛЕВОЕ СОЕДИНЕНИЕ вт_ГотоваяПродукция КАК вт_ГотоваяПродукция
        ПО вт_ВсяНоменклатура.Номенклатура = вт_ГотоваяПродукция.Номенклатура
ГДЕ
    НЕ вт_ГотоваяПродукция.Номенклатура ЕСТЬ NULL

СГРУППИРОВАТЬ ПО
    вт_ВсяНоменклатура.Номенклатура

4 smartu

18.11.16

✎

23:51

на упп попробовал, может подойдет к бп

5 kubik_live

18.11.16

✎

23:55

Спасибо, щас наваяю. Отпишусь по результату.

6 kubik_live

19.11.16

✎

00:18

(4) СПАСИБО!!!

Получилось:

ВЫБРАТЬ
    Номенклатура.Ссылка КАК Номенклатура
ПОМЕСТИТЬ ВТ_Номенклатура
ИЗ
    Справочник.Номенклатура КАК Номенклатура
ГДЕ
    Номенклатура.ЭтоГруппа = ЛОЖЬ
    И Номенклатура.Ссылка В ИЕРАРХИИ(&ВыбНоменклатура)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    СпецификацииНоменклатуры.Владелец КАК Номенклатура
ПОМЕСТИТЬ ВТ_Спецификация
ИЗ
    Справочник.СпецификацииНоменклатуры КАК СпецификацииНоменклатуры

СГРУППИРОВАТЬ ПО
    СпецификацииНоменклатуры.Владелец
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ВТ_Номенклатура.Номенклатура
ИЗ
    ВТ_Номенклатура КАК ВТ_Номенклатура
        ЛЕВОЕ СОЕДИНЕНИЕ ВТ_Спецификация КАК ВТ_Спецификация
        ПО ВТ_Номенклатура.Номенклатура = ВТ_Спецификация.Номенклатура
ГДЕ
    ВТ_Спецификация.Номенклатура ЕСТЬ NULL

СГРУППИРОВАТЬ ПО
    ВТ_Номенклатура.Номенклатура