Добрый день.
В документе есть две табличные части на форме. Одну из них требуется заполнить по тарифам вот такой вот процедурой, вызываемой из команды.  Запрос данные собирает верно, но заполнения при этом не происходит. При этом ошибок никаких не выдает. Может, сможете посоветовать?
&НаСервере
Процедура ЗаполнитьСуммыПоТарифуПрочееПаллетыНаСеpвере()
    
    Запрос = Новый Запрос;
    Запрос.Текст = "ВЫБРАТЬ
                   |    ЕСТЬNULL(СкладскиеУслугиПрочееПаллеты.КоличествоОтгруженныхПаллет, 0) КАК КоличествоОтгруженныхПаллет,
                   |    ЕСТЬNULL(ЕСТЬNULL(СкладскиеУслугиПрочееПаллеты.КоличествоОтгруженныхПаллет, 0) * ЕСТЬNULL(ТарифнаяСеткаКЛУОтгрузкаСрезПоследних.ТарифПаллет, 0), 0) КАК СуммаЗатратПоТарифу,
                   |    ЕСТЬNULL(ТарифнаяСеткаКЛУОтгрузкаСрезПоследних.ТарифПаллет, 0) КАК ТарифПаллет
                   |ИЗ
                   |    Документ.СкладскиеУслуги.ПрочееПаллеты КАК СкладскиеУслугиПрочееПаллеты
                   |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ТарифнаяСеткаКЛУОтгрузка.СрезПоследних(&Период, ) КАК ТарифнаяСеткаКЛУОтгрузкаСрезПоследних
                   |        ПО СкладскиеУслугиПрочееПаллеты.Ссылка.Склад = ТарифнаяСеткаКЛУОтгрузкаСрезПоследних.Склад
                   |ГДЕ
                   |    СкладскиеУслугиПрочееПаллеты.Ссылка = &ТекущееКЛУ";
    
    Запрос.УстановитьПараметр("ТекущееКЛУ", Объект.Ссылка);
    Запрос.УстановитьПараметр("Период", Объект.Месяц);
    Выборка = Запрос.Выполнить().Выбрать();
    Если Выборка.Следующий() Тогда
        Если Выборка.ТарифПаллет = 0 Тогда
            Сообщение = "Не задан тариф на отгрузку транзитных паллет для " + Объект.Склад + " на " + Объект.Месяц;
            Сообщить(Сообщение);
        Иначе
            Выборка.Сбросить();
            Пока Выборка.Следующий() Цикл
                Для Каждого Стр из Объект.ПрочееПаллеты Цикл
                    Стр.СуммаЗатратПоТарифу = Выборка.СуммаЗатратПоТарифу;
                КонецЦикла;
            КонецЦикла;
        КонецЕсли;
    КонецЕсли;
    
КонецПроцедуры

Впервые за много лет вижу использование "Выборка.Сбросить()"

Ну, мне требуется проверить первую строку, если она не 0, то можно продолжать. Не имеет смысла в цикле крутить эту проверку.

Ибо Тариф одинаковый для всех строк, если он задан.
Можно еще просто первую строку выбирать, но с моим знанием 1С пока не получилось.)

(2) это можно сделать и в цикле Пока Выборка.Следующий()
и если она равна 0 - то Прервать;

+ (4) если она равна = если тариф равен

(0) если честно -смущает код

Пока Выборка.Следующий() Цикл
  Для Каждого Стр из Объект.ПрочееПаллеты Цикл
    Стр.СуммаЗатратПоТарифу = Выборка.СуммаЗатратПоТарифу;
  КонецЦикла;
КонецЦикла;

почему ты думаешь, что у тебя порядок строк в ТЧ документа и порядок строк в выборке - совпадают?

Объект.ПрочееПаллеты случайно не пустая ТЧ?

(0) Типы значения проверял?
может быть не совпадают?

Прервать использовать не могу, там дальше еще один запрос, поэтому пришлось так.

ПрочееПаллеты заполненная ТЧ, в запросе все считается верно и выводится в три столбца, как и должно быть. Порядок строк в ТЧ документа и выборке совпадают (по крайней мере судя по запросу).

Типы значений везде Число, на всякий случай проверил.

Даже если убрать проверку на 0 значение, все равно такая же картина.

Да, второй запрос пока закомментировал, чтобы исключить влияние.

я как всмотрелся в код, так волосы зашевелились...
нафига цикл в цикле?
бери первый попавшийся ТарифПаллет, 1 раз проходи тч и в этом проходе все считай:
Стр.СуммаЗатратПоТарифу = стр.КоличествоОтгруженныхПаллет*ТарифПаллет;

(11) + если это сложно тебе для понимания, то делай так:
    Если Выборка.Следующий() Тогда
        Если Выборка.ТарифПаллет = 0 Тогда
            Сообщение = "Не задан тариф на отгрузку транзитных паллет для " + Объект.Склад + " на " + Объект.Месяц;
            Сообщить(Сообщение);
        Иначе
            ТарифПаллет = Выборка.ТарифПаллет;
            Для Каждого Стр из Объект.ПрочееПаллеты Цикл
                Стр.СуммаЗатратПоТарифу = стр.КоличествоОтгруженныхПаллет*ТарифПаллет;
            КонецЦикла;
        КонецЕсли;
    КонецЕсли;

(9) Прервать прерывает не процедуру а цикл, в котором он используется

Так, спасибо огромное за советы, пойду пробовать.
Я только учусь, так что не обессудьте.)

(12) да, так будет гораздо правильнее

да и с самим тарифом можно запрос не городить,а использовать

Отбор  = Новый Структура("Склад",Объект.Склад);

ТаблицаСреза= РегистрыСведений.ТарифнаяСеткаКЛУОтгрузка.СрезПоследних(Объект.Месяц, Отбор);

Если ТаблицаСреза.Количество()=0 Тогда Сообщить("Низя!")
Иначе Тариф = ТаблицаСреза[0].ТарифПаллет Конец

(0) Выборка.СуммаЗатратПоТарифу = 0 ИМХО

dezss, тебе отдельное спасибо, поправил так, как ты порекомендовал, все считается. Я просто читал, что в запросе проще сразу подсчитывать.