УНФ (1.6.11.83) КУДиР

1С реализовали в УНФ "полноценный" КУДИР (д-р) пару-тройку месяцев назад. И вот подоспел период, открываем и видим картинку маслом - в записях третьего квартала, в самом конце признанные расходы на товар и НДС по нему октябрем. Работа идет с отсрочкой платежа, дата документа - дата оплаты проданного и отгруженного товара.

Если мне не изменяет память, то такая запись должна попадать в 4 квартал, т.к. последним совпало условие оплаты товара поставщику.

Ковыряю конфу, нахожу:

[CODE]
Процедура ВыполнитьФормированиеПоРасходамНаТовары(Организация, ПериодФормирования, Результат, МенеджерВТ)

    ДокументФормирования = Результат.ДокументФормирования;

    Запрос = Новый Запрос;
    Запрос.МенеджерВременныхТаблиц = МенеджерВТ;

    Запрос.Текст =
    "ВЫБРАТЬ
    |    ПартииТоваровОбороты.ДокументПартии,
    |    ПартииТоваровОбороты.ДокументРегистрацииВКУДиР КАК ПервичныйДокумент,
    |    ПартииТоваровОбороты.ДокументРегистрацииВКУДиР.Дата КАК ДатаПервичногоДокумента,
    |    ПартииТоваровОбороты.ДокументРегистрацииВКУДиР.Номер КАК НомерПервичногоДокумента,
    |    СУММА(ПартииТоваровОбороты.СуммаРасход) КАК СуммаРасход,
    |    СУММА(ПартииТоваровОбороты.СуммаНДСРасход) КАК СуммаНДСРасход
    |ПОМЕСТИТЬ ВтОплаченныеПартии
    |ИЗ
    |     РегистрНакопления.ПартииТоваров.Обороты(&НачалоПериода, &ОкончаниеПериода, Регистратор, Организация = &Организация) КАК ПартииТоваровОбороты
    |ГДЕ
    |    НЕ ПартииТоваровОбороты.ДокументПартии ЕСТЬ NULL
    |
    |СГРУППИРОВАТЬ ПО
    |    ПартииТоваровОбороты.ДокументРегистрацииВКУДиР,
    |    ПартииТоваровОбороты.ДокументПартии,
    |    ПартииТоваровОбороты.Регистратор.Дата,
    |    ПартииТоваровОбороты.Регистратор.Номер
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ
    |    ВЫБОР
    |        КОГДА ВтОплаченныеПартии.СуммаРасход > 0
    |            ТОГДА &ПризнаныРасходыНаТовары
    |        ИНАЧЕ &РасходыУменьшенныеОтВозврата
    |    КОНЕЦ КАК Содержание,
    |    СУММА(ВтОплаченныеПартии.СуммаРасход) КАК РасходВсего,
    |    СУММА(ВтОплаченныеПартии.СуммаРасход) КАК РасходБаза,
    |    ВтОплаченныеПартии.ДатаПервичногоДокумента,
    |    ВтОплаченныеПартии.НомерПервичногоДокумента,
    |    ВтОплаченныеПартии.ПервичныйДокумент КАК ПервичныйДокумент
    |ИЗ
    |    ВтОплаченныеПартии КАК ВтОплаченныеПартии
    |ГДЕ
    |    ВтОплаченныеПартии.СуммаРасход <> 0
    |
    |СГРУППИРОВАТЬ ПО
    |    ВтОплаченныеПартии.ПервичныйДокумент,
    |    ВЫБОР
    |        КОГДА ВтОплаченныеПартии.СуммаРасход > 0
    |            ТОГДА &ПризнаныРасходыНаТовары
    |        ИНАЧЕ &РасходыУменьшенныеОтВозврата
    |    КОНЕЦ,
    |    ВтОплаченныеПартии.ДатаПервичногоДокумента,
    |    ВтОплаченныеПартии.НомерПервичногоДокумента
    |
    |ОБЪЕДИНИТЬ ВСЕ
    |
    |ВЫБРАТЬ
    |    ВЫБОР
    |        КОГДА ВтОплаченныеПартии.СуммаНДСРасход > 0
    |            ТОГДА &ПризнаныРасходыНаТоварыНДС
    |        ИНАЧЕ &РасходыУменьшенныеОтВозвратаНДС
    |    КОНЕЦ,
    |    СУММА(ВтОплаченныеПартии.СуммаНДСРасход),
    |    СУММА(ВтОплаченныеПартии.СуммаНДСРасход),
    |    ВтОплаченныеПартии.ДатаПервичногоДокумента,
    |    ВтОплаченныеПартии.НомерПервичногоДокумента,
    |    ВтОплаченныеПартии.ПервичныйДокумент
    |ИЗ
    |    ВтОплаченныеПартии КАК ВтОплаченныеПартии
    |ГДЕ
    |    ВтОплаченныеПартии.СуммаНДСРасход <> 0
    |
    |СГРУППИРОВАТЬ ПО
    |    ВЫБОР
    |        КОГДА ВтОплаченныеПартии.СуммаНДСРасход > 0
    |            ТОГДА &ПризнаныРасходыНаТоварыНДС
    |        ИНАЧЕ &РасходыУменьшенныеОтВозвратаНДС
    |    КОНЕЦ,
    |    ВтОплаченныеПартии.ПервичныйДокумент,
    |    ВтОплаченныеПартии.ДатаПервичногоДокумента,
    |    ВтОплаченныеПартии.НомерПервичногоДокумента
    |
    |УПОРЯДОЧИТЬ ПО
    |    ВтОплаченныеПартии.ДатаПервичногоДокумента";


    Запрос.УстановитьПараметр("НачалоПериода", НачалоКвартала(ПериодФормирования));
    Запрос.УстановитьПараметр("ОкончаниеПериода", ПериодФормирования);
    Запрос.УстановитьПараметр("Организация", Организация);

    Запрос.УстановитьПараметр("ПризнаныРасходыНаТовары", НСтр("ru='Признаны расходы на приобретение товаров'"));
    Запрос.УстановитьПараметр("РасходыУменьшенныеОтВозврата", НСтр("ru='Расходы уменьшены на сумма возвращенных покупателем товаров'"));

    Запрос.УстановитьПараметр("ПризнаныРасходыНаТоварыНДС", НСтр("ru='Признаны расходы на приобретение товаров (НДС)'"));
    Запрос.УстановитьПараметр("РасходыУменьшенныеОтВозвратаНДС", НСтр("ru='Расходы уменьшены на сумму возвращенных покупателем товаров (НДС)'"));

    РезультатЗапроса = Запрос.Выполнить().Выгрузить();
    Если ДокументФормирования = Неопределено И РезультатЗапроса.Количество() > 0 Тогда
        ДокументФормирования = Документы.ЗаписиУСН.СоздатьДокумент();
        ДокументФормирования.Дата = ПериодФормирования;
        ДокументФормирования.Организация = Организация;
        ДокументФормирования.ВидЗаписей = Перечисления.ВидыЗаписейФормированийКУДиР.РасходыНаТовары;
    КонецЕсли;
    Если ДокументФормирования <> Неопределено Тогда

        ДокументФормирования.ЗаписиКУДиР.Загрузить(РезультатЗапроса);
        Для Каждого СтрокаКУДиР ИЗ ДокументФормирования.ЗаписиКУДиР Цикл
            СтрокаКУДиР.НомерПервичногоДокумента =  ПрефиксацияОбъектовКлиентСервер.НомерНаПечать(СтрокаКУДиР.НомерПервичногоДокумента, Истина, Истина);
        КонецЦикла;


        Результат.ДополнительнаяИнформация = НСтр("ru='Сформировано записей: '") + Строка(ДокументФормирования.ЗаписиКУДиР.Количество());
        ДокументФормирования.Записать(РежимЗаписиДокумента.Проведение);
        Результат.ДокументФормирования = ДокументФормирования.Ссылка;
    КонецЕсли;

    Запрос.Текст = "
    |УНИЧТОЖИТЬ ВтОплаченныеПартии;";
    Запрос.Выполнить();

КонецПроцедуры

[/CODE]

WTF? Может мне персонально кривая конфа досталась? Или тут что-то с трактовкой закона не так? HELP )))