Ошибка в обмене с бухгалтерией

Перем СтатусПроверкиДиапазона Экспорт;      // Структура для проверки кода в диапазоне кодов

///////////////////////////////////////////////////////////////////////////////
// ПРОЦЕДУРЫ И ФУНКЦИИ ОБЩЕГО НАЗНАЧЕНИЯ

// Получает таблицу категорий цен
Функция ПолучитьТаблицуКатегорийЦен(ПолучитьЗакупочнуюЦену,ВыводитьГлавные = Истина, ВыводитьПодчиненные = Истина) Экспорт

    Перем СписокТО;

    ЕстьОграничениеДоступа = ОграничениеДоступа.ЕстьОграничениеДоступаКТОНаПросмотр(СписокТО);

    Запрос = Новый Запрос;

    Запрос.УстановитьПараметр("ЕстьОграничениеДоступа", ЕстьОграничениеДоступа);
    Запрос.УстановитьПараметр("СписокТО"          , СписокТО);

    Запрос.Текст =
    "ВЫБРАТЬ РАЗЛИЧНЫЕ
    |    ТорговыеОбъекты.Ссылка КАК КатегорияЦен,
    |    ТорговыеОбъекты.Ссылка.Наименование КАК Наименование
    |ИЗ
    |    Справочник.КатегорииЦен.ТорговыеОбъекты КАК ТорговыеОбъекты
    |ГДЕ
    |    (Не &ЕстьОграничениеДоступа ИЛИ ТорговыеОбъекты.ТорговыйОбъект В (&СписокТО))
    |    И ТорговыеОбъекты.Просмотр = ИСТИНА"
    +?(НЕ ВыводитьПодчиненные И НЕ(ВыводитьГлавные И ВыводитьПодчиненные) ,"
    |      И ( ТорговыеОбъекты.Ссылка.Родитель = ЗНАЧЕНИЕ(Справочник.КатегорииЦен.ПустаяСсылка)
    |        ИЛИ ТорговыеОбъекты.Ссылка.ПереоценкаПоГруппе = ИСТИНА
    |        ИЛИ ТорговыеОбъекты.Ссылка.Родитель.ПереоценкаПоГруппе = ЛОЖЬ )","")
    +?(НЕ ВыводитьГлавные И НЕ(ВыводитьГлавные И ВыводитьПодчиненные),"
    |      И ТорговыеОбъекты.Ссылка.Родитель.ПереоценкаПоГруппе = ИСТИНА","")
    +?(ПолучитьЗакупочнуюЦену, "", "
    |    И ТорговыеОбъекты.Ссылка <> ЗНАЧЕНИЕ(Справочник.КатегорииЦен.Закупочная)") + ?(ПолучитьЗакупочнуюЦену, "
    |ОБЪЕДИНИТЬ
    |ВЫБРАТЬ
    |    ЗНАЧЕНИЕ(Справочник.КатегорииЦен.Закупочная),
    |    (ЗНАЧЕНИЕ(Справочник.КатегорииЦен.Закупочная)).Наименование", "")+"
    |УПОРЯДОЧИТЬ ПО
    |    Наименование";

    Таблица = Запрос.Выполнить().Выгрузить();
    Таблица.Колонки.Добавить("НаценкаПоУмолчанию", Новый ОписаниеТипов("Число", Новый КвалификаторыЧисла(6, 2, ДопустимыйЗнак.Неотрицательный)));
    Таблица.Колонки.Добавить("ПравилоОкругления",  Новый ОписаниеТипов("СправочникСсылка.ПравилаОкругления"));
    Таблица.Колонки.Добавить("КоридорЦен",         Новый ОписаниеТипов("СправочникСсылка.КоридорыЦен"));
    Таблица.Колонки.Добавить("ИзГруппы",           Новый ОписаниеТипов("Булево"));

    Возврат Таблица;

КонецФункции

// Обновляет таблицу значений ТаблицаКатегорийЦен по категориям цен заданным в таблице значений ТабКатегорийЦен
// В таблице ТабКатегорийЦен обязательна колонка КатегорияЦен
Процедура ОбновитьТаблицуКатегорийЦен(ИсходнаяТаблица, ТабКатегорийЦен) Экспорт

    НоваяТаблица = ПолучитьТаблицуПравилЦенообразования(ТабКатегорийЦен,Родитель,);

    Для Каждого СтрокаТЧ Из ИсходнаяТаблица Цикл
        СтрокаНовТаб = НоваяТаблица.Найти(СтрокаТЧ.КатегорияЦен, "КатегорияЦен");
        Если СтрокаНовТаб <> Неопределено Тогда
            ЗаполнитьЗначенияСвойств(СтрокаТЧ, СтрокаНовТаб);
            СтрокаТЧ.ИзГруппы = Истина;
        КонецЕсли;
    КонецЦикла;

КонецПроцедуры

// Функция проверяет, существуют ли ссылки на номенклатуру в регистрах.
//
// Параметры:
//  СуществуютСсылки - старое значение параметра, для единичного запуска функции.
//
// Возвращаемое значение:
//  Истина - если есть движения, Ложь - если нет.
//
Функция СуществуютСсылки(СуществуютСсылки) Экспорт

    Если СуществуютСсылки <> Неопределено Тогда
        Возврат СуществуютСсылки;
    КонецЕсли;

    Если ЭтоНовый() Тогда
        Возврат Ложь;
    КонецЕсли;

    Запрос = Новый Запрос();

    Запрос.УстановитьПараметр("ТекущийВладелец", Ссылка);

    Запрос.Текст =
    "ВЫБРАТЬ ПЕРВЫЕ 1
    |    ОстаткиНоменклатуры.Номенклатура
    |ИЗ
    |    РегистрНакопления.ОстаткиНоменклатуры КАК ОстаткиНоменклатуры
    |ГДЕ
    |    ОстаткиНоменклатуры.Номенклатура = &Номенклатура
    |
    |ОБЪЕДИНИТЬ ВСЕ
    |
    |ВЫБРАТЬ ПЕРВЫЕ 1
    |    ПартииНоменклатуры.Номенклатура
    |ИЗ
    |    РегистрНакопления.ПартииНоменклатуры КАК ПартииНоменклатуры
    |ГДЕ
    |    ПартииНоменклатуры.Номенклатура = &Номенклатура
    |
    |ОБЪЕДИНИТЬ ВСЕ
    |
    |ВЫБРАТЬ ПЕРВЫЕ 1
    |    ОстаткиНоменклатурыВРознице.Номенклатура
    |ИЗ
    |    РегистрНакопления.ОстаткиНоменклатурыВРознице КАК ОстаткиНоменклатурыВРознице
    |ГДЕ
    |    ОстаткиНоменклатурыВРознице.Номенклатура = &Номенклатура
    |
    |ОБЪЕДИНИТЬ ВСЕ
    |
    |ВЫБРАТЬ ПЕРВЫЕ 1
    |    ТоварыНаРеализации.Номенклатура
    |ИЗ
    |    РегистрНакопления.ТоварыНаРеализации КАК ТоварыНаРеализации
    |ГДЕ
    |    ТоварыНаРеализации.Номенклатура = &Номенклатура";

    Запрос.УстановитьПараметр("Номенклатура", Ссылка);

    СуществуютСсылки =  НЕ Запрос.Выполнить().Пустой();

    Возврат СуществуютСсылки;

КонецФункции

// Процедура получает код из диапозона кодов.
//
// Отказ - код выдать не удалось,
// УстанавливатьКод - устанавливать код, или проверить на возможность его выдачи,
// ТихийРежим - тихий режим работы.
//
Процедура ПолучитьКодИзДиапазона(Отказ, УстанавливатьКод = Истина, ТихийРежим = Ложь) Экспорт

    Если СтатусПроверкиДиапазона.ПоискКодаВДиапозоне Тогда

        ДиапазонНачало = ПолучитьПараметрИБ(ПараметрыСеанса.ТекущаяИБ, "ДиапазонНачало");
        ДиапазонКонец  = ПолучитьПараметрИБ(ПараметрыСеанса.ТекущаяИБ, "ДиапазонКонец");

        Результат = ПолучитьКодИзДиапазонаТаблицы("Справочник.Номенклатура", "Код", ДиапазонНачало, ДиапазонКонец);

        Если Результат.Ошибка Тогда
            Если УстанавливатьКод Тогда
                Окончание = ", элемент не записан!";
            Иначе
                Окончание = ", нельзя завести элемент!";
            КонецЕсли;
            СтрокаСообщение = "Нет свободных кодов в выбранном диапазоне" + Окончание;
            Если ТихийРежим Тогда
                Сообщить(СтрокаСообщение);
            Иначе
                #Если ТолстыйКлиентОбычноеПриложение Тогда
                    Предупреждение(СтрокаСообщение);
                #КонецЕсли
            КонецЕсли;

            Отказ = Истина;
            Возврат;

        ИначеЕсли УстанавливатьКод Тогда
            Код = Результат.Код;
        КонецЕсли;

    КонецЕсли;

КонецПроцедуры

////////////////////////////////////////////////////////////////////////////////
// ОБРАБОТЧИКИ СОБЫТИЙ

// Обработчик события "ПередЗаписью" элемента справочника.
//
Процедура ПередЗаписью(Отказ)

    Если НЕ ОбменДанными.Загрузка Тогда

        // дополнительное право на редактирование Номенклатуры
        ТекстСообщения = "";
        Если НЕ ПроверитьПравоПользователяНаРедактированиеНоменклатуры( ТекстСообщения ) Тогда
            Предупреждение( ТекстСообщения );
            Отказ = Истина;
            Возврат;
        КонецЕсли;

        // При попытке перемещения группы
        Если НЕ ЭтоНовый() И ЭтоГруппа И ПланыОбмена.ГлавныйУзел() <> Неопределено Тогда
            Если Ссылка.Родитель <> ЭтотОбъект.Родитель Тогда
                Сообщить("Перемещение групп товаров доступно только в главном узле.", СтатусСообщения.Внимание);
                Отказ = Истина;
            КонецЕсли;
        КонецЕсли;

        НеобходимостьПроверкиДиапазона(ЭтотОбъект, ЭтотОбъект.СтатусПроверкиДиапазона);

        Если ЭтотОбъект.ЭтоНовый() Тогда
            Если Не ЭтотОбъект.СтатусПроверкиДиапазона.Новый Тогда
                Если ЭтотОбъект.СтатусПроверкиДиапазона.Константа Тогда
                    Сообщить("Элемент можно завести только в узле с заданным диапазоном кодов.", СтатусСообщения.Важное);
                    Отказ = Истина;
                Иначе
                    Сообщить("Элемент можно завести только в узле с признаком ведения справочников.", СтатусСообщения.Важное);
                    Отказ = Истина;
                КонецЕсли;
            Иначе

                ПредвАртикул = Формат(Код, "ЧГ=0"); // для случая когда артикул сформировался по некорректно полученному коду

                Если ДополнительныеСвойства.Свойство("ЗаписьИзФормы") Или Код = 0 Тогда
                    УстановитьНовыйКод();
                КонецЕсли;

                Если Код = 0 Тогда
                    Отказ = Истина;
                Иначе
                    Если НЕ ЭтоГруппа И (ПустаяСтрока(Артикул) ИЛИ Артикул = ПредвАртикул) Тогда
                        Артикул = Формат(Код, "ЧГ=0");
                    КонецЕсли;
                КонецЕсли;

            КонецЕсли;
        ИначеЕсли Не ЭтотОбъект.СтатусПроверкиДиапазона.Редактирование Тогда
            Если ЭтотОбъект.СтатусПроверкиДиапазона.Константа Тогда
                Сообщить("Элемент редактируется в узле с признаком ведения справочников либо в узле где был создан.", СтатусСообщения.Важное);
                Отказ = Истина;
            Иначе
                Сообщить("Элемент редактируется только в узле с признаком ведения справочников.", СтатусСообщения.Важное);
                Отказ = Истина;
            КонецЕсли;
        КонецЕсли;

        Если НЕ ЭтоГруппа Тогда

            Если ТабачныеИзделия Тогда
                Если НЕ ЗначениеЗаполнено(КатегорияТовара)
                    Или КатегорияТовара = Справочники.КатегорииТоваров.УчетПоХарактеристикамНеВедется
                    Или Не ПроверитьКорректностьКатегорииТовараДляТабака() Тогда
                    Сообщить("Для номенклатуры с видом ""Табак"" необходимо указать категорию товара с включенным обязательным свойством ""МРЦ""!");
                    Отказ = Истина;
                Иначе
                    ИспользоватьХарактеристикиНоменклатуры                = Истина;
                    ОбязательноеЗаполнениеХарактеристикиНоменклатуры    = Истина;
                КонецЕсли;
            Иначе
                Если НЕ ЗначениеЗаполнено(КатегорияТовара) Тогда
                    Если ИспользоватьХарактеристикиНоменклатуры Тогда
                        Сообщить("Не указана категория товара!", СтатусСообщения.Важное);
                        Отказ = Истина;
                    Иначе
                        КатегорияТовара = Справочники.КатегорииТоваров.УчетПоХарактеристикамНеВедется;
                    КонецЕсли;
                КонецЕсли;
            КонецЕсли;

            Если Не ЭтоНовый() Тогда

                Если Не Услуга И НЕ ЗначениеЗаполнено(БазоваяЕдиницаИзмерения) Тогда
                    Сообщить("Не указана базовая единица измерения.", СтатусСообщения.Важное);
                    Отказ = Истина;
                Иначе

                    // Надо проверить владельца единицы хранения остатков
                    Если БазоваяЕдиницаИзмерения.Владелец <> Ссылка Тогда
                        Сообщить("У базовой единицы номенклатуры """ + СокрЛП(Ссылка) + """ неверно указан владелец!", СтатусСообщения.Важное);
                        Отказ = Истина;
                    КонецЕсли;

                КонецЕсли;

                Если (НЕ Услуга) И (НЕ ЗначениеЗаполнено(ЕдиницаИзмеренияЗаказов)) Тогда
                    ЕдиницаИзмеренияЗаказов = БазоваяЕдиницаИзмерения;
                КонецЕсли;

                Если НЕ ЗначениеЗаполнено(ЕдиницаИзмеренияОтчетов) Тогда
                    ЕдиницаИзмеренияОтчетов = БазоваяЕдиницаИзмерения;
                КонецЕсли;
            КонецЕсли;

            Если Тара И СтавкаНДС <> Перечисления.СтавкиНДС.БезНДС Тогда
                СтавкаНДС = Перечисления.СтавкиНДС.БезНДС;
            ИначеЕсли Не ЗначениеЗаполнено(СтавкаНДС) Тогда
                Сообщить("Не указана ставка НДС.", СтатусСообщения.Важное);
                Отказ = Истина;
            КонецЕсли;

            СуществуютСсылки = Неопределено;
            Если НЕ Услуга
               И Ссылка.БазоваяЕдиницаИзмерения <> БазоваяЕдиницаИзмерения
               И СуществуютСсылки(СуществуютСсылки) Тогда
                Сообщить("Единица """ + СокрЛП(Ссылка.БазоваяЕдиницаИзмерения) + """ является базовой единицей для """ + Наименование + """
                |и уже участвует в товародвижении.
                |Изменить эту единицу уже нельзя!", СтатусСообщения.Важное);
            КонецЕсли;

            Если Услуга <> Ссылка.Услуга
               И СуществуютСсылки(СуществуютСсылки)Тогда
                ТекстСообщения = "Номенклатура """ + СокрЛП(Ссылка) + """ участвует в товародвижении.
                |Признак услуги не может быть изменен!";
                СообщитьОбОшибкеДАЛИОН(ТекстСообщения, Отказ);
            КонецЕсли;

            Если Тара <> Ссылка.Тара
               И СуществуютСсылки(СуществуютСсылки)Тогда
                ТекстСообщения = "Номенклатура """ + СокрЛП(Ссылка) + """ участвует в товародвижении.
                |Признак тары не может быть изменен!";
                СообщитьОбОшибкеДАЛИОН(ТекстСообщения, Отказ);
            КонецЕсли;

            Если ФиксированныйПоставщик И НЕ ЗначениеЗаполнено(ОсновнойПоставщик) Тогда
                Сообщить("Не выбран основной поставщик.", СтатусСообщения.Важное);
                Отказ = Истина;
            КонецЕсли;

            Если Алкоголь Тогда

                Если НЕ ЗначениеЗаполнено(ОбъемАлкоголь) Тогда
                    Сообщить("Не заполнен объем алкоголя.", СтатусСообщения.Важное);
                    Отказ = Истина;
                КонецЕсли;

                Если ПивнаяКега Тогда
                    Если ЗначениеЗаполнено(НоменклатураРазливноеПиво) Тогда
                        Если НоменклатураРазливноеПиво = Ссылка Тогда
                            Сообщить("Нельзя указывать в качестве номенклатуры ""Разливное пиво"" саму себя!");
                            Отказ = Истина;
                        ИначеЕсли НЕ НоменклатураРазливноеПиво.Алкоголь Тогда
                            Сообщить("Нельзя указывать в качестве номенклатуры ""Разливное пиво"" неалкогольную продукцию!");
                            Отказ = Истина;
                        КонецЕсли;
                    КонецЕсли;
                Иначе
                    НоменклатураРазливноеПиво = Справочники.Номенклатура.ПустаяСсылка();
                КонецЕсли;
            Иначе
                //Очистка алкогольных реквизитов
                ВидАлкогольнойПродукции     = Справочники.ВидыАлкогольнойПродукции.ПустаяСсылка();
                ПроизводительАлкоголя        = Справочники.ПроизводителиАлкоголя.ПустаяСсылка();
                ОбъемАлкоголь                = 0;
                ЕмкостьПотребительскойТары     = 0;
                НаименованиеДляДекларации   = "";
                СодержаниеСпирта            = 0;
                ПивнаяКега                    = Ложь;
                РазливноеПиво                = Ложь;
                НоменклатураРазливноеПиво    = Справочники.Номенклатура.ПустаяСсылка();
            КонецЕсли;

        КонецЕсли;

    КонецЕсли;

КонецПроцедуры // ПередЗаписью()

// Обработчик события "ПриЗаписи" элемента справочника.
//
Процедура ПриЗаписи(Отказ)

    Если НЕ ЭтоГруппа И НЕ ОбменДанными.Загрузка Тогда

        Если ШтрихКодВключаетКоличество И (Не ИспользоватьХарактеристикиНоменклатуры ИЛИ Не ОбязательноеЗаполнениеХарактеристикиНоменклатуры) И ЗначениеЗаполнено(БазоваяЕдиницаИзмерения) Тогда
            НайтиВнутреннийКодТовара(Ссылка, Справочники.ХарактеристикиНоменклатуры.ПустаяСсылка(), БазоваяЕдиницаИзмерения, Истина);
        ИначеЕсли ВыгружатьВВесы И (Не ИспользоватьХарактеристикиНоменклатуры ИЛИ Не ОбязательноеЗаполнениеХарактеристикиНоменклатуры) И ЗначениеЗаполнено(БазоваяЕдиницаИзмерения) Тогда
            НайтиВнутреннийКодТовара(Ссылка, Справочники.ХарактеристикиНоменклатуры.ПустаяСсылка(), БазоваяЕдиницаИзмерения, Истина);
        КонецЕсли;

        Если ЭтоНовый() Тогда

            МенеджерЗаписи = РегистрыСведений.ПараметрыНоменклатуры.СоздатьМенеджерЗаписи();
            МенеджерЗаписи.Период                       = Дата(1980, 1, 1);
            МенеджерЗаписи.Номенклатура                 = Ссылка;
            МенеджерЗаписи.ЦенаЗадаетсяНаХарактеристику = Ложь;
            МенеджерЗаписи.Записать();

        Иначе

            Отбор = Новый Структура("Номенклатура", Ссылка);

            ТаблицаЗаписей = РегистрыСведений.ПараметрыНоменклатуры.СрезПоследних(ТекущаяДата(), Отбор);

            Если ТаблицаЗаписей.Количество() = 0 Тогда

                МенеджерЗаписи = РегистрыСведений.ПараметрыНоменклатуры.СоздатьМенеджерЗаписи();
                МенеджерЗаписи.Период                       = Дата(1980, 1, 1);
                МенеджерЗаписи.Номенклатура                 = Ссылка;
                МенеджерЗаписи.ЦенаЗадаетсяНаХарактеристику = Ложь;
                МенеджерЗаписи.Записать();

            КонецЕсли;

        КонецЕсли;

    ИначеЕсли ЭтоГруппа И НЕ ОбменДанными.Загрузка Тогда

        МаксУровень    = ГлубинаСправочникаНоменклатура();
        ТекущийУровень = Ссылка.Уровень();

        Если ТекущийУровень >= МаксУровень Тогда

            СтруктураСохранения = Новый Структура;
            СтруктураСохранения.Вставить("МаксУровень",    ТекущийУровень + 1);
            СтруктураСохранения.Вставить("ДатаСохранения", НачалоДня(ТекущаяДата()));

            СохранитьЗначениеКонф("ГлубинаСправочникаНоменклатура", СтруктураСохранения, Истина);

        КонецЕсли;

    КонецЕсли;

КонецПроцедуры

// Обработчик события ПриУстановкеНовогоКода объекта.
//
Процедура ПриУстановкеНовогоКода(СтандартнаяОбработка, Префикс)

    НеобходимостьПроверкиДиапазона(ЭтотОбъект, СтатусПроверкиДиапазона);
    Если СтатусПроверкиДиапазона.ПоискКодаВДиапозоне Тогда

        ПолучитьКодИзДиапазона(Ложь, Истина, Истина);
        СтандартнаяОбработка = Ложь;

    КонецЕсли;

КонецПроцедуры

Функция ПроверитьКорректностьКатегорииТовараДляТабака()

    Запрос = Новый Запрос;
    Запрос.Текст =  "ВЫБРАТЬ
                    |    НазначенияСвойствОбъектов.Свойство
                    |ИЗ
                    |    РегистрСведений.НазначенияСвойствОбъектов КАК НазначенияСвойствОбъектов
                    |ГДЕ
                    |    НазначенияСвойствОбъектов.Объект = &КатегорияТовара
                    |    И НазначенияСвойствОбъектов.ОбязательноеЗаполнение
                    |    И НазначенияСвойствОбъектов.Свойство = ЗНАЧЕНИЕ(ПланВидовХарактеристик.СвойстваОбъектов.МРЦ)";
    Запрос.УстановитьПараметр("КатегорияТовара", КатегорияТовара);
    Результат = Запрос.Выполнить();
    Если Результат.Пустой() Тогда
        Возврат Ложь;
    Иначе
        Возврат Истина;
    КонецЕсли;

КонецФункции