Доброго времени, уважаемые!

Подскажите, ка в обработке сделать так, чтобы как у отчета можно было вывести элементы отбора в быстром доступе.

Сейчас сделано через таблицу, у которой путь данных = КомпоновщикНастроек.Настройки.Отбор.

Заранее благодарю!

Посмотри общую форму отчета у любой типовой на БСП

Таблица с источником-компоновщиком никакие быстрые отборы не умеет

У меня УПП на УФ

Я вроде не спрашивал, чего там у тебя

)) Спасибо
Читать и читать в этой форме...

Ох, пните еще раз в нужную сторону!

смотрю в ЗУП 3.1:
            
ПолеВвода = Элементы.Добавить(ЗначениеИмя, Тип("ПолеФормы"), Группа);
ПолеВвода.Вид                = ВидПоляФормы.ПолеВвода;
ПолеВвода.Заголовок          = СвойстваНастройки.Представление;
ПолеВвода.ПоложениеЗаголовка = ПоложениеЗаголовкаЭлементаФормы.Нет;

Если СтрДлина(СвойстваНастройки.Представление) > 40 Тогда // Если заголовок существенно длиннее остальных заголовков, переносим его.
    ПолеВвода.ВысотаЗаголовка = 2;
КонецЕсли;
            
// Связь с СКД.
ПолеВвода.ПутьКДанным = Прочее.ПутьККомпоновщику + ".ПользовательскиеНастройки[" + СвойстваНастройки.ИндексВКоллекции + "].Значение";

Я по аналогии пишу:

НовыйЭлемент = Элементы.Добавить("Сеть1", Тип("ПолеФормы"),);
НовыйЭлемент.Вид         = ВидПоляФормы.ПолеВвода;
НовыйЭлемент.Заголовок   = "Сеть1";

НовыйЭлемент.ПутьКДанным = "КомпоновщикНастроекФормы.ПользовательскиеНастройки.Элементы[0].Значение";
НовыйЭлемент.ПоложениеЗаголовка = ПоложениеЗаголовкаЭлементаФормы.Право;

Но получаю ошибку:
{ВнешняяОбработка.ЗагрузкаЧерезЗагрузочныйФайл.Форма.ФормаУправляемая.Форма(182)}: Ошибка при установке значения атрибута контекста (ПутьКДанным)
        Флажок.ПутьКДанным = "КомпоновщикНастроекФормы.ПользовательскиеНастройки.Элементы[0].Значение";
по причине:
Недопустимое значение

ЧЯДНТ?

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
    ИнициализироватьОтбор();
    ДобавлениеЭлементов();
КонецПроцедуры

&НаСервере
Процедура ИнициализироватьОтбор()
    Обработка =  РеквизитФормыВЗначение("Объект");
    СхемаКомпоновкиДанных = Обработка.ПолучитьМакет("СхемаКомпоновкиДанных");
    Настройки = СхемаКомпоновкиДанных.ВариантыНастроек.Основной.Настройки;
    КомпоновщикНастроек = Новый КомпоновщикНастроекКомпоновкиДанных;
    
    АдресСхемы = ПоместитьВоВременноеХранилище(СхемаКомпоновкиДанных);
    КомпоновщикНастроек.Инициализировать(Новый ИсточникДоступныхНастроекКомпоновкиДанных(АдресСхемы));
    КомпоновщикНастроек.ЗагрузитьНастройки(Настройки);
    КомпоновщикНастроекФормы = КомпоновщикНастроек;
КонецПроцедуры


А выше изложенное художество в процедуре ДобавлениеЭлементов()

В отладке смотреть надо, что по твоему пути к данным есть данные

Есть данные - смотрела. Поэтому и пишу то, где есть значение.

КомпоновщикНастроекФормы.ПользовательскиеНастройки.Элементы[0] = ЗначениеПараметраНастроекКомпоновкиДанных

В (10) так-то не то, на что указывает путь к данным

(11) Ладно, спасибо, добрый человек! Подумаю посижу, что не так. Главное, чтобы направление верное было...

(12) Ну ладно, подскажу еще: у таблицы формы есть свойство "Режим отображения" = "Быстрый доступ"

(13) Это первое, что сделала)) - нифига нет быстрого доступа!

Может к этому свойству еще какая-нибудь хитрость есть?

Может. Но это уже надо смотреть, проверять, брать и пробовать

(17) "Я сама дошла - на лыжах!" А не работает это свойство по той причине, что это обработка, а не отчет.

Всё! Я это сделала!

&НаСервере
Процедура ДобавлениеЭлементов()
    инд = 0;
    
    Для каждого ЭлементОтбора из КомпоновщикНастроекФормы.Настройки.Отбор.Элементы цикл
        Группа = Элементы.Добавить("Группа" + СокрЛП(ЭлементОтбора.ЛевоеЗначение), Тип("ГруппаФормы"), Элементы.ГруппаОтбора);
        Группа.Вид                 = ВидГруппыФормы.ОбычнаяГруппа;
        Группа.Отображение         = ОтображениеОбычнойГруппы.Нет;
        //Группа.Заголовок           = "Группа";
        Группа.ОтображатьЗаголовок = Ложь;
        Группа.Группировка = ГруппировкаПодчиненныхЭлементовФормы.Горизонтальная;
        
        НовыйЭлемент = Элементы.Добавить("Использование" + ЭлементОтбора.ЛевоеЗначение, Тип("ПолеФормы"), Группа);
        НовыйЭлемент.Вид         = ВидПоляФормы.ПолеФлажка;
        //НовыйЭлемент.Заголовок   = "Использование";
        НовыйЭлемент.ПутьКДанным = "КомпоновщикНастроекФормы.Настройки.Отбор[" + инд + "].Использование";
        НовыйЭлемент.ПоложениеЗаголовка = ПоложениеЗаголовкаЭлементаФормы.Нет;
        
        НовыйЭлемент = Элементы.Добавить("Параметр" + ЭлементОтбора.ЛевоеЗначение, Тип("ПолеФормы"), Группа);
        НовыйЭлемент.Вид         = ВидПоляФормы.ПолеВвода;
        //НовыйЭлемент.Заголовок   = "Параметр";
        НовыйЭлемент.ПутьКДанным = "КомпоновщикНастроекФормы.Настройки.Отбор[" + инд + "].ЛевоеЗначение";
        НовыйЭлемент.ПоложениеЗаголовка = ПоложениеЗаголовкаЭлементаФормы.Нет;
        
        НовыйЭлемент = Элементы.Добавить("ВидСравнения" + ЭлементОтбора.ЛевоеЗначение, Тип("ПолеФормы"), Группа);
        НовыйЭлемент.Вид         = ВидПоляФормы.ПолеВвода;
        //НовыйЭлемент.Заголовок   = "ВидСравнения";
        НовыйЭлемент.ПутьКДанным = "КомпоновщикНастроекФормы.Настройки.Отбор[" + инд + "].ВидСравнения";
        НовыйЭлемент.ПоложениеЗаголовка = ПоложениеЗаголовкаЭлементаФормы.Нет;
        
        НовыйЭлемент = Элементы.Добавить("Значение" + ЭлементОтбора.ЛевоеЗначение, Тип("ПолеФормы"), Группа);
        НовыйЭлемент.Вид         = ВидПоляФормы.ПолеВвода;
        //НовыйЭлемент.Заголовок   = "Значение";
        НовыйЭлемент.ПутьКДанным = "КомпоновщикНастроекФормы.Настройки.Отбор[" + инд + "].ПравоеЗначение";
        НовыйЭлемент.ПоложениеЗаголовка = ПоложениеЗаголовкаЭлементаФормы.Нет;
        
        инд = инд + 1;
    КонецЦикла;
КонецПроцедуры

Выражаю благодарность Cyberhawk за направление в нужное русло!

О, гуру! Продолжаю разбираться. Помогите опытом или советом!

Есть элемент отбора СКД типа ПеречислениеСсылка.ТакоеТо, который разместила на форме. Мне нужно органичить список выбора элемента с учетом того, что возможен вид сравнения в списке. Задать в схеме не могу, т.к. состав списка задается по определенным условиям.

Делаю:

    СписокСостояний = Новый СписокЗначений;
    ЗаполнитьСписокСостояний(СписокСостояний);
    КомпоновщикНастроекФормы.Настройки.Отбор.ДоступныеПоляОтбора.Элементы[8].ДоступныеЗначения = СписокСостояний;

Это делаю при инициализации в процедуре ИнициализироватьОтбор(). Но при НачалеВыбора проверяю отладчиком ДоступныеЗначения выше указанного элемента, а там опять Неопределено.

Как можно реализовать необходимое мне органичение?

(20) нужно у элемента формы делать

(21) Хорошо, для ВидСравнения "Равно" я могу это следать, даже пробовала. А вот как быть, когда нужно ВидСравнения "В списке"?

(22) У элемента формы, огладываясь на текущий вид сравнения

Я не догоняю чего-то...

Если я поставлю ВидСравнения "В списке", например, то открывается типовой подбор в список значений.

Мне подменять форму выбора?

(24) А что должно быть?

Ну, так там мне тоже нужно, чтобы при подборе значений в список значений давался ограниченный вариант.

В моём представлении, как-то надо на начальном этапе в настройки схемы запихивать ограничение, а в элементе, связанном с настройками схемы, должно автоматом отрабатывать ограничение.
Или у меня слишком фантазийное представление?))

Решение череззад, но пока так...

В моем случае создаю две одинаковые схемы, в которых для нужного поля устанавливаю в самой схеме доступные значения.
А в зависимости от моих условий, я получаю настройки нужной схемы.

Буду очень благодарна, если есть у кого опыт программной установки ДоступныхЗначений, поделится вариантом решения.

может в зависимости от условий саму схему корректировать?

те при изменяем схему и переинициализируем компоновщик

Мне, в принципе, достаточно при открытии заполнить КомпоновщикНастроек, т.к. элементы его отбора добавляются программно на форму, чтобы пользователю красиво было и наглядно. Они ж у нас ранимые создания!

&НаСервере
Процедура ИнициализироватьОтбор()
    РольДоступна_КорректировкаЗакрытия = РольДоступна("КорректировкаЗакрытия");
    
    //Нужно для реализации ограничения списка выбора для реквизита Состояние
    ИмяМакетаСКД = ?(РольДоступна_КорректировкаЗакрытия, "СхемаКомпоновкиДанных_КорректировкаЗакрытия", "СхемаКомпоновкиДанных");
        
    Обработка =  РеквизитФормыВЗначение("Объект");
    
    СхемаКомпоновкиДанных = Обработка.ПолучитьМакет(ИмяМакетаСКД);
    Настройки = СхемаКомпоновкиДанных.ВариантыНастроек.Основной.Настройки;
    КомпоновщикНастроек = Новый КомпоновщикНастроекКомпоновкиДанных;
    АдресСхемы = ПоместитьВоВременноеХранилище(СхемаКомпоновкиДанных);
    КомпоновщикНастроек.Инициализировать(Новый ИсточникДоступныхНастроекКомпоновкиДанных(АдресСхемы));
    КомпоновщикНастроек.ЗагрузитьНастройки(Настройки);
    КомпоновщикНастроекФормы = КомпоновщикНастроек;
КонецПроцедуры

А почему кстати используется обработка, а не отчет? Это какая-то типовая обработка, которую потребовалось доработать?

Разработка по тз. Я не всё могу оспорить

Так зачем оспаривать - просто спроси, мол, чем думал постановщик

(35) Дайте мне испытательный срок пройти!))  Зато с такой постановкой я для себя много нового отрыла))

Я, конечно, спрашивала, вернее говорила, что вот если бы это сделать как отчет, то проблем было бы меньше. На что мне ответили, что какая разница между отчетом и обработкой - одно и то же, делай по ТЗ. Слушаю и временно повинуюсь.

Ясно. Срок, значит, срок )