Задача следующая. Есть массив масМесяцы - массив дат, на которые мне надо получить остатки по регистру накопления. На каждую из этих дат надо взять остатки и поместить в таблицу.
Запрос простейший:

ВЫБРАТЬ
        |        ЗадолженностьПоУдержаниямФизическихЛиц.Организация КАК Организация,
        |        ЗадолженностьПоУдержаниямФизическихЛиц.ФизическоеЛицо КАК ФизическоеЛицо,
        |        ЗадолженностьПоУдержаниямФизическихЛиц.Удержание КАК Удержание,
        |        ЗадолженностьПоУдержаниямФизическихЛиц.ДокументОснование КАК ДокументОснование,
        |        ЗадолженностьПоУдержаниямФизическихЛиц.СуммаОстаток КАК Сумма
        |    ИЗ
        |        РегистрНакопления.ЗадолженностьПоУдержаниямФизическихЛиц.Остатки(
        |                &МесяцНачисления,
        |                Организация = &ГоловнаяОрганизация
        |                    И ФизическоеЛицо В (&СписокФизическихЛиц)) КАК ЗадолженностьПоУдержаниямФизическихЛиц
        |    

Вот тут &МесяцНачисления - мне надо перебрать все даты из моего массива.

Можно ли как-то переделать запрос, чтобы не выполнять его в цикле?

Для каждого МесяцНачисления из масМесяцы цикл
Запрос.УстановитьПараметр("МесяцНачисления", МесяцНачисления);
тзИсточник = Запрос.Выполнить().Выгрузить();
ОбъединитьТаблицы(тзПриемник, тзИсточник);
КонецЦикла;

Аналогичный вопрос про виртуальную таблицу РегистрСведений.СрезПоследних

Остаток на каждую дату - классика же

Загоняешь нужные даты в одну таблицу, к ней уже присоединяешь остатки по дате

(1) Как то так

ВЫБРАТЬ
    АвансовыйОтчет.Дата КАК ДатаИзНекоегоМассиваДат
ПОМЕСТИТЬ втНекийМассивДат
ИЗ
    Документ.АвансовыйОтчет КАК АвансовыйОтчет

СГРУППИРОВАТЬ ПО
    АвансовыйОтчет.Дата
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ЦеныНоменклатуры.Период КАК Период,
    ЦеныНоменклатуры.Номенклатура КАК Номенклатура,
    МАКСИМУМ(ЦеныНоменклатуры.Цена) КАК Цена
ПОМЕСТИТЬ втРегистрСведений
ИЗ
    РегистрСведений.ЦеныНоменклатуры КАК ЦеныНоменклатуры

СГРУППИРОВАТЬ ПО
    ЦеныНоменклатуры.Период,
    ЦеныНоменклатуры.Номенклатура
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    взРезультат.ДатаИзНекоегоМассиваДат КАК ДатаИзНекоегоМассиваДат,
    взРезультат.Период КАК Период,
    взРезультат.Номенклатура КАК Номенклатура,
    взРезультат.Цена КАК Цена
ИЗ
    (ВЫБРАТЬ
        взПоследнийПериодНаДату.ДатаИзНекоегоМассиваДат КАК ДатаИзНекоегоМассиваДат,
        втРегистрСведений.Период КАК Период,
        втРегистрСведений.Номенклатура КАК Номенклатура,
        втРегистрСведений.Цена КАК Цена
    ИЗ
        (ВЫБРАТЬ
            втНекийМассивДат.ДатаИзНекоегоМассиваДат КАК ДатаИзНекоегоМассиваДат,
            МАКСИМУМ(втРегистрСведений.Период) КАК ПоследнийПериодНаДату,
            втРегистрСведений.Номенклатура КАК Номенклатура
        ИЗ
            втНекийМассивДат КАК втНекийМассивДат
                ВНУТРЕННЕЕ СОЕДИНЕНИЕ втРегистрСведений КАК втРегистрСведений
                ПО втНекийМассивДат.ДатаИзНекоегоМассиваДат >= втРегистрСведений.Период
        
        СГРУППИРОВАТЬ ПО
            втНекийМассивДат.ДатаИзНекоегоМассиваДат,
            втРегистрСведений.Номенклатура) КАК взПоследнийПериодНаДату
            ВНУТРЕННЕЕ СОЕДИНЕНИЕ втРегистрСведений КАК втРегистрСведений
            ПО взПоследнийПериодНаДату.Номенклатура = втРегистрСведений.Номенклатура
                И взПоследнийПериодНаДату.ПоследнийПериодНаДату = втРегистрСведений.Период) КАК взРезультат

(4) Ты с трехэтажными вложенными запросами пришел к нам из эпохы блинных HDD? )

(5) А в чем проблема? Тут нет соединения нескольких вложенных запросов.

(6) Проблема в читаемости

(7) Не соглашусь. Слишком много виртуальных таблиц ухудшает читабельность.

Если некую законченную операцию можно сделать в рамках одной вирт таблицы, с помощью вложенных запросов, ИМХО, так и надо поступать.

(3)"Загоняешь нужные даты в одну таблицу, к ней уже присоединяешь остатки по дате"
А есть пример?

Пример "на каждый день", только надо переделать "на каждый месяц"

ВЫБРАТЬ РАЗЛИЧНЫЕ
    РегламентированныйПроизводственныйКалендарь.ДатаКалендаря КАК Период
ПОМЕСТИТЬ Дни
ИЗ
    РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь
ГДЕ
    РегламентированныйПроизводственныйКалендарь.ДатаКалендаря МЕЖДУ &НачалоПериода И &КонецПериода
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    Движения.Номенклатура КАК Номенклатура,
    ДНИ.Период КАК Период,
    СУММА(ВЫБОР
            КОГДА Движения.Период = &НачалоПериода
                ТОГДА Движения.КоличествоКонечныйОстаток
            ИНАЧЕ ВЫБОР
                    КОГДА Движения.Период <= ДНИ.Период
                        ТОГДА Движения.КоличествоОборот
                    ИНАЧЕ 0
                КОНЕЦ
        КОНЕЦ) КАК КоличествоКонечныйОстаток
ИЗ
    Дни КАК ДНИ,
    РегистрНакопления.ОстаткиТоваров.ОстаткиИОбороты(&НачалоПериода, &КонецПериода, День, , Номенклатура = &Номенклатура) КАК Движения

СГРУППИРОВАТЬ ПО
    Движения.Номенклатура,
    ДНИ.Период

УПОРЯДОЧИТЬ ПО
    Номенклатура,
    Период

(10)Спасибо за пример!
Еще не очень силен в запросах. Можешь пояснить, правильно ли я понимаю этот запрос?

- КОГДА Движения.Период = &НачалоПериода
это вроде понятно, берем самый первый остаток на начало периода

- КОГДА Движения.Период <= ДНИ.Период
                        ТОГДА Движения.КоличествоОборот
а здесь, прибавляем к предыдущему остатку сумму оборотов, таким образом считаем остаток на следующий день. Верно?

(0) Создаёшь ТЗ с нужными датами, соединяешь со своей таблицей

(4) запросы с трехэтажной вложенностью трудно читаемы.
Временные таблицы в 100500 раз проще.
Ответ на вопрос нашел здесь: https://helpf.pro/faq8/view/1499.html

(11) Верно.

(11) Эта катавасия из-за того, что таблица ОстаткиИОбороты не выдается остатки за периоды, в которых не было движений.