Всем привет,

БГУ 2.0 (2.0.63.39) хотя какая конфигурация не важно.

Написал отчет на СКД. Текст запроса (хотя это тоже не важно):
ВЫБРАТЬ
    ЧекККМТоварыРаботыУслуги.Ссылка КАК Ссылка,
    ЧекККМТоварыРаботыУслуги.Ссылка.Дата КАК СсылкаДата,
    ЧекККМТоварыРаботыУслуги.Ссылка.ФормаОплаты КАК СсылкаФормаОплаты,
    ЧекККМТоварыРаботыУслуги.Номенклатура.Номенклатура КАК НоменклатураЧека,
    ЧекККМТоварыРаботыУслуги.Номенклатура.Номенклатура.Родитель КАК ОтделениеЧека,
    ЧекККМТоварыРаботыУслуги.Номенклатура КАК ПрейскурантЧека,
    ЧекККМТоварыРаботыУслуги.СтавкаНДС КАК СтавкаНДСЧека,
    ЧекККМТоварыРаботыУслуги.Количество КАК КоличествоЧека,
    ЧекККМТоварыРаботыУслуги.ЦенаБезСкидок КАК ЦенаБезСкидокЧека,
    ЧекККМТоварыРаботыУслуги.Цена КАК ЦенаЧека,
    ЧекККМТоварыРаботыУслуги.Скидка КАК СкидкаЧека,
    ЧекККМТоварыРаботыУслуги.Сумма КАК СуммаЧека,
    ЧекККМТоварыРаботыУслуги.СуммаНДС КАК СуммаНДСЧека,
    ЧекККМТоварыРаботыУслуги.Всего КАК ВсегоЧека,
    ЧекККМТоварыРаботыУслуги.Ссылка.Организация КАК ОрганизацияЧека,
    ЧекККМТоварыРаботыУслуги.Ссылка.КассаККМ КАК КассаККМЧека,
    ЧекККМТоварыРаботыУслуги.Ссылка.КассоваяСмена КАК КассоваяСменаЧека,
    ЧекККМТоварыРаботыУслуги.Ссылка.Ответственный КАК ОтветственныйЧека,
    ЧекККМТоварыРаботыУслуги.Ссылка.СтатусЧекаККМ КАК СтатусЧекаККМЧека,
    ЗНАЧЕНИЕ(Документ.ЧекККМ.ПустаяСсылка) КАК ЧекПродажиЧека,
    ЛОЖЬ КАК ВозвратЧека
ПОМЕСТИТЬ Чеки
ИЗ
    Документ.ЧекККМ.ТоварыРаботыУслуги КАК ЧекККМТоварыРаботыУслуги
ГДЕ
    НАЧАЛОПЕРИОДА(ЧекККМТоварыРаботыУслуги.Ссылка.Дата, ДЕНЬ) >= НАЧАЛОПЕРИОДА(&ДатаНачала, ДЕНЬ)
    И НАЧАЛОПЕРИОДА(ЧекККМТоварыРаботыУслуги.Ссылка.Дата, ДЕНЬ) <= НАЧАЛОПЕРИОДА(&ДатаОкончания, ДЕНЬ)
    И ЧекККМТоварыРаботыУслуги.Ссылка.Проведен
    И НЕ ЧекККМТоварыРаботыУслуги.Ссылка.ПометкаУдаления

ОБЪЕДИНИТЬ

ВЫБРАТЬ
    ЧекККМНаВозвратТоварыРаботыУслуги.Ссылка,
    ЧекККМНаВозвратТоварыРаботыУслуги.Ссылка.Дата,
    ЧекККМНаВозвратТоварыРаботыУслуги.Ссылка.ФормаОплаты,
    ЧекККМНаВозвратТоварыРаботыУслуги.Номенклатура.Номенклатура,
    ЧекККМНаВозвратТоварыРаботыУслуги.Номенклатура.Номенклатура.Родитель,
    ЧекККМНаВозвратТоварыРаботыУслуги.Номенклатура,
    ЧекККМНаВозвратТоварыРаботыУслуги.СтавкаНДС,
    -ЧекККМНаВозвратТоварыРаботыУслуги.Количество,
    ЧекККМНаВозвратТоварыРаботыУслуги.ЦенаБезСкидок,
    ЧекККМНаВозвратТоварыРаботыУслуги.Цена,
    ЧекККМНаВозвратТоварыРаботыУслуги.Скидка,
    -ЧекККМНаВозвратТоварыРаботыУслуги.Сумма,
    -ЧекККМНаВозвратТоварыРаботыУслуги.СуммаНДС,
    -ЧекККМНаВозвратТоварыРаботыУслуги.Всего,
    ЧекККМНаВозвратТоварыРаботыУслуги.Ссылка.Организация,
    ЧекККМНаВозвратТоварыРаботыУслуги.Ссылка.КассаККМ,
    ЧекККМНаВозвратТоварыРаботыУслуги.Ссылка.КассоваяСмена,
    ЧекККМНаВозвратТоварыРаботыУслуги.Ссылка.Ответственный,
    ЧекККМНаВозвратТоварыРаботыУслуги.Ссылка.СтатусЧекаККМ,
    ЧекККМНаВозвратТоварыРаботыУслуги.Ссылка.ЧекККМПродажа,
    ИСТИНА
ИЗ
    Документ.ЧекККМНаВозврат.ТоварыРаботыУслуги КАК ЧекККМНаВозвратТоварыРаботыУслуги
ГДЕ
    НАЧАЛОПЕРИОДА(ЧекККМНаВозвратТоварыРаботыУслуги.Ссылка.Дата, ДЕНЬ) >= НАЧАЛОПЕРИОДА(&ДатаНачала, ДЕНЬ)
    И НАЧАЛОПЕРИОДА(ЧекККМНаВозвратТоварыРаботыУслуги.Ссылка.Дата, ДЕНЬ) <= НАЧАЛОПЕРИОДА(&ДатаОкончания, ДЕНЬ)
    И ЧекККМНаВозвратТоварыРаботыУслуги.Ссылка.Проведен
    И НЕ ЧекККМНаВозвратТоварыРаботыУслуги.Ссылка.ПометкаУдаления
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    Чеки.Ссылка КАК Документ,
    Чеки.СсылкаДата КАК ДатаДокумента,
    Чеки.СсылкаФормаОплаты КАК ФормаОплаты,
    ВЫБОР
        КОГДА Чеки.СсылкаФормаОплаты = 0
            ТОГДА "Наличные"
        КОГДА Чеки.СсылкаФормаОплаты = 1
            ТОГДА "Платежная карта"
        ИНАЧЕ "Другое"
    КОНЕЦ КАК ВидОплаты,
    Чеки.ОтделениеЧека КАК Отделение,
    Чеки.ПрейскурантЧека КАК Прейскурант,
    Чеки.НоменклатураЧека КАК Номенклатура,
    Чеки.СтавкаНДСЧека КАК СтавкаНДС,
    Чеки.ОрганизацияЧека КАК Организация,
    Чеки.КассаККМЧека КАК КассаККМ,
    Чеки.КассоваяСменаЧека КАК КассоваяСмена,
    Чеки.ОтветственныйЧека КАК Ответственный,
    Чеки.СтатусЧекаККМЧека КАК СтатусЧекаККМ,
    Чеки.ЧекПродажиЧека КАК ЧекПродажи,
    Чеки.ВозвратЧека КАК Возврат,
    Чеки.КоличествоЧека КАК Количество,
    Чеки.ЦенаБезСкидокЧека КАК ЦенаБезСкидок,
    Чеки.ЦенаЧека КАК Цена,
    Чеки.СкидкаЧека КАК Скидка,
    Чеки.СуммаЧека КАК Сумма,
    Чеки.СуммаНДСЧека КАК СуммаНДС,
    Чеки.ВсегоЧека КАК Всего
ИЗ
    Чеки КАК Чеки


Суть проблемы: при выводе отчета он не видит все данные, а при расшифровке видит
Пример: по номенклатуре "Бензин АИ-92 2019" по кассе "ВИКИ ПРИНТ 57Ф" количество 3, сумма 36. На самом деле количество 4 сумма 48. И расшифровка показывает верно (смотри картинку)
https://b.radikal.ru/b11/1909/32/4af6fe32aadb.jpg

СКД должна сгруппировать эти документы и сложить сумму, но она не складывает (как будто в ресурсах стоит максимум, а не сумма).
Она складывает, если количество или сумма разные, а если одинаковые, то в упор не видит.
Если поменять сумму или количество в одном из чеков, то сложит нормально.
Отчет выводится без детальных записей, а выбранные поля только ресурсы (думаю, копать нужно тут)
Добавить детальные записи не вариант, так как мне нужна группировка по номенклатуре, кассе, виду оплаты.

Вопрос получился достаточно большим и разобраться в нем трудно, заранее спасибо за любую помощь.

Что-то так сразу и не смог понять, в чем причина. Понятно, что то ли чек 000002, то ли чек 000003 не попадает в группировку, у которой ресурс Сумма (36) обведен красным квадратом. Но тогда в какую же группировку этот чек изначально попадает? Если удастся найти, вероятно придет и решение проблемы.
Что касается "Если поменять сумму или количество в одном из чеков, то сложит нормально.".  В каком? В любом или в определенном? Если в определенном, то вот этот документ (и аналогичные) и надо смотреть, что у него с реквизитами. Возможно, после изменения суммы или количества перед сохранением в документе автоматически дозаполняются какие-то реквизиты, после чего он уже попадают в ту группировку, где он и должен быть.

Но это все догадки... возможно, ларчик открывается более просто. хз.

(1) Да понимаю, описать это сложно...

Ситуация 1:
Документ Ном    Кол Цена Сумма
Чек1     Бензин  1   100  100
Чек2     Бензин  1   100  100

Результат в моем отчете при ситуации 1 (сгруппировано по номенклатуре):
Ном    Кол Цена Сумма
Бензин  1   100  100

А должно быть так (цена рассчитывается по МАКСИМУМ):
Ном    Кол Цена Сумма
Бензин  2   100  200

Если я зайду в любой чек, и поменяю любой ресурс (цену, количество или сумму), то все будет нормально
Ситуация 2:
Документ Ном    Кол Цена Сумма
Чек1     Бензин  1   100  100
Чек2     Бензин  1   110  110

Результат в моем отчете при ситуации 2 (сгруппировано по номенклатуре):
Ном    Кол Цена Сумма
Бензин  2   110  210

Вывод: СКД как-то не правильно группирует данные и свзано это, скорее всего, что у меня в выбранных полях одни ресурсы. Этот чек не попадет в другую группировку, потому что если например поменять сумму, от в отчете изменится общий итог. Отбор стоит только по периоду (да и у меня всего 3 чека и все в этом периоде)

(0) После слова "Объединить" все таблицы запросов сверху включая таблицу которая идет после этого ключевого слова будут свернуты.

http://1s-portal.ru/index.php/stati/common-questions/28-zapros/91-zapros-objedinit.html

Соответственно, я бы просто добавил номер строки чека - что бы была уникальность.

То есть примерно так
...
    ЛОЖЬ КАК ВозвратЧека,
    Чеки.НомерСтроки КАК СтрокаЧека
ПОМЕСТИТЬ Чеки
...
    ИСТИНА,
    Чеки.НомерСтроки
ИЗ
...

(3) Спасибо, помогло.

Я собственно поменял "ОБЪЕДИНИТЬ" на "ОБЪЕДИНИТЬ ВСЕ". Номер строки не добавлял.

Это все-равно странность от СКД.
Я объединяю из чеков и чеков на возврат, поэтому там не может быть дублей, я же вытягиваю ссылку и другие различные поля. Уникальность есть. Я и не писал поэтому "ВСЕ"
Если выполнить запрос в консоли, то он отработает одинаково и с "ВСЕ" и без. Все данные выводит, а через СКД нет.

Можно конечно добавить в ресурс номер строки и группировать ее по МАКСИМУМ, и попробывать скрыть или не выводить... в общем надо ковыряться. Но дописал "ВСЕ" и все заработало