Обмен УТ11 (11.4.8.68) - ККМ Офлайн. Не работает.

Если кому понадобится, создайте, добавьте в расширение общий модуль МенеджерОфлайнОборудованияПереопределяемый, а в него код из ближайшего рабочего релиза (11.4.8.57) или скопируйте код ниже.

#Область ПрограммныйИнтерфейс
&Вместо("ПолучитьДоступныеТипыОфлайнОборудования")
Функция Расш1_ПолучитьДоступныеТипыОфлайнОборудования() Экспорт

    СписокОборудования = Новый Массив;

    СписокОборудования.Добавить(Перечисления.ТипыОфлайнОборудования.ККМ);
    СписокОборудования.Добавить(Перечисления.ТипыОфлайнОборудования.ПрайсЧекер);

    Возврат СписокОборудования;

КонецФункции

#Область ВыгрузкаДанныхНаОфлайнОборудование
&Вместо("ПриВыгрузкеНастроек")
Процедура Расш1_ПриВыгрузкеНастроек(ОфлайнОборудование, НастройкиОборудования) Экспорт

    ПодключаемоеОборудованиеOfflineВызовСервера.ЗаполнитьНастройкиККМ(ОфлайнОборудование, НастройкиОборудования);

КонецПроцедуры
&Вместо("ПриВыгрузкеПрайсЛиста")
Процедура Расш1_ПриВыгрузкеПрайсЛиста(ОфлайнОборудование, ПрайсЛист, ПолнаяВыгрузка) Экспорт

    ПодключаемоеОборудованиеOfflineВызовСервера.ЗаполнитьПрайсЛистККМ(ОфлайнОборудование, ПрайсЛист, ПолнаяВыгрузка);

КонецПроцедуры
&Вместо("ПриВыгрузкеТовараПоШтрихкоду")
Процедура Расш1_ПриВыгрузкеТовараПоШтрихкоду(ОфлайнОборудование, ПрайсЛист, Штрихкод) Экспорт

    ПодключаемоеОборудованиеOfflineВызовСервера.ЗаполнитьПрайсЛистККМПоШтрихкоду(ОфлайнОборудование, ПрайсЛист, Штрихкод);

КонецПроцедуры
&Вместо("ПриВыгрузкеЗаказов")
Процедура Расш1_ПриВыгрузкеЗаказов(ОфлайнОборудование, Заказы) Экспорт

    Возврат;

КонецПроцедуры
&Вместо("ПослеУспешнойВыгрузкиДанных")
Процедура Расш1_ПослеУспешнойВыгрузкиДанных(ОфлайнОборудование, НаборВыгруженныхДанных) Экспорт

    Если НаборВыгруженныхДанных.ПрайсЛист Тогда

        // снять с регистрации товары
        ПодключаемоеОборудованиеOfflineВызовСервера.УдалитьРегистрациюПрайсЛистаПослеВыгрузки(ОфлайнОборудование);

    КонецЕсли;

    Если НаборВыгруженныхДанных.Заказы Тогда
        // снять с регистрации заказы
    КонецЕсли;

    Возврат;

КонецПроцедуры

#КонецОбласти

#Область ЗагрузкаДанныхИзОфлайнОборудования
&Вместо("ПриЗагрузкеДанныхОПродажахИзККМ")
Процедура Расш1_ПриЗагрузкеДанныхОПродажахИзККМ(ОфлайнОборудование, ДанныеОПродажах, Отказ, СообщениеОбОшибке) Экспорт

    ПодключаемоеОборудованиеOfflineВызовСервера.ЗагрузитьОтчетыОПродажахИзККМ(ОфлайнОборудование, ДанныеОПродажах, Отказ, СообщениеОбОшибке);

КонецПроцедуры
&Вместо("ПриЗагрузкеДанныхОВскрытияхАлкогольнойТарыИзККМ")
Процедура Расш1_ПриЗагрузкеДанныхОВскрытияхАлкогольнойТарыИзККМ(ОфлайнОборудование, ДанныеОВскрытияхТары, Отказ, СообщениеОбОшибке) Экспорт

КонецПроцедуры
&Вместо("ПриЗагрузкеДанныхОПроверкахЦенников")
Процедура Расш1_ПриЗагрузкеДанныхОПроверкахЦенников(ОфлайнОборудование, ДанныеОПроверкахЦенников, Отказ, СообщениеОбОшибке) Экспорт

КонецПроцедуры

#КонецОбласти

#Область ПереопределяемыеПроцедурыФорм
&Вместо("ФормаОбменСОфлайнОборудованиемПриСозданииНаСервере")
Процедура Расш1_ФормаОбменСОфлайнОборудованиемПриСозданииНаСервере(Форма) Экспорт

КонецПроцедуры
&Вместо("ФормаНастройкиОфлайнОборудованияПриСозданииНаСервере")
Процедура Расш1_ФормаНастройкиОфлайнОборудованияПриСозданииНаСервере(Форма, ОфлайнОборудование) Экспорт

    Если ОфлайнОборудование.ТипОборудования = Перечисления.ТипыПодключаемогоОборудования.ККМОфлайн
        И ОфлайнОборудование.ТипОфлайнОборудования = Перечисления.ТипыОфлайнОборудования.ПрайсЧекер Тогда

        НовыеРеквизиты = Новый Массив;
        ПринтерПечати = Новый РеквизитФормы("ПринтерПечати", Новый ОписаниеТипов("Строка"), , , Ложь);
        НовыеРеквизиты.Добавить(ПринтерПечати);
        СохранятьЦенники = Новый РеквизитФормы("СохранятьЦенники", Новый ОписаниеТипов("Булево"), , , Ложь);
        НовыеРеквизиты.Добавить(СохранятьЦенники);
        ШаблонЦенника = Новый РеквизитФормы("ШаблонЦенника", Новый ОписаниеТипов("СправочникСсылка.ХранилищеШаблонов"), , , Ложь);
        НовыеРеквизиты.Добавить(ШаблонЦенника);
        Форма.ИзменитьРеквизиты(НовыеРеквизиты);

        ЭлементСохранятьЦенники = Форма.Элементы.Добавить("СохранятьЦенники", Тип("ПолеФормы"));
        ЭлементСохранятьЦенники.Заголовок = НСтр("ru = 'Сохранять ценники в конфигурации'");
        ЭлементСохранятьЦенники.Вид = ВидПоляФормы.ПолеВвода;
        ЭлементСохранятьЦенники.АвтоМаксимальнаяШирина = Ложь;
        ЭлементСохранятьЦенники.РастягиватьПоГоризонтали = Истина;
        ЭлементСохранятьЦенники.ПутьКДанным = "СохранятьЦенники";

        ЭлементПринтерПечати = Форма.Элементы.Добавить("ПринтерПечати", Тип("ПолеФормы"));
        ЭлементПринтерПечати.Заголовок = НСтр("ru = 'Принтер печати'");
        ЭлементПринтерПечати.Вид = ВидПоляФормы.ПолеВвода;
        ЭлементПринтерПечати.АвтоМаксимальнаяШирина = Ложь;
        ЭлементПринтерПечати.РастягиватьПоГоризонтали = Истина;
        ЭлементПринтерПечати.ПутьКДанным = "ПринтерПечати";
        ЭлементПринтерПечати.РежимВыбораИзСписка = Истина;

        ЭлементШаблонЦенника = Форма.Элементы.Добавить("ШаблонЦенника", Тип("ПолеФормы"));
        ЭлементШаблонЦенника.Заголовок = НСтр("ru = 'Шаблон ценника'");
        ЭлементШаблонЦенника.Вид = ВидПоляФормы.ПолеВвода;
        ЭлементШаблонЦенника.АвтоМаксимальнаяШирина = Ложь;
        ЭлементШаблонЦенника.РастягиватьПоГоризонтали = Истина;
        ЭлементШаблонЦенника.ПутьКДанным = "ШаблонЦенника";

        Форма.ПринтерПечати    = Форма.Элементы.ПринтерПечати.СписокВыбора.Добавить(ОфлайнОборудование.ПринтерПечати, ОфлайнОборудование.ПринтерПечати);;
        Форма.ШаблонЦенника    = ОфлайнОборудование.ШаблонЦенника;
        Форма.СохранятьЦенники = ОфлайнОборудование.СохранятьЦенникиВКонфигурации;

    КонецЕсли;

КонецПроцедуры
&Вместо("ФормаНастройкиПроизвольногоПериодаЭвоторПриСозданииНаСервере")
Процедура Расш1_ФормаНастройкиПроизвольногоПериодаЭвоторПриСозданииНаСервере(Форма) Экспорт

КонецПроцедуры

#КонецОбласти

#КонецОбласти