Добрый день. Необходимо вывести отчет с суммой и суммой НДС документа корректировки реализации документа реализации, для более удобного сравнения бухгалтеру. Имею такой запрос:

"ВЫБРАТЬ
    КорректировкаРеализации.Ссылка КАК Ссылка,
    СУММА(КорректировкаРеализацииТовары.Сумма) КАК Сумма,
    СУММА(КорректировкаРеализацииТовары.СуммаНДС) КАК СуммаНДС,
    КорректировкаРеализации.ДокументРеализации КАК ДокументРеализацииСсылка,
    КорректировкаРеализации.ДокументРеализации.Сумма КАК ДокументРеализацииСумма,
    КорректировкаРеализации.ДокументРеализации.СуммаНДС КАК ДокументРеализацииСуммаНДС
ИЗ
    Документ.КорректировкаРеализации.Товары КАК КорректировкаРеализацииТовары
        ЛЕВОЕ СОЕДИНЕНИЕ Документ.КорректировкаРеализации КАК КорректировкаРеализации
        ПО (КорректировкаРеализацииТовары.Ссылка = КорректировкаРеализации.Ссылка)
ГДЕ
    КорректировкаРеализации.Дата > &Дата

СГРУППИРОВАТЬ ПО
    КорректировкаРеализации.Ссылка,
    КорректировкаРеализации.ДокументРеализации.Сумма,
    КорректировкаРеализации.ДокументРеализации.СуммаНДС,
    КорректировкаРеализации.ДокументРеализации"

Но в итоге заполняется все, кроме суммы и НДС реализации (основания). Если на затруднит, подскажите что не так?

Зачем такая структура запроса?
Соединяешь таблицу документа с таблицей его табличной части, а данные выбираешь через две точки?

Что покажет запрос:

ВЫБРАТЬ

    ДокументРеализации КАК ДокументРеализацииСсылка,
    ДокументРеализации.Сумма КАК ДокументРеализацииСумма,
    ДокументРеализации.СуммаНДС КАК ДокументРеализацииСуммаНДС
ИЗ
    Документ.РеализацияТоваров КАК ДокументРеализации

ГДЕ
    ДокументРеализации.Ссылка = &Ссылка


?

В твоем запросе поле ДокументРеализацииСсылка заполняется? Там нужный документ?

(1) ну уж

В документе реализации нет такого реквизита СуммаНДС.

Вам ли не знать.

(2) Ну если у него запрос выполняется и все данные, кроме этих, выводятся, значит есть. Другое дело, что он может быть пустой, как и "Сумма".

(3) тогда это не факт

ИЗ
    Документ.РеализацияТоваров КАК ДокументРеализации

Да, какой именно там тип документа я не знаю. Но чтобы гадать дальше, нужна хоть какая-то обратная связь.

(0) В КорректировкаРеализации.ДокументРеализации много разных типов документов и не во всех есть реквизиты Сумма и СуммаНДС. В т.ч. в документе РеализацияТоваровУслуг эти реквизиты содержатся только в табчасти. (но есть СуммаДокумента).

Запрос подойдет только если в КорректировкаРеализации.ДокументРеализации содержится РеализацияТоваровУслуг, для других типов документов нужно дописывать  
ВЫБРАТЬ
    ВложенныйЗапрос.Ссылка,
    ВложенныйЗапрос.Сумма,
    ВложенныйЗапрос.СуммаНДС,
    ВложенныйЗапрос1.Ссылка1 КАК ДокументРеализацииСсылка,
    ВложенныйЗапрос1.Сумма1 КАК ДокументРеализацииСумма,
    ВложенныйЗапрос1.СуммаНДС1 КАК ДокументРеализацииСуммаНДС
ИЗ
    (ВЫБРАТЬ
        КорректировкаРеализацииТовары.Ссылка КАК Ссылка,
        СУММА(КорректировкаРеализацииТовары.Сумма) КАК Сумма,
        СУММА(КорректировкаРеализацииТовары.СуммаНДС) КАК СуммаНДС
    ИЗ
        Документ.КорректировкаРеализации.Товары КАК КорректировкаРеализацииТовары
    
    СГРУППИРОВАТЬ ПО
        КорректировкаРеализацииТовары.Ссылка) КАК ВложенныйЗапрос
        ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
            РеализацияТоваровУслугТовары.Ссылка КАК Ссылка1,
            СУММА(РеализацияТоваровУслугТовары.Сумма) КАК Сумма1,
            СУММА(РеализацияТоваровУслугТовары.СуммаНДС) КАК СуммаНДС1
        ИЗ
            Документ.РеализацияТоваровУслуг.Товары КАК РеализацияТоваровУслугТовары
        
        СГРУППИРОВАТЬ ПО
            РеализацияТоваровУслугТовары.Ссылка) КАК ВложенныйЗапрос1
        ПО ВложенныйЗапрос.Ссылка.ДокументРеализации.Ссылка = ВложенныйЗапрос1.Ссылка1
ГДЕ
    ВложенныйЗапрос.Ссылка.Дата > &Дата

Либо, но сумма НДС только если в КорректировкаРеализации.ДокументРеализации основание СчетФактураВыданный, для остальных типов документов нужно дописать отображение сумм НДС
ВЫБРАТЬ
    КорректировкаРеализацииТовары.Ссылка,
    СУММА(КорректировкаРеализацииТовары.Сумма) КАК Сумма,
    СУММА(КорректировкаРеализацииТовары.СуммаНДС) КАК СуммаНДС,
    КорректировкаРеализацииТовары.Ссылка.ДокументРеализации.Ссылка,
    КорректировкаРеализацииТовары.Ссылка.ДокументРеализации.СуммаДокумента,
    ВЫБОР
        КОГДА КорректировкаРеализацииТовары.Ссылка.ДокументРеализации.Ссылка ССЫЛКА Документ.СчетФактураВыданный
            ТОГДА КорректировкаРеализацииТовары.Ссылка.ДокументРеализации.СуммаНДС
        ИНАЧЕ 0
    КОНЕЦ КАК СФСуммаНДС
ИЗ
    Документ.КорректировкаРеализации.Товары КАК КорректировкаРеализацииТовары
ГДЕ
    КорректировкаРеализацииТовары.Ссылка.Дата > &Дата

СГРУППИРОВАТЬ ПО
    КорректировкаРеализацииТовары.Ссылка,
    ВЫБОР
        КОГДА КорректировкаРеализацииТовары.Ссылка.ДокументРеализации.Ссылка ССЫЛКА Документ.СчетФактураВыданный
            ТОГДА КорректировкаРеализацииТовары.Ссылка.ДокументРеализации.СуммаНДС
        ИНАЧЕ 0
    КОНЕЦ,
    ВЫБОР
        КОГДА КорректировкаРеализацииТовары.Ссылка.ДокументРеализации.Ссылка ССЫЛКА Документ.СчетФактураВыданный
            ТОГДА КорректировкаРеализацииТовары.Ссылка.ДокументРеализации.СуммаНДС
        ИНАЧЕ 0
    КОНЕЦ

(6) Спасибо Вам большое! Мой низки поклон Марии.
Ну и всем остальным тоже, за активное участие!

Еще не разобрался с запросами и закидонами информационной базы. Вообще странно, при запросе поля эти есть, в документе все есть, но надо объединять вложенными запросами, т.е. передается только сумма документа и ссылка на него. Зачем все эти лишние поля....
Отработал запрос:
ВЫБРАТЬ
    ВложенныйЗапрос.Ссылка,
    ВложенныйЗапрос.Сумма,
    ВложенныйЗапрос.СуммаНДС,
    ВложенныйЗапрос1.Ссылка1 КАК ДокументРеализацииСсылка,
    ВложенныйЗапрос1.Сумма1 КАК ДокументРеализацииСумма,
    ВложенныйЗапрос1.СуммаНДС1 КАК ДокументРеализацииСуммаНДС
ИЗ
    (ВЫБРАТЬ
        КорректировкаРеализацииТовары.Ссылка КАК Ссылка,
        СУММА(КорректировкаРеализацииТовары.Сумма) КАК Сумма,
        СУММА(КорректировкаРеализацииТовары.СуммаНДС) КАК СуммаНДС
    ИЗ
        Документ.КорректировкаРеализации.Товары КАК КорректировкаРеализацииТовары
    
    СГРУППИРОВАТЬ ПО
        КорректировкаРеализацииТовары.Ссылка) КАК ВложенныйЗапрос
        ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
            РеализацияТоваровУслугТовары.Ссылка КАК Ссылка1,
            СУММА(РеализацияТоваровУслугТовары.Сумма) КАК Сумма1,
            СУММА(РеализацияТоваровУслугТовары.СуммаНДС) КАК СуммаНДС1
        ИЗ
            Документ.РеализацияТоваровУслуг.Товары КАК РеализацияТоваровУслугТовары
        
        СГРУППИРОВАТЬ ПО
            РеализацияТоваровУслугТовары.Ссылка) КАК ВложенныйЗапрос1
        ПО ВложенныйЗапрос.Ссылка.ДокументРеализации.Ссылка = ВложенныйЗапрос1.Ссылка1
ГДЕ
    ВложенныйЗапрос.Ссылка.Дата > &Дата

Во втором запросе сумма НДС не заполнилась.
Ну хотьь теперь вложенные запросы понял как объединять ))

(7) Далее для УТ 10.3
У документа КорректировкаРеализации Реквизит ДокументРеализации содержит следующие типы документов:
ВозвратТоваровПоставщикуИзНТТ,
КорректировкаРеализации,
ОтражениеРеализацииТоваровИУслугНДС,
ОтчетКомитентуОПродажах,
СчетФактураВыданный,
ДокументРасчетовСКонтрагентом,
ВозвратТоваровПоставщику,
ОтчетКомиссионераОПродажах,
РеализацияТоваровУслуг.
Реквизиты Сумма и СуммаНДС есть только у СчетФактураВыданный. У остальных сумма и суммаНДС содержатся только в табчасти. (для этого и нужен был вложенный запрос, что бы получить итоговую сумму по документу)
У всех документов есть реквизит СуммаДокумента (это во втором варианте запроса использовано. Но что бы заполнить Суммы НДС для остальных типов документов кроме СчетФактураВыданный нужно дописать запрос.)