Есть ТаблицаЗначений в ней 2 колонки, одна Пометка тип Булево, вторая имя документа, делаю обход этой таблицы с удалением строк где Пометка = Ложь, но в результате выполнения кода все равно получаю таблицу без изменении. Пните:)
Для каждого Стр Из ТЗ Цикл
    Если Стр.Пометка = Ложь Тогда
        ТЗ.Удалить(Стр);
    КонецЕсли;
КонецЦикла;
    
ДокиРезультат = ТЗ.Скопировать();

т.е. в таблице ДокиРезультат должен получить все доки у которых пометка = Истина

(0) Через одну скорее удаляет а не "все равно получаю таблицу без изменении"

возможно выборка сбивается "Для каждого Стр Из ТЗ Цикл" после первого удаления. Либо обходи по индексу, либо "найтистроки" - а дальше "для каждого"

(0) Не смущает, что ТЗ после удаления изменится?

КУдалению = ТЗ.Найтистроки(Новый Структура("Пометка", Ложь));
Для каждого Стр Из КУдалению  Цикл
    ТЗ.Удалить(Стр);
КонецЦикла;

(5) получилось, через НайтиСтроки

общий подход такой..., но можно проще как в (5)

мУдалить = Новый Массив;

Для каждого Стр Из ТЗ Цикл
    Если Стр.Пометка = Ложь Тогда
        мУдалить.Добавить(Стр);
    КонецЕсли;
КонецЦикла;

Для каждого Стр Из мУдалить Цикл
    ТЗ.Удалить(Стр);
КонецЦикла;

(6) еще лучше
ДокиРезультат = ТЗ.Скопировать(Новый Структура("Пометка", Истина));
))))

(8) лаконичнее:-)

(9) слегка

Или через цикл с Конца.
сч=Тз.КоличествоСтрок()-1;

Пока сч>-1 Цикл
  стр=Тз[сч];

Если Стр.Пометка Тогда
ТЗ.Удалить(Стр);
КонецЕсли;
сч=сч-1;
КонецЦикла

Либо  http://catalog.mista.ru/public/371762/

Функция НайтиПоУсловию(Тз,Условие,Список="",Модуль="") Экспорт
Массив = новый массив;
Для каждого Стр из Тз Цикл
   Если Вычислить(Условие) Тогда
     массив.Добавить(стр)
   КонецЕсли
КонецЦикла;
возврат массив
КонецФункции

Функция НайтиПоУсловию(Тз,Условие,Список="",Модуль="") Экспорт
Массив = новый массив;
Для каждого Стр из Тз Цикл
   Если Вычислить(Условие) Тогда
     массив.Добавить(стр)
   КонецЕсли
КонецЦикла;
возврат Тз.Скопировать(массив)
КонецФункции

Где
// Примеры использования
//тз=НайтиПоУсловию(тз,"Стр.Колонка1<20 и Стр.Колонка2>500");
//  или
//Список=ОбщегоНазначение.РазложитьСтрокуВМассивПодстрок("Иванов,Сидоров,Петров");

//Рез=НайтиПоУсловию(тз,"Список.Найти(стр.ФизЛицо)<>Неопределено");

//Или

//Рез=НайтиПоУсловию(тз,"Найти(Врег(стр.Значение),Врег(""акф""))>0");

//Рез=НайтиПоУсловию(тз,"Модуль.ФункцияСравнения(Стр,Список)",МассивСтруктур,ЭтотОбъект);

//То есть в модуле обработки должна быть функция
//  Функция ФункцияСравнения(стр,МассивСтруктур) Экспорт

В твоем случае

тз=НайтиПоУсловию(тз,"Стр.Пометка");

(13) Я предлагаю для решения такой сложной задачи написать внешнюю компоненту. Причем  она должна будет работать и на Линукс, и на x64 и в веб-клиенте на макос. А то вдруг?

Хотя постойте... Кому ж я это пишу? (: