Добрый день.

УПП, РАУЗ.

Формирую ведомость по учету МПЗ. Одна позиция выходит минусом.
Начальный остаток 2, приход 0, расход 24, конечный остаток -22.

По товарам на складах минусов нет.

Отрицательные остатки идут только по регистру учет затрат бух. учет.

Отчего это может быть?
Как отследить всю цепочку и исправить расхождения?

УПП 1.3 последняя версия.

(0)[Как отследить всю цепочку и исправить расхождения? ]
отдельная наука
ищи на инофстарте статьи как правильно настроить отчеты по разделам учета

(1) находил, по аналитика детализация, я так исправляю расхождения по движению МПЗ и затрат, милое дело )))

и отрицательные остатки, на которые ругается расчет себестоимости я исправил, а вот МПЗ с минусом еще не победил ((((

Смотри товары на складах по документам. И сравни документы которые попали в товары на складах с документами которые попали в МПЗ

Скорее всего в каком то из документов (или поступление или перемещение) забыли установить отражение в БУ и НУ (стоит только УУ)

(5) вот я тоже грешу на перемещения, у меня по некоторым перемещениям вообще затраты бухг. учет нет движений.

Завтра еще проверю, отпишусь )))
Спасибо за совет! )

Просмотрел отчеты по разделам учета.
Все ошибки легко выявляются при детализации по аналитикам.

1. Сначала смотрим ведомость по учету МПЗ.
Детализация по номенклатуре и регистратору. Количество < 0 в отборе. Смотрим, по каким позициям есть отрицательные остатки МПЗ.

2. Далее Смотрим движения по МПЗ и затратам.
Отчеты - Расширенная аналитика учета - Анализ движения МПЗ и затрат. Делаем отбор по затрате (номенклатура, которая в минусе по п.1). Выставляем детализацию по аналитикам учета:
Раздел учета
Аналитика вида учета
Аналитика распределения затрат
Аналитика учета затрат
Регистратор
Данные отобразятся в виде иерархической структуры. Смотрим на структуру и если есть ошибки, то их сразу будет видно: ошибки в заполнении документов => расхождения по аналитикам. Исправляем ошибки, затраты и МПЗ выравниваются, отрицательные остатки уходят.
Какие у меня были ошибки:
а) неверно задано подразделение организации
б) неверно задан счет учета БУ
в) неверное количество в учете затрат (разные данные по отчету производства за смену и требованием накладной).

Как-то так ;)
Может кому пригодится ;)

Для отлавливания отрицательных остатков при расчете с/с я просто скопировал с общего модуля запрос, который находит отрицательные остатки и чуть его доработал (чтобы отображались аналитики, а не только раздел учета). В последнее время у меня такие расхождения только из-за неверных подразделений организаций в производственных документах. Исправляется подразделение, перепроводится документ - отрицательные остатки уходят.

Сам запрос:
ВЫБРАТЬ
    АналитикаВидаУчета.Ссылка,
    АналитикаВидаУчета.РазделУчета
ПОМЕСТИТЬ ОтборАналитикаВидаУчета
ИЗ
    РегистрСведений.АналитикаВидаУчета КАК АналитикаВидаУчета
ГДЕ
    АналитикаВидаУчета.РазделУчета <> ЗНАЧЕНИЕ(Перечисление.РазделыУчета.ПогашеннаяСтоимость)
    И АналитикаВидаУчета.РазделУчета <> ЗНАЧЕНИЕ(Перечисление.РазделыУчета.Выпуск)
    И АналитикаВидаУчета.Организация = &Организация
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ОтборАналитикаВидаУчета.Ссылка
ПОМЕСТИТЬ ОтборРазделУчетаЗатраты
ИЗ
    ОтборАналитикаВидаУчета КАК ОтборАналитикаВидаУчета
ГДЕ
    (ОтборАналитикаВидаУчета.РазделУчета = ЗНАЧЕНИЕ(Перечисление.РазделыУчета.Затраты)
            ИЛИ ОтборАналитикаВидаУчета.РазделУчета = ЗНАЧЕНИЕ(Перечисление.РазделыУчета.ЗатратыНаВыпуск))
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    УчетЗатрат.АналитикаВидаУчета,
    УчетЗатрат.АналитикаУчетаЗатрат,
    УчетЗатрат.АналитикаУчетаПартий,
    УчетЗатрат.АналитикаРаспределенияЗатрат,
    СУММА(УчетЗатрат.Количество) КАК Количество
ПОМЕСТИТЬ ВозвратныеОтходы
ИЗ
    РегистрНакопления.УчетЗатратРегл КАК УчетЗатрат
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ ОтборРазделУчетаЗатраты КАК ОтборРазделУчетаЗатраты
        ПО УчетЗатрат.АналитикаВидаУчета = ОтборРазделУчетаЗатраты.Ссылка
ГДЕ
    УчетЗатрат.КодОперации = ЗНАЧЕНИЕ(Перечисление.КодыОперацийЗатратыНаВыпускПродукции.ОтрицательныеЗатраты)
    И УчетЗатрат.Активность
    И УчетЗатрат.Период МЕЖДУ &ДатаНачалаПериода И &ДатаКонцаПериода
    И УчетЗатрат.ВидДвижения = ЗНАЧЕНИЕ(ВидДвиженияНакопления.Приход)

СГРУППИРОВАТЬ ПО
    УчетЗатрат.АналитикаВидаУчета,
    УчетЗатрат.АналитикаУчетаЗатрат,
    УчетЗатрат.АналитикаУчетаПартий,
    УчетЗатрат.АналитикаРаспределенияЗатрат
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    УчетЗатратОстатки.АналитикаВидаУчета,
    УчетЗатратОстатки.АналитикаУчетаЗатрат,
    УчетЗатратОстатки.АналитикаУчетаПартий,
    УчетЗатратОстатки.АналитикаРаспределенияЗатрат,
    УчетЗатратОстатки.КоличествоОстаток КАК Количество
ПОМЕСТИТЬ ОтрицательныеОстатки
ИЗ
    РегистрНакопления.УчетЗатратРегл.Остатки(
            &КонГраница,
            АналитикаВидаУчета В
                (ВЫБРАТЬ
                    ОтборАналитикаВидаУчета.Ссылка
                ИЗ
                    ОтборАналитикаВидаУчета КАК ОтборАналитикаВидаУчета)) КАК УчетЗатратОстатки
ГДЕ
    УчетЗатратОстатки.КоличествоОстаток < 0
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ
    ОтборАналитикаВидаУчета.РазделУчета КАК РазделУчета,
    ОтрицательныеОстатки.АналитикаВидаУчета,
    ОтрицательныеОстатки.АналитикаУчетаЗатрат,
    ОтрицательныеОстатки.АналитикаРаспределенияЗатрат,
    ОтрицательныеОстатки.Количество
ИЗ
    ОтрицательныеОстатки КАК ОтрицательныеОстатки
        ЛЕВОЕ СОЕДИНЕНИЕ ВозвратныеОтходы КАК ВозвратныеОтходы
        ПО ОтрицательныеОстатки.АналитикаВидаУчета = ВозвратныеОтходы.АналитикаВидаУчета
            И ОтрицательныеОстатки.АналитикаУчетаЗатрат = ВозвратныеОтходы.АналитикаУчетаЗатрат
            И ОтрицательныеОстатки.АналитикаУчетаПартий = ВозвратныеОтходы.АналитикаУчетаПартий
            И ОтрицательныеОстатки.АналитикаРаспределенияЗатрат = ВозвратныеОтходы.АналитикаРаспределенияЗатрат
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ ОтборАналитикаВидаУчета КАК ОтборАналитикаВидаУчета
        ПО ОтрицательныеОстатки.АналитикаВидаУчета = ОтборАналитикаВидаУчета.Ссылка
ГДЕ
    ОтрицательныеОстатки.Количество < ЕСТЬNULL(ВозвратныеОтходы.Количество, 0)

УПОРЯДОЧИТЬ ПО
    РазделУчета

Как-то странно сайт коды парсит :)
Разрывает запрос на несколько