ПоказатьВопрос() и проведение документа

Доброго дня Коллеги!
Предлагаю решение по ветке:

http://forum-mista.pro/topic.php?id=781806#0

Платформа: 1С:Предприятие 8.3 (8.3.9.2170)
Режим совместимости: Версия 8.2.13
Работает в обычном приложении и в управляемом (не модально)
Форма управляемая.

Если есть более интересное предлагайте:

&НаКлиенте
Перем РешилиПроводить;

&НаКлиенте
Перем ЗакрытьПослеПроведения;

// Переопределение стандартной команды т.к. не нашел
// возможности перехватить событие нажатия кнопки
// "ПровестиИЗакрыть"
&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
ЭтаФорма.КоманднаяПанель.ПодчиненныеЭлементы.ФормаПровестиИЗакрыть.ИмяКоманды = "ПровестиИЗакрытьЛокальная";
КонецПроцедуры

&НаКлиенте
Процедура ПровестиИЗакрытьЛокальная(Команда)
    Записать(Новый Структура("РежимЗаписи",РежимЗаписиДокумента.Проведение));
    ЗакрытьПослеПроведения = Истина;
КонецПроцедуры

&НаКлиенте
Процедура ПередЗаписью(Отказ, ПараметрыЗаписи)
    Если ПараметрыЗаписи.РежимЗаписи = РежимЗаписиДокумента.Проведение Тогда
        Если РешилиПроводить = Неопределено Тогда
            Отказ = Истина;
            ПоказатьВопрос(Новый ОписаниеОповещения("ВопросПередЗаписьюЗавершение", ЭтаФорма), "Текст вопроса?",РежимДиалогаВопрос.ДаНет);
        Иначе
            РешилиПроводить = Неопределено;
        КонецЕсли;
    КонецЕсли;
КонецПроцедуры

&НаКлиенте
Процедура ВопросПередЗаписьюЗавершение(РезультатВопроса, ДополнительныеПараметры) Экспорт
    Если РезультатВопроса = КодВозвратаДиалога.Да Тогда
        РешилиПроводить = Истина;
        Записать(Новый Структура("РежимЗаписи",РежимЗаписиДокумента.Проведение));
        Если ЗначениеЗаполнено(ЗакрытьПослеПроведения) и ЗакрытьПослеПроведения Тогда
            Закрыть();
        КонецЕсли;
    КонецЕсли;
КонецПроцедуры