Здравствуйте  друзья.
Есть запроса подбора остатков, который выполняется очень долго. Около 3-4 секунд.
        ВЫБРАТЬ ПЕРВЫЕ 200
            Номен.Ссылка КАК Номенклатура,
            ТоварыНаСкладахОстатки.Характеристика КАК Серия,
            ТоварыНаСкладахОстатки.КоличествоОстаток КАК Остаток,
            ЦеныНоменклатурыСрезПоследних.Цена КАК Цена
        ИЗ
            Справочник.Номенклатура КАК Номен
                ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ТоварыНаСкладах.Остатки(, Склад = &РозничныйСклад) КАК ТоварыНаСкладахОстатки
                    ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры.СрезПоследних(, ВидЦены = &Розничная) КАК ЦеныНоменклатурыСрезПоследних
                    ПО ТоварыНаСкладахОстатки.Характеристика = ЦеныНоменклатурыСрезПоследних.Характеристика
                ПО Номен.Ссылка = ТоварыНаСкладахОстатки.Характеристика.Владелец
        ГДЕ
           Номен.НАИМЕНОВАНИЕ ПОДОБНО "%" + &СтрокаПоиска + "%"
        УПОРЯДОЧИТЬ ПО
            Остаток УБЫВ

Я примерно понимаю в чем дело. Каждый раз у меня при запросе отбираются все цены которые когда либо были и все остатки.
В идеале как то сделать так, чтоб цены и остатки брались только для той номенклатуры которая соответствует условию отбора Номен.НАИМЕНОВАНИЕ ПОДОБНО "%" + &СтрокаПоиска + "%"

Первая мысль задать в параметрых виртуальных таблиц конструкцию вида ВидЦены = &Розничная И Характеристика ВСПИСКЕ &ТаблицаОтобранныхНоменклатур

Ну так сначала отбери номенклатуру в временную таблицу, потом уже её соединяй с остальным...

(0) разбей на временные таблицы
1-товар
2 и 3 - данные по товару
а потом уже соединяй

(0) разнеси по виртуальным таблицам.
а то получатся что сразу выполняется весь запрос а потом уже идет отсечение по твоему условию.

ну и ПОДОБНО - это вообще тормозная штука...

плюс условие ГДЕ на левую таблицу надо в связи выносить
но тут не поможет...

хм..

ВЫБРАТЬ ПЕРВЫЕ 200
    Номен.Ссылка КАК Номенклатура,
    ТоварыНаСкладахОстатки.Характеристика КАК Серия,
    ТоварыНаСкладахОстатки.КоличествоОстаток КАК Остаток,
    ЦеныНоменклатурыСрезПоследних.Цена КАК Цена
ИЗ
    Справочник.Номенклатура КАК Номен
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ТоварыНаСкладах.Остатки(, Склад = &РозничныйСклад И Характеристика.Владелец.Наименование ПОДОБНО "%" + &СтрокаПоиска + "%") КАК ТоварыНаСкладахОстатки
            ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры.СрезПоследних(, ВидЦены = &Розничная И Характеристика.Наименование ПОДОБНО "%" + &СтрокаПоиска + "%") КАК ЦеныНоменклатурыСрезПоследних
            ПО (ТоварыНаСкладахОстатки.Характеристика = ЦеныНоменклатурыСрезПоследних.Характеристика)
        ПО (Номен.Ссылка = ТоварыНаСкладахОстатки.Характеристика.Владелец)
ГДЕ
    Номен.Наименование ПОДОБНО "%" + &СтрокаПоиска + "%"

УПОРЯДОЧИТЬ ПО
    Остаток УБЫВ


Сделал так.. Я гений??

Где условие по номенклатуре при соединении с ценами?
ПОДОБНО - зло

(7) Гений с большой буквы Г

(9) да точноо... туплю под вечер

(2) разве когда я буду создавать ВременныеТаблицы они не будут содержать всех данных?
И ЛЕВОЕ СОЕДИНЕНИЕ опять таки будет по огромному регистру цены..
Но все равно щас попробую

(11) Во временной таблице ты сам регулируешь объём данных, которые в ней хранянтся

Выбери в первом запросе все товары тебе нужные
помести их в виртуальную.
потом
во втором получи остатки и их в виртуальную
потом цены и их в виртуальную.
а итогом запросе склей

(13) ок ща сделаю

(13) ВЫБРАТЬ ПЕРВЫЕ 200
    Номен.Ссылка КАК Номенклатура
ПОМЕСТИТЬ ВрТовары
ИЗ
    Справочник.Номенклатура КАК Номен
ГДЕ
    Номен.Наименование ПОДОБНО "%" + &СтрокаПоиска + "%"
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    Остатки.Характеристика КАК Характеристика,
    Остатки.КоличествоОстаток КАК КоличествоОстаток
ПОМЕСТИТЬ ВрОстатки
ИЗ
    РегистрНакопления.ТоварыНаСкладах.Остатки(&ДатаОстатков, Склад = &РозничныйСклад) КАК Остатки
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    Цены.Характеристика КАК Характеристика,
    Цены.Цена КАК Цена
ПОМЕСТИТЬ ВрЦены
ИЗ
    РегистрСведений.ЦеныНоменклатуры.СрезПоследних(, ВидЦены = &Розничная) КАК Цены
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ВрТовары.Номенклатура КАК Номенклатура,
    ВрОстатки.Характеристика КАК Характеристика,
    ВрОстатки.КоличествоОстаток КАК КоличествоОстаток,
    ВрЦены.Цена КАК Цена
ИЗ
    ВрТовары КАК ВрТовары
        ЛЕВОЕ СОЕДИНЕНИЕ ВрОстатки КАК ВрОстатки
            ЛЕВОЕ СОЕДИНЕНИЕ ВрЦены КАК ВрЦены
            ПО (ВрОстатки.Характеристика = ВрЦены.Характеристика)
        ПО (ВрТовары.Номенклатура = ВрОстатки.Характеристика.Владелец)


___
Переделал прирост не такой большой..
время выполнения  = 1.891с

Зачем вот так
ВрТовары.Номенклатура = ВрОстатки.Характеристика.Владелец

у регистра цен стоит галка итоги по срез послдедних?

(16) ну а как по другому то..

(17) не стоит

ВрТовары.Номенклатура = ВрОстатки.Характеристика.Владелец
поменял на
ВрТовары.Номенклатура = ВрОстатки.Номенклатура

стало еще чуть дольше выполняться 2.54 - 3 сек

Параметр в виртуальные таблиц Остатки Цены поставить.
Где Номенклатура в (Выбрать Товар из ВТ_Товары)

(19) ну так поставь

(22) конфа на поддержке

(21) Спасибо тебе добрый человек.
И всем остальным тоже.

(21) Как-то так:

ВЫБРАТЬ
    Номен.Ссылка КАК Номенклатура
ПОМЕСТИТЬ ВрТовары
ИЗ
    Справочник.Номенклатура КАК Номен
ГДЕ
    Номен.Наименование ПОДОБНО "%" + &СтрокаПоиска + "%"
Индексировать по Номенклатура    
;

////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ
    Остатки.Характеристика КАК Характеристика,
    Остатки.Номенклатура КАК Номенклатура,
    Остатки.КоличествоОстаток КАК КоличествоОстаток
ПОМЕСТИТЬ ВрОстатки
ИЗ
    РегистрНакопления.ТоварыНаСкладах.Остатки(&ДатаОстатков, Склад = &РозничныйСклад И Номенклатура В (Выбрать Номенклатура ИЗ ВрТовары)) КАК Остатки
Индексировать по Номенклатура    
;

////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ
    Цены.Характеристика КАК Характеристика,
    Цены.Цена КАК Цена
ПОМЕСТИТЬ ВрЦены
ИЗ
    РегистрСведений.ЦеныНоменклатуры.СрезПоследних(, ВидЦены = &Розничная И Номенклатура В (Выбрать Номенклатура ИЗ ВрТовары)) КАК Цены
Индексировать по Характеристика    
;

////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ Первые 200
    ВрТовары.Номенклатура КАК Номенклатура,
    ВрОстатки.Характеристика КАК Характеристика,
    ВрОстатки.КоличествоОстаток КАК КоличествоОстаток,
    ВрЦены.Цена КАК Цена
ИЗ
    ВрТовары КАК ВрТовары
        ЛЕВОЕ СОЕДИНЕНИЕ ВрОстатки КАК ВрОстатки
            ЛЕВОЕ СОЕДИНЕНИЕ ВрЦены КАК ВрЦены
            ПО (ВрОстатки.Характеристика = ВрЦены.Характеристика)
        ПО (ВрТовары.Номенклатура = ВрОстатки.Номенклатура)

Первые 200
в самый первый запрос

И пользователи скажут тебе спасибо, когда забьют пустую строку

(26) Не факт, что у этих первых двухсот будут какие-то остатки, а значит такая выборка не имеет особого смысла.

(26) Хотя если в последнем запросе нет отбора по NULL то действительно лучше в первый.

(29) Да

(14) наложи отбор на таблицы товара из первого запроса. как в (25)

(25) спасибо за ваш вариант.
мой запрос который я написал уже работает очень быстро.
Еше бы понять зачем индексирование в вашем варианте.

(32) рекомендации 1С - индексировать поля временных таблиц, по которым идет отбор или соединение. Далеко не всегда влияет на результат, но общий подход такой.