ВЫБОР
    КОГДА ВТ.ЕдиницаХранения = &ЕдиницаХранения ТОГДА ВТ.Количество
    ИНАЧЕ ВЫБОР
              КОГДА ВТ.ВесШтуки = 0 ТОГДА ВТ.ВесПогонногоМетра * ВТ.Количество/1000
              ИНАЧЕ ВТ.ВесШтуки * ВТ.Количество/1000
    КОНЕЦ    
КОНЕЦ    


Неверные параметры "*"
ИНАЧЕ <<?>> ВТ.ВесШтуки * ВТ.Количество/1000

ВТ.ВесШтуки - не числовое значение, возможно NULL, весь запрос не видно сложно сказать. Откуда ВТ берется?
Попробуй так
ВЫБОР
    КОГДА ВТ.ЕдиницаХранения = &ЕдиницаХранения ТОГДА ВТ.Количество
    ИНАЧЕ ВЫБОР
              КОГДА ЕстьNULL(ВТ.ВесШтуки,0) = 0 ТОГДА ВТ.ВесПогонногоМетра * ВТ.Количество/1000
              ИНАЧЕ ЕстьNULL(ВТ.ВесШтуки,0) * ВТ.Количество/1000
    КОНЕЦ    
КОНЕЦ

Значение числовое предыдущем пакете использовал функцию ЕСТЬNULL

(0) это выражение в какой секции запроса

Ну выведи в выборку отдельно поля ВТ.ВесШтуки и  ВТ.Количество, и смотри что там

+ здесь можно сокращенную форму ВЫБОР использовать:
ВЫБОР
КОГДА <Условие1> ТОГДА ...
КОГДА <Условие2>  ТОГДА ...
ИНАЧЕ ...
КОНЕЦ

(0). Как формируется ВТ?

Упрощенный не работает ошибку выдает


ВЫБОР
КОГДА ВТ.ЕдиницаХранения <> &ЕдиницаХранения
        ТОГДА ВЫБОР
                  КОГДА ВТ.ВесШтуки = 0
                      ТОГДА 1
                      ИНАЧЕ 0
                КОНЕЦ    
        ИНАЧЕ  ВТ.Количество
КОНЕЦ


Вот так без ошибок

Операциями умн дел сум раз выдает ошибку

(9) весь запрос в студию


ВЫБРАТЬ РАЗРЕШЕННЫЕ
    Таблица.Регистратор КАК Регистратор,
    Таблица.ПериодСекунда КАК ПериодСекунда,
    Таблица.ПериодДень КАК ПериодДень,
    Таблица.ПериодНеделя КАК ПериодНеделя,
    Таблица.ПериодДекада КАК ПериодДекада,
    Таблица.ПериодМесяц КАК ПериодМесяц,
    Таблица.ПериодКвартал КАК ПериодКвартал,
    Таблица.ПериодПолугодие КАК ПериодПолугодие,
    Таблица.ПериодГод КАК ПериодГод,
    СУММА(Таблица.Количество) КАК Количество,
    ВЫБОР
        КОГДА &ДанныеОтчета = 1
            ТОГДА СУММА(Таблица.Выручка)
        КОГДА &ДанныеОтчета = 3
            ТОГДА СУММА(Таблица.ВыручкаРегл)
        ИНАЧЕ СУММА(Таблица.ВыручкаБезНДС)
    КОНЕЦ КАК Выручка,
    СУММА(Таблица.ВыручкаБезНДС) КАК ВыручкаБезНДС,
    СУММА(Таблица.Выручка) - СУММА(Таблица.ВыручкаБезНДС) КАК ВыручкаНДС,
    ВЫБОР
        КОГДА &ДанныеОтчета = 1
            ТОГДА СУММА(Таблица.СуммаРучнойСкидкиОборот)
        ИНАЧЕ 0
    КОНЕЦ КАК СуммаРучнойСкидки,
    ВЫБОР
        КОГДА &ДанныеОтчета = 1
            ТОГДА СУММА(Таблица.СуммаАвтоматическойСкидкиОборот)
        ИНАЧЕ 0
    КОНЕЦ КАК СуммаАвтоматическойСкидки,
    ВЫБОР
        КОГДА &ДанныеОтчета = 1
            ТОГДА СУММА(Таблица.СуммаРучнойСкидкиОборот)
        ИНАЧЕ 0
    КОНЕЦ + ВЫБОР
        КОГДА &ДанныеОтчета = 1
            ТОГДА СУММА(Таблица.СуммаАвтоматическойСкидкиОборот)
        ИНАЧЕ 0
    КОНЕЦ КАК ВсегоСкидок,
    ВЫБОР
        КОГДА &ДанныеОтчета = 1
            ТОГДА СУММА(Таблица.Себестоимость)
        КОГДА &ДанныеОтчета = 3
            ТОГДА СУММА(Таблица.СебестоимостьРегл)
        ИНАЧЕ СУММА(Таблица.СебестоимостьБезНДС)
    КОНЕЦ КАК Себестоимость,
    ВЫБОР
        КОГДА &ДанныеОтчета = 1
            ТОГДА СУММА(Таблица.Себестоимость) - СУММА(Таблица.СебестоимостьБезНДС)
        КОГДА &ДанныеОтчета = 3
            ТОГДА СУММА(Таблица.СебестоимостьРегл)
        ИНАЧЕ СУММА(Таблица.СебестоимостьБезНДС)
    КОНЕЦ КАК СебестоимостьНДС,
    ВЫБОР
        КОГДА &ДанныеОтчета = 1
            ТОГДА СУММА(Таблица.ДопРасходы)
        КОГДА &ДанныеОтчета = 3
            ТОГДА 0
        ИНАЧЕ СУММА(Таблица.ДопРасходыБезНДС)
    КОНЕЦ КАК ДопРасходы,
    ВЫБОР
        КОГДА &ДанныеОтчета = 1
            ТОГДА СУММА(Таблица.Выручка) - СУММА(Таблица.Себестоимость) - СУММА(Таблица.ДопРасходы)
        КОГДА &ДанныеОтчета = 3
            ТОГДА СУММА(Таблица.ВыручкаРегл) - СУММА(Таблица.СебестоимостьРегл)
        ИНАЧЕ СУММА(Таблица.ВыручкаБезНДС) - СУММА(Таблица.СебестоимостьБезНДС) - СУММА(Таблица.ДопРасходыБезНДС)
    КОНЕЦ КАК ВаловаяПрибыль,
    ВЫБОР
        КОГДА &ДанныеОтчета = 1
            ТОГДА ВЫРАЗИТЬ(ВЫБОР
                        КОГДА СУММА(Таблица.Выручка) <> 0
                            ТОГДА (СУММА(Таблица.Выручка) - СУММА(Таблица.Себестоимость) - СУММА(Таблица.ДопРасходы)) / СУММА(Таблица.Выручка)
                        ИНАЧЕ 0
                    КОНЕЦ * 100 КАК ЧИСЛО(15, 2))
        КОГДА &ДанныеОтчета = 3
            ТОГДА ВЫРАЗИТЬ(ВЫБОР
                        КОГДА СУММА(Таблица.ВыручкаРегл) <> 0
                            ТОГДА (СУММА(Таблица.ВыручкаРегл) - СУММА(Таблица.СебестоимостьРегл)) / СУММА(Таблица.ВыручкаРегл)
                        ИНАЧЕ 0
                    КОНЕЦ * 100 КАК ЧИСЛО(15, 2))
        ИНАЧЕ ВЫРАЗИТЬ(ВЫБОР
                    КОГДА СУММА(Таблица.ВыручкаБезНДС) <> 0
                        ТОГДА (СУММА(Таблица.ВыручкаБезНДС) - СУММА(Таблица.СебестоимостьБезНДС) - СУММА(Таблица.ДопРасходыБезНДС)) / СУММА(Таблица.ВыручкаБезНДС)
                    ИНАЧЕ 0
                КОНЕЦ * 100 КАК ЧИСЛО(15, 2))
    КОНЕЦ КАК Рентабельность,
    ВЫБОР
        КОГДА Таблица.Партнер = ЗНАЧЕНИЕ(Справочник.Партнеры.НашеПредприятие)
            ТОГДА ИСТИНА
        ИНАЧЕ ЛОЖЬ
    КОНЕЦ КАК ПродажиМеждуОрганизациями,
    Таблица.Номенклатура КАК Номенклатура,
    Таблица.Номенклатура.ЕдиницаИзмерения КАК ЕдиницаХранения,
    Таблица.Номенклатура.ЕдиницаДляОтчетов КАК ЕдиницаДляОтчетов,
    Таблица.Номенклатура.КоэффициентЕдиницыДляОтчетов КАК КоэффициентЕдиницыДляОтчетов,
    Таблица.Номенклатура.ГруппаАналитическогоУчета КАК ГруппаАналитическогоУчета,
    Таблица.Характеристика КАК Характеристика,
    Таблица.Организация КАК Организация,
    Таблица.Продавец КАК Продавец,
    Таблица.Партнер КАК Партнер,
    Таблица.ЗаказКлиента КАК ЗаказКлиента,
    Таблица.Подразделение КАК Подразделение,
    Таблица.Склад КАК Склад,
    Таблица.Контрагент КАК Контрагент,
    Таблица.Покупатель КАК Покупатель,
    Таблица.Поставщик КАК Поставщик,
    Таблица.Менеджер КАК Менеджер,
    Таблица.ВидЗапасов КАК ВидЗапасов,
    Таблица.ГруппаФинансовогоУчета КАК ГруппаФинансовогоУчета,
    Таблица.ВидСделки КАК ВидСделки,
    Таблица.ХозяйственнаяОперация КАК ХозяйственнаяОперация,
    ВЫБОР
        КОГДА &ДанныеОтчета = 1
            ТОГДА СУММА(Таблица.Себестоимость)
        КОГДА &ДанныеОтчета = 3
            ТОГДА СУММА(Таблица.СебестоимостьРегл)
        ИНАЧЕ СУММА(Таблица.СебестоимостьБезНДС)
    КОНЕЦ + ВЫБОР
        КОГДА &ДанныеОтчета = 1
            ТОГДА СУММА(Таблица.Себестоимость)
        КОГДА &ДанныеОтчета = 3
            ТОГДА СУММА(Таблица.СебестоимостьРегл)
        ИНАЧЕ СУММА(Таблица.СебестоимостьБезНДС)
    КОНЕЦ * &ПроцентНаценки / 100 КАК SEB,
    СУММА(Таблица.СебестоимостьБезНДС) КАК СебестоимостьБезНДС,
    ЕСТЬNULL(ВесШтуки.С_ВесШтуки, 0) КАК ВесШтуки,
    ЕСТЬNULL(ВесПогонногоМетра.С_ВесПогонногоМетра, 0) КАК ВесПогонногоМетра
ПОМЕСТИТЬ ВТ
ИЗ
    (ВЫБРАТЬ
        ВЫБОР
            КОГДА Продажи.Регистратор = НЕОПРЕДЕЛЕНО
                ТОГДА NULL
            ИНАЧЕ Продажи.Регистратор
        КОНЕЦ КАК Регистратор,
        Продажи.ПериодСекунда КАК ПериодСекунда,
        НАЧАЛОПЕРИОДА(Продажи.ПериодДень, ДЕНЬ) КАК ПериодДень,
        НАЧАЛОПЕРИОДА(Продажи.ПериодНеделя, НЕДЕЛЯ) КАК ПериодНеделя,
        НАЧАЛОПЕРИОДА(Продажи.ПериодДекада, ДЕКАДА) КАК ПериодДекада,
        НАЧАЛОПЕРИОДА(Продажи.ПериодМесяц, МЕСЯЦ) КАК ПериодМесяц,
        НАЧАЛОПЕРИОДА(Продажи.ПериодКвартал, КВАРТАЛ) КАК ПериодКвартал,
        НАЧАЛОПЕРИОДА(Продажи.ПериодПолугодие, ПОЛУГОДИЕ) КАК ПериодПолугодие,
        НАЧАЛОПЕРИОДА(Продажи.ПериодГод, ГОД) КАК ПериодГод,
        ВЫБОР
            КОГДА Продажи.Менеджер = ЗНАЧЕНИЕ(Справочник.Пользователи.ПустаяСсылка)
                ТОГДА ЕСТЬNULL(Продажи.ЗаказКлиента.Менеджер, ЗНАЧЕНИЕ(Справочник.Пользователи.ПустаяСсылка))
            ИНАЧЕ Продажи.Менеджер
        КОНЕЦ КАК Менеджер,
        АналитикаНоменклатуры.Номенклатура КАК Номенклатура,
        АналитикаНоменклатуры.Характеристика КАК Характеристика,
        АналитикаНоменклатуры.Серия КАК Серия,
        АналитикаПоПартнерам.Организация КАК Организация,
        АналитикаПоПартнерам.Организация КАК Продавец,
        АналитикаПоПартнерам.Партнер КАК Партнер,
        АналитикаНоменклатуры.Склад КАК Склад,
        Продажи.ВидЗапасов КАК ВидЗапасов,
        Продажи.ВидЗапасов.ГруппаФинансовогоУчета КАК ГруппаФинансовогоУчета,
        Продажи.Подразделение КАК Подразделение,
        ВЫБОР
            КОГДА Продажи.ВидЗапасов.РеализацияЗапасовДругойОрганизации
                ТОГДА ВЫБОР
                        КОГДА Продажи.ВидЗапасов.ВидЗапасовВладельца.ТипЗапасов = ЗНАЧЕНИЕ(Перечисление.ТипыЗапасов.КомиссионныйТовар)
                            ТОГДА Продажи.ВидЗапасов.ВидЗапасовВладельца.Комитент
                        ИНАЧЕ Продажи.ВидЗапасов.ВидЗапасовВладельца.Поставщик
                    КОНЕЦ
            ИНАЧЕ ВЫБОР
                    КОГДА Продажи.ВидЗапасов.ТипЗапасов = ЗНАЧЕНИЕ(Перечисление.ТипыЗапасов.КомиссионныйТовар)
                        ТОГДА Продажи.ВидЗапасов.Комитент
                    ИНАЧЕ Продажи.ВидЗапасов.Поставщик
                КОНЕЦ
        КОНЕЦ КАК Поставщик,
        Продажи.ЗаказКлиента КАК ЗаказКлиента,
        ВЫБОР
            КОГДА АналитикаПоПартнерам.Контрагент ССЫЛКА Справочник.Контрагенты
                ТОГДА АналитикаПоПартнерам.Контрагент
            ИНАЧЕ NULL
        КОНЕЦ КАК Контрагент,
        ВЫБОР
            КОГДА АналитикаПоПартнерам.Контрагент ССЫЛКА Справочник.Организации
                ТОГДА АналитикаПоПартнерам.Контрагент
            ИНАЧЕ NULL
        КОНЕЦ КАК Покупатель,
        ВЫБОР
            КОГДА НЕ Продажи.ЗаказКлиента.Сделка.ВидСделки ЕСТЬ NULL
                ТОГДА Продажи.ЗаказКлиента.Сделка.ВидСделки.Наименование
            КОГДА Продажи.ЗаказКлиента ССЫЛКА Документ.ЗаказКлиента
                    ИЛИ Продажи.ЗаказКлиента ССЫЛКА Документ.ЗаявкаНаВозвратТоваровОтКлиента
                ТОГДА &СтрокаПродажиПоЗаказам
            ИНАЧЕ &СтрокаПродажиБезЗаказов
        КОНЕЦ КАК ВидСделки,
        Продажи.КоличествоОборот КАК Количество,
        Продажи.СуммаВыручкиОборот КАК Выручка,
        Продажи.СуммаВыручкиРеглОборот КАК ВыручкаРегл,
        Продажи.СуммаВыручкиБезНДСОборот КАК ВыручкаБезНДС,
        ВЫБОР
            КОГДА Продажи.ТипЗапасов = ЗНАЧЕНИЕ(Перечисление.ТипыЗапасов.КомиссионныйТовар)
                ТОГДА Продажи.СуммаВыручкиОборот
            КОГДА ЕСТЬNULL(РасчетСебестоимости.Ссылка.ПредварительныйРасчет, ЛОЖЬ)
                ТОГДА ВЫРАЗИТЬ(Продажи.КоличествоОборот * ЕСТЬNULL(СтоимостьНоменклатуры.Стоимость, 0) * 1.18 КАК ЧИСЛО(15, 2))
            ИНАЧЕ Продажи.СебестоимостьОборот
        КОНЕЦ КАК Себестоимость,
        ВЫБОР
            КОГДА Продажи.ТипЗапасов = ЗНАЧЕНИЕ(Перечисление.ТипыЗапасов.КомиссионныйТовар)
                ТОГДА Продажи.СуммаВыручкиБезНДСОборот
            КОГДА ЕСТЬNULL(РасчетСебестоимости.Ссылка.ПредварительныйРасчет, ЛОЖЬ)
                ТОГДА ВЫРАЗИТЬ(Продажи.КоличествоОборот * ЕСТЬNULL(СтоимостьНоменклатуры.Стоимость, 0) КАК ЧИСЛО(15, 2))
            ИНАЧЕ Продажи.СебестоимостьБезНДСОборот
        КОНЕЦ КАК СебестоимостьБезНДС,
        ВЫБОР
            КОГДА Продажи.ТипЗапасов = ЗНАЧЕНИЕ(Перечисление.ТипыЗапасов.КомиссионныйТовар)
                ТОГДА Продажи.СуммаВыручкиРеглОборот
            КОГДА ЕСТЬNULL(РасчетСебестоимости.Ссылка.ПредварительныйРасчет, ЛОЖЬ)
                ТОГДА ВЫРАЗИТЬ(Продажи.КоличествоОборот * ЕСТЬNULL(СтоимостьНоменклатуры.СтоимостьРегл, 0) КАК ЧИСЛО(15, 2))
            ИНАЧЕ Продажи.СебестоимостьРеглОборот
        КОНЕЦ КАК СебестоимостьРегл,
        ВЫБОР
            КОГДА Продажи.ТипЗапасов = ЗНАЧЕНИЕ(Перечисление.ТипыЗапасов.КомиссионныйТовар)
                ТОГДА 0
            КОГДА ЕСТЬNULL(РасчетСебестоимости.Ссылка.ПредварительныйРасчет, ЛОЖЬ)
                ТОГДА ВЫРАЗИТЬ(Продажи.КоличествоОборот * ЕСТЬNULL(СтоимостьНоменклатуры.СтоимостьДопРасходы, 0) КАК ЧИСЛО(15, 2))
            ИНАЧЕ Продажи.СуммаДополнительныхРасходовОборот
        КОНЕЦ КАК ДопРасходы,
        ВЫБОР
            КОГДА Продажи.ТипЗапасов = ЗНАЧЕНИЕ(Перечисление.ТипыЗапасов.КомиссионныйТовар)
                ТОГДА 0
            КОГДА ЕСТЬNULL(РасчетСебестоимости.Ссылка.ПредварительныйРасчет, ЛОЖЬ)
                ТОГДА ВЫРАЗИТЬ(Продажи.КоличествоОборот * ЕСТЬNULL(СтоимостьНоменклатуры.СтоимостьДопРасходыБезНДС, 0) КАК ЧИСЛО(15, 2))
            ИНАЧЕ Продажи.СуммаДополнительныхРасходовБезНДСОборот
        КОНЕЦ КАК ДопРасходыБезНДС,
        Продажи.СуммаРучнойСкидкиОборот КАК СуммаРучнойСкидкиОборот,
        Продажи.СуммаАвтоматическойСкидкиОборот КАК СуммаАвтоматическойСкидкиОборот,
        Продажи.ХозяйственнаяОперация КАК ХозяйственнаяОперация
    {ВЫБРАТЬ
        ЗаказКлиента.*,
        Подразделение.*,
        Номенклатура.*,
        Характеристика.*,
        Склад.*,
        Организация.*,
        Продавец.*,
        Партнер.*,
        Контрагент.*,
        Покупатель.*,
        Поставщик.*,
        Менеджер.*,
        ВидЗапасов.*,
        ГруппаФинансовогоУчета.*,
        Регистратор,
        ПериодСекунда,
        ПериодДень,
        ПериодНеделя,
        ПериодДекада,
        ПериодМесяц,
        ПериодКвартал,
        ПериодПолугодие,
        ПериодГод,
        ВидСделки,
        ХозяйственнаяОперация.*}
    ИЗ
        РегистрНакопления.ВыручкаИСебестоимостьПродаж.Обороты({(&НачалоПериода)}, {(&ОкончаниеПериода)}, Авто, {(ЕСТЬNULL(ЗаказКлиента.Сделка, ЗНАЧЕНИЕ(Справочник.СделкиСКлиентами.ПустаяСсылка))).* КАК Сделка, (ЕСТЬNULL(ЗаказКлиента.Сделка.Ответственный, ЗНАЧЕНИЕ(Справочник.Пользователи.ПустаяСсылка))).* КАК МенеджерСделки, (ВЫБОР
                    КОГДА Менеджер = ЗНАЧЕНИЕ(Справочник.Пользователи.ПустаяСсылка)
                        ТОГДА ЕСТЬNULL(ЗаказКлиента.Менеджер, ЗНАЧЕНИЕ(Справочник.Пользователи.ПустаяСсылка))
                    ИНАЧЕ Менеджер
                КОНЕЦ).* КАК Менеджер, (ВЫБОР
                    КОГДА ВидЗапасов.РеализацияЗапасовДругойОрганизации
                        ТОГДА ВЫБОР
                                КОГДА ВидЗапасов.ВидЗапасовВладельца.ТипЗапасов = ЗНАЧЕНИЕ(Перечисление.ТипыЗапасов.КомиссионныйТовар)
                                    ТОГДА ВидЗапасов.ВидЗапасовВладельца.Комитент
                                ИНАЧЕ ВидЗапасов.ВидЗапасовВладельца.Поставщик
                            КОНЕЦ
                    ИНАЧЕ ВЫБОР
                            КОГДА ВидЗапасов.ТипЗапасов = ЗНАЧЕНИЕ(Перечисление.ТипыЗапасов.КомиссионныйТовар)
                                ТОГДА ВидЗапасов.Комитент
                            ИНАЧЕ ВидЗапасов.Поставщик
                        КОНЕЦ
                КОНЕЦ).* КАК Поставщик, (ВидЗапасов.ГруппаФинансовогоУчета).* КАК ГруппаФинансовогоУчета, (ВЫБОР
                    КОГДА НЕ ЗаказКлиента.Сделка.ВидСделки ЕСТЬ NULL
                        ТОГДА ЗаказКлиента.Сделка.ВидСделки.Наименование
                    КОГДА ЗаказКлиента ССЫЛКА Документ.ЗаказКлиента
                            ИЛИ ЗаказКлиента ССЫЛКА Документ.ЗаявкаНаВозвратТоваровОтКлиента
                        ТОГДА &СтрокаПродажиПоЗаказам
                    ИНАЧЕ &СтрокаПродажиБезЗаказов
                КОНЕЦ) КАК ВидСделки}) КАК Продажи
            {ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.АналитикаУчетаНоменклатуры КАК АналитикаНоменклатуры
            ПО Продажи.АналитикаУчетаНоменклатуры = АналитикаНоменклатуры.КлючАналитики}
            {ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.АналитикаУчетаПоПартнерам КАК АналитикаПоПартнерам
            ПО Продажи.АналитикаУчетаПоПартнерам = АналитикаПоПартнерам.КлючАналитики}
            {ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.СтоимостьТоваров КАК СтоимостьНоменклатуры
            ПО Продажи.АналитикаУчетаНоменклатуры = СтоимостьНоменклатуры.АналитикаУчетаНоменклатуры
                И (АналитикаПоПартнерам.Организация = СтоимостьНоменклатуры.Организация)
                И Продажи.ВидЗапасов = СтоимостьНоменклатуры.ВидЗапасов
                И (СтоимостьНоменклатуры.Период = НАЧАЛОПЕРИОДА(Продажи.ПериодМесяц, МЕСЯЦ))
                И (СтоимостьНоменклатуры.РазделУчета <> ЗНАЧЕНИЕ(Перечисление.РазделыУчетаСебестоимостиТоваров.ТоварыПринятыеНаКомиссию))
                И (СтоимостьНоменклатуры.РазделУчета <> ЗНАЧЕНИЕ(Перечисление.РазделыУчетаСебестоимостиТоваров.МатериалыПринятыеВПереработку))}
            {ЛЕВОЕ СОЕДИНЕНИЕ Документ.РасчетСебестоимостиТоваров.Организации КАК РасчетСебестоимости
            ПО (НАЧАЛОПЕРИОДА(Продажи.ПериодМесяц, МЕСЯЦ) = НАЧАЛОПЕРИОДА(РасчетСебестоимости.Ссылка.Дата, МЕСЯЦ))
                И (АналитикаПоПартнерам.Организация = РасчетСебестоимости.Организация)
                И (РасчетСебестоимости.Ссылка.Проведен)}
    ГДЕ
        (&ПоказыватьПродажи = 1
                    И АналитикаПоПартнерам.Партнер <> ЗНАЧЕНИЕ(Справочник.Партнеры.НашеПредприятие)
                ИЛИ &ПоказыватьПродажи = 2
                    И АналитикаПоПартнерам.Партнер = ЗНАЧЕНИЕ(Справочник.Партнеры.НашеПредприятие)
                ИЛИ &ПоказыватьПродажи = 0)
    {ГДЕ
        АналитикаНоменклатуры.Номенклатура.* КАК Номенклатура,
        АналитикаНоменклатуры.Характеристика.* КАК Характеристика,
        АналитикаПоПартнерам.Организация.* КАК Организация,
        АналитикаПоПартнерам.Партнер.* КАК Партнер,
        АналитикаНоменклатуры.Склад.* КАК Склад,
        АналитикаНоменклатуры.Номенклатура.* КАК Номенклатура,
        АналитикаНоменклатуры.Характеристика.* КАК Характеристика,
        АналитикаПоПартнерам.Партнер.* КАК Партнер,
        (ЕСТЬNULL(Продажи.ЗаказКлиента.Сделка, ЗНАЧЕНИЕ(Справочник.СделкиСКлиентами.ПустаяСсылка))).* КАК Сделка,
        (ВЫБОР
                КОГДА АналитикаПоПартнерам.Контрагент ССЫЛКА Справочник.Контрагенты
                    ТОГДА АналитикаПоПартнерам.Контрагент
                ИНАЧЕ NULL
            КОНЕЦ).* КАК Контрагент,
        (ВЫБОР
                КОГДА АналитикаПоПартнерам.Контрагент ССЫЛКА Справочник.Организации
                    ТОГДА АналитикаПоПартнерам.Контрагент
                ИНАЧЕ NULL
            КОНЕЦ).* КАК Покупатель,
        Продажи.ХозяйственнаяОперация.*}) КАК Таблица
        ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
            ВесШтуки.Ссылка КАК Ссылка,
            ВесШтуки.Значение КАК С_ВесШтуки
        ИЗ
            Справочник.ХарактеристикиНоменклатуры.ДополнительныеРеквизиты КАК ВесШтуки
        ГДЕ
            ВесШтуки.Свойство = &Свойство) КАК ВесШтуки
        ПО Таблица.Характеристика = ВесШтуки.Ссылка
        ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
            ХарактеристикиНоменклатурыДополнительныеРеквизиты.Ссылка КАК Ссылка,
            ХарактеристикиНоменклатурыДополнительныеРеквизиты.Значение КАК С_ВесПогонногоМетра
        ИЗ
            Справочник.ХарактеристикиНоменклатуры.ДополнительныеРеквизиты КАК ХарактеристикиНоменклатурыДополнительныеРеквизиты
        ГДЕ
            ХарактеристикиНоменклатурыДополнительныеРеквизиты.Свойство = &ВесПогонногоМетра) КАК ВесПогонногоМетра
        ПО Таблица.Характеристика = ВесПогонногоМетра.Ссылка
{ГДЕ
    (Таблица.Номенклатура.ТипНоменклатуры = &Товар)}

СГРУППИРОВАТЬ ПО
    Таблица.Номенклатура,
    Таблица.Характеристика,
    Таблица.Организация,
    Таблица.Продавец,
    Таблица.Партнер,
    Таблица.Регистратор,
    Таблица.ПериодСекунда,
    Таблица.ПериодДень,
    Таблица.ПериодНеделя,
    Таблица.ПериодДекада,
    Таблица.ПериодМесяц,
    Таблица.ПериодКвартал,
    Таблица.ПериодПолугодие,
    Таблица.ПериодГод,
    Таблица.ЗаказКлиента,
    Таблица.Подразделение,
    Таблица.Склад,
    Таблица.Контрагент,
    Таблица.Покупатель,
    Таблица.Поставщик,
    Таблица.Менеджер,
    Таблица.ВидЗапасов,
    Таблица.ГруппаФинансовогоУчета,
    Таблица.ВидСделки,
    Таблица.Номенклатура.ЕдиницаИзмерения,
    Таблица.Номенклатура.ЕдиницаДляОтчетов,
    Таблица.Номенклатура.КоэффициентЕдиницыДляОтчетов,
    Таблица.СуммаРучнойСкидкиОборот,
    Таблица.СуммаАвтоматическойСкидкиОборот,
    Таблица.ХозяйственнаяОперация,
    Таблица.Номенклатура.ГруппаАналитическогоУчета,
    ЕСТЬNULL(ВесШтуки.С_ВесШтуки, 0),
    ЕСТЬNULL(ВесПогонногоМетра.С_ВесПогонногоМетра, 0)

ИМЕЮЩИЕ
    (СУММА(Таблица.Количество) <> 0
        ИЛИ ВЫБОР
            КОГДА &ДанныеОтчета = 1
                ТОГДА СУММА(Таблица.Выручка)
            КОГДА &ДанныеОтчета = 3
                ТОГДА СУММА(Таблица.ВыручкаРегл)
            ИНАЧЕ СУММА(Таблица.ВыручкаБезНДС)
        КОНЕЦ <> 0
        ИЛИ ВЫБОР
            КОГДА &ДанныеОтчета = 1
                ТОГДА СУММА(Таблица.Себестоимость)
            КОГДА &ДанныеОтчета = 3
                ТОГДА СУММА(Таблица.СебестоимостьРегл)
            ИНАЧЕ СУММА(Таблица.СебестоимостьБезНДС)
        КОНЕЦ <> 0
        ИЛИ ВЫБОР
            КОГДА &ДанныеОтчета = 1
                ТОГДА СУММА(Таблица.ДопРасходы)
            КОГДА &ДанныеОтчета = 3
                ТОГДА 0
            ИНАЧЕ СУММА(Таблица.ДопРасходыБезНДС)
        КОНЕЦ <> 0
        ИЛИ ВЫБОР
            КОГДА &ДанныеОтчета = 1
                ТОГДА СУММА(Таблица.Выручка) - СУММА(Таблица.Себестоимость) - СУММА(Таблица.ДопРасходы)
            КОГДА &ДанныеОтчета = 3
                ТОГДА СУММА(Таблица.ВыручкаРегл) - СУММА(Таблица.СебестоимостьРегл)
            ИНАЧЕ СУММА(Таблица.ВыручкаБезНДС) - СУММА(Таблица.СебестоимостьБезНДС) - СУММА(Таблица.ДопРасходыБезНДС)
        КОНЕЦ <> 0)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ВТ.Регистратор КАК Регистратор,
    ВТ.ПериодСекунда КАК ПериодСекунда,
    ВТ.ПериодДень КАК ПериодДень,
    ВТ.ПериодНеделя КАК ПериодНеделя,
    ВТ.ПериодДекада КАК ПериодДекада,
    ВТ.ПериодМесяц КАК ПериодМесяц,
    ВТ.ПериодКвартал КАК ПериодКвартал,
    ВТ.ПериодПолугодие КАК ПериодПолугодие,
    ВТ.ПериодГод КАК ПериодГод,
    ВЫБОР
        КОГДА ВТ.ЕдиницаХранения = &ЕдиницаХранения
            ТОГДА ВТ.Количество
    КОНЕЦ КАК Количество,
    ВТ.Выручка КАК Выручка,
    ВТ.ВыручкаБезНДС КАК ВыручкаБезНДС,
    ВТ.ВыручкаНДС КАК ВыручкаНДС,
    ВТ.СуммаРучнойСкидки КАК СуммаРучнойСкидки,
    ВТ.СуммаАвтоматическойСкидки КАК СуммаАвтоматическойСкидки,
    ВТ.ВсегоСкидок КАК ВсегоСкидок,
    ВТ.Себестоимость КАК Себестоимость,
    ВТ.СебестоимостьНДС КАК СебестоимостьНДС,
    ВТ.ДопРасходы КАК ДопРасходы,
    ВТ.ВаловаяПрибыль КАК ВаловаяПрибыль,
    ВТ.Рентабельность КАК Рентабельность,
    ВТ.ПродажиМеждуОрганизациями КАК ПродажиМеждуОрганизациями,
    ВТ.Номенклатура КАК Номенклатура,
    ВТ.ЕдиницаХранения КАК ЕдиницаХранения,
    ВТ.ЕдиницаДляОтчетов КАК ЕдиницаДляОтчетов,
    ВТ.КоэффициентЕдиницыДляОтчетов КАК КоэффициентЕдиницыДляОтчетов,
    ВТ.ГруппаАналитическогоУчета КАК ГруппаАналитическогоУчета,
    ВТ.Характеристика КАК Характеристика,
    ВТ.Организация КАК Организация,
    ВТ.Продавец КАК Продавец,
    ВТ.Партнер КАК Партнер,
    ВТ.ЗаказКлиента КАК ЗаказКлиента,
    ВТ.Подразделение КАК Подразделение,
    ВТ.Склад КАК Склад,
    ВТ.Контрагент КАК Контрагент,
    ВТ.Покупатель КАК Покупатель,
    ВТ.Поставщик КАК Поставщик,
    ВТ.Менеджер КАК Менеджер,
    ВТ.ВидЗапасов КАК ВидЗапасов,
    ВТ.ГруппаФинансовогоУчета КАК ГруппаФинансовогоУчета,
    ВТ.ВидСделки КАК ВидСделки,
    ВТ.ХозяйственнаяОперация КАК ХозяйственнаяОперация,
    ВТ.SEB КАК SEB,
    ВТ.СебестоимостьБезНДС КАК СебестоимостьБезНДС,
    ВложенныйЗапрос.Количество КАК КоличествоСумма,
    ВложенныйЗапрос.Выручка КАК ВыручкаСумма,
    ВТ.ВесШтуки КАК ВесШтуки,
    ВТ.ВесПогонногоМетра КАК ВесПогонногоМетра
ИЗ
    ВТ КАК ВТ
        ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
            СУММА(ВТ.Количество) КАК Количество,
            СУММА(ВТ.Выручка) КАК Выручка
        ИЗ
            ВТ КАК ВТ) КАК ВложенныйЗапрос
        ПО (ИСТИНА)


Может скобками текст засыпать?

Пробывал


ВЫБОР
    КОГДА ВТ.ЕдиницаХранения <> &ЕдиницаХранения
        ТОГДА ВЫБОР
                  КОГДА ВТ.ВесШтуки = 0
                      ТОГДА ВТ.ВесПогонногоМетра * 1
                      ИНАЧЕ ВТ.ВесШтуки *1
                КОНЕЦ    
        ИНАЧЕ  ВТ.Количество
КОНЕЦ

так не работает а так работает

ВЫБОР
    КОГДА ВТ.ЕдиницаХранения <> &ЕдиницаХранения
        ТОГДА ВЫБОР
                  КОГДА ВТ.ВесШтуки = 0
                      ТОГДА ВТ.ВесПогонногоМетра
                      ИНАЧЕ ВТ.ВесШтуки
                КОНЕЦ    
        ИНАЧЕ  ВТ.Количество
КОНЕЦ


нижнее без умножения на 1 работает

С_ВесШтуки не число и не null

Возможно, в этом месте
ХарактеристикиНоменклатурыДополнительныеРеквизиты.Значение КАК С_ВесПогонногоМетра
реквизит Значение не является числом. Можно попробовать через ВЫРАЗИТЬ(...) КАК ЧИСЛО(15,3)
То же самое с ВесШтуки

(17) Помогло СПС