//******************************************************************************
// глВернутьЦену(Номенклатура, ТипЦены, ДатаЦены, ЦенаЦены, ЕдЦены, ВалЦены, НаценкаЦены, НайденнаяЦена)
//
// Параметры:
//  Номенклатура  - элемент справочника "Номенклатура"
//  ТипЦены       - элемент справочника "ТипыЦен"
//  ДатаЦены      - дата, на которую надо получить цену
//  ЦенаЦены      - переменная, которую надо заполнитиь значением (число) полученной цены
//  ЕдЦены        - переменная, которую надо заполнитиь значением
//                  (элемент справочника Единицы) единицы, за которую дается цена
//  ВалЦены       - переменная, которую надо заполнитиь значением валюты, в которой выражена цена
//  НайденнаяЦена - переменная, которую надо заполнить найденным элементом справочника цен
//
// Возвращаемое значение:
//  1 - если есть такая цена, пераметры цены заполнены
//  0 - нет такой цены
// -1 - есть только цены, помеченные на удаление
//
// Описание:
//  Формирует ценовые характеристики номенклатурной единицы по заданному типу цен.
//
Функция глВернутьЦену(Номенклатура, ТипЦены, ДатаЦены = 0, ЦенаЦены = 0, ЕдЦены = 0, ВалЦены = 0, НаценкаЦены = 0, НайденнаяЦена = 0) Экспорт
    Перем ЦеныНоменклатуры;
    Перем Рассчетная;
    Перем НужныйТипЦен;
    Перем ЕстьУдаленные;
    
    Рез = 1;
    НайденнаяЦена = ПолучитьПустоеЗначение("Справочник.Цены");
    
    Если ПустоеЗначение(ДатаЦены) = 1 Тогда
        ДатаЦены = РабочаяДата();
    КонецЕсли;

    // Найдет или нужную цену в справочнике
    // если она рассчитывается, то найдем базовую цену
    Рассчетная        = ТипЦены.Рассчитывается;
    НужныйТипЦен    = ?(ПустоеЗначение(Рассчетная) = 1, ТипЦены, ТипЦены.БазовыйТипЦен);
    
    ЦеныНоменклатуры= СоздатьОбъект("Справочник.Цены");
    ЦеныНоменклатуры.ИспользоватьВладельца(Номенклатура);
    ЦеныНоменклатуры.ВыбратьЭлементы();
    
    Пока ЦеныНоменклатуры.ПолучитьЭлемент()  = 1 Цикл    
        Если ЦеныНоменклатуры.ТипЦен <> НужныйТипЦен Тогда
            Продолжить;
        КонецЕсли;
        

        // КТ1 === ??? =======
        НайденнаяЦена = ЦеныНоменклатуры.ТекущийЭлемент();
        
        Если ЦеныНоменклатуры.ПометкаУдаления() = 1 Тогда
            Рез = - 1; // Цена есть, но помечена на удаление
            Продолжить; // КТ2 === ВОТ ЗДЕСЬ КАКОЙ ГЛУБОКИЙ СМЫСЛ. почему не ПРЕРВАТЬ ..? =======
        Иначе
            Прервать;
        КонецЕсли;
        
    КонецЦикла;      
    
    Если ПустоеЗначение(НайденнаяЦена) = 1 Тогда
        
        // Нет такой цены
        Возврат 0;
    КонецЕсли;
    
    // Заполним все ценовые характериситики
    
    // если не задана единица цены на эту дату, то потом придется обрабатывать случай нулевого коэффициента у  пустой единицы
    ЕдЦены        = НайденнаяЦена.Единица.Получить(ДатаЦены);
    
    Если ПустоеЗначение(Рассчетная) = 1 Тогда
        
        //Если цена не рассчитывается
        ЦенаЦены    = НайденнаяЦена.Цена.Получить(ДатаЦены);
        
        // элемент справочника существует Валюту и Наценку возьмем из него
        ВалЦены        = НайденнаяЦена.Валюта;
        НаценкаЦены    = НайденнаяЦена.Процент;
    Иначе
        
        //Если цена рассчитывается
        БазоваяЦена     = НайденнаяЦена.Цена.Получить(ДатаЦены);
        БазоваяВалюта    = НайденнаяЦена.Валюта;
        
        // Цены у базового типа могут отличаться
        ЦенаЦены    = глПересчет(БазоваяЦена, БазоваяВалюта, ДатаЦены, ТипЦены.Валюта, ДатаЦены);
        ЦенаЦены    = глОкруглить(ЦенаЦены * (100 + ТипЦены.Процент) / 100, ТипЦены.ПорядокОкругления);
        
        // элемент справочника Цены не существует (расчетный). Валюту и Наценку возьмем из типа цены
        ВалЦены        = ТипЦены.Валюта;
        НаценкаЦены    = ТипЦены.Процент;
    КонецЕсли;
    
    Возврат Рез;
КонецФункции // глВернутьЦену()

А что не понятного то?

сек, пишу...

Потому что может быть другой такой же тип цен, не помеченный на удаление иначе прервать

Дальше по коду отлови ситуацию, когда на твоих данных цена всё же получена, и запиши (в ЖР, мыло, в крайнем случае сообщением пользователю - только дойдёт несколько % таких сообщений) себе этот случай.

1. допустим, что вот так вот получилось что в Спр.Цены "задвоены" записи для ТипЦены, первая запись помечена на удаление, вторая - норм.
получится что через _параметры_ вернет норм.цену (для второй записи), а как результат функции вернет -1 (для первой записи) - НЕХОРОШО.

2. допустим, что вот так вот получилось что в Спр.Цены "задвоены" записи для ТипЦены, первая запись норм, вторая - помечена на удаление.
получится что через _параметры_ вернет норм.цену (для первой записи), а как результат функции вернет 1 (для первой записи) - хорошо.

Может быть 2 цены - тип - розничная, если одна помеченна на удаление - тоищем дальше, до первого вхождения не помеченной

По идее в КТ1 надо поставить
Рез = 1;

????

(6) кривой результат будет, сп. п.5.1

(5) п.1 вернет "-1" если не найдет НЕ помеченную на уделения цену, найдет вернет 1
п.2 до втрой не дойдет, потому что там прервать!

Смысл в том что это то что обычно называется "овнокод" :)
Функция возвращает цену побочным эффектом в передваемый параметр ЦенаЦены. А сам результат функции якобы используется для каких то проверок.

Но вот здесь я вижу вот так
Если ЦеныНоменклатуры.ПометкаУдаления() = 1 Тогда
            Рез = - 1; // Цена есть, но помечена на удаление
            Продолжить; // КТ2 === ВОТ ЗДЕСЬ КАКОЙ ГЛУБОКИЙ СМЫСЛ. почему не ПРЕРВАТЬ ..? =======
        Иначе
            Рез = 1;// переприсвоить результат после помеченой на удаление
            Прервать;
        КонецЕсли;

(10) Кроме ЦенаЦены, она еще возвращает ссылку на подчиненный справочник цены подчиненный номенклатуре по типу цены со всеми его атрибутами

(12) это несущественно сейчас

(12) Так вот и нужно смотреть контекст вызова этой функции. Она видимо может вызываться
когда в любом случае нужно получить актуальную цену или это контекст где проверяется
что цена с требуемым типом помечена на удаление.

(9) кто-то из нас тупит.
по 5.1 - если НАЙДЕТ удаленую - вернет -1, при этом параметрами вернет ПРО НЕУДАЛЕННУЮ

(15) Читай (11)

проеп 1с кодеров однозначно

но кстати такие ситуации крайне редки ИМХО, по крайней мере у меня такого не было

(16) ну да так тоже можно

(18) ну, у меня тоже не было, бо штатно такой ситуации с задвоением хрен получишь (урбд нет), но потенциально - можно

(17) то есть согласен что диагноз я поставил верно?

(21) да, согласен

(22) ок

Есть в типовой еще один косяк, он достаточно тяжелый, приводит к неявным труднообнаруживаемым пересортам, но проявляется когда включена партионока, в партиях задаются свойства (например, цвет) и по продаже идет ВозвратОтПокупателя - могут пересортиться на остатках, возвращают допустим красный цвет, а на остатки ляжет синий...

Гм. А занимательно читать записки археологов. :-)

(25) Без знания прошлого - нет будущего! что мы и видим в тупиковом развитии 8-ки ;-)

Мы в свое время оптимизировали эту функцию.
Делали отбор по реквизиту "Тип цен"

и в коде

ЦеныНоменклатуры.ИспользоватьВладельца(Номенклатура);
ЦеныНоменклатуры.ВыбратьЭлементы();

добавляли выборку по реквизиту "Тип цены".
В базах данных с большим количеством типов цен это значительно повышало производительность.

Если принять что для помеченых на удаление цен (элементов СПр.Цены) числовое значение цены должно трактоваться как 0(ноль) - т.е. цены нет - то все правик сводятся к трем операторам в функции глВернутьЦену.
.
Прошерстил глоб.модуль и конфигу (974 релиз) - более никаких доработок по коду не требуется, все остается работоспособным "автоматом".
.
Типа вот так получается, тестирвоание на юзверях покажет ;-)
.
//******************************************************************************
//[*]progadmin, 27.11.2019, НЕТИПОВОЕ
//// глВернутьЦену(Номенклатура, ТипЦены, ДатаЦены, ЦенаЦены, ЕдЦены, ВалЦены, НаценкаЦены, НайденнаяЦена)
// -------------
// глВернутьЦену(Номенклатура, ТипЦены, ДатаЦены, ЦенаЦены, ЕдЦены, ВалЦены, НаценкаЦены, НайденнаяЦена, ВозвращатьУдаленнуюЦенаЦены)
// Параметры:
//  ВозвращатьУдаленнуюЦенаЦены - 0/1, если для удаленных цен значение ЦенаЦены считается незаданным/заданным (0/1 соответственно)
//[*]_progadmin, 27.11.2019, НЕТИПОВОЕ
//
// Параметры:
//  Номенклатура  - элемент справочника "Номенклатура"
//  ТипЦены       - элемент справочника "ТипыЦен"
//  ДатаЦены      - дата, на которую надо получить цену
//  ЦенаЦены      - переменная, которую надо заполнитиь значением (число) полученной цены
//  ЕдЦены        - переменная, которую надо заполнитиь значением
//                  (элемент справочника Единицы) единицы, за которую дается цена
//  ВалЦены       - переменная, которую надо заполнитиь значением валюты, в которой выражена цена
//  НайденнаяЦена - переменная, которую надо заполнить найденным элементом справочника цен
//
// Возвращаемое значение:
//  1 - если есть такая цена, пераметры цены заполнены
//  0 - нет такой цены
// -1 - есть только цены, помеченные на удаление
//
// Описание:
//  Формирует ценовые характеристики номенклатурной единицы по заданному типу цен.
//
//[*]progadmin, 27.11.2019, НЕТИПОВОЕ
//Функция глВернутьЦену(Номенклатура, ТипЦены, ДатаЦены = 0, ЦенаЦены = 0, ЕдЦены = 0, ВалЦены = 0, НаценкаЦены = 0, НайденнаяЦена = 0) Экспорт
// -------------
Функция глВернутьЦену(Номенклатура, ТипЦены, ДатаЦены = 0, ЦенаЦены = 0, ЕдЦены = 0, ВалЦены = 0, НаценкаЦены = 0, НайденнаяЦена = 0, ВозвращатьУдаленнуюЦенаЦены=0) Экспорт
//[*]_progadmin, 27.11.2019, НЕТИПОВОЕ
    Перем ЦеныНоменклатуры;
    Перем Рассчетная;
    Перем НужныйТипЦен;
    Перем ЕстьУдаленные;
    
    
    Рез = 1;
    НайденнаяЦена = ПолучитьПустоеЗначение("Справочник.Цены");
    
    Если ПустоеЗначение(ДатаЦены) = 1 Тогда
        ДатаЦены = РабочаяДата();
    КонецЕсли;

    // Найдет или нужную цену в справочнике
    // если она рассчитывается, то найдем базовую цену
    Рассчетная        = ТипЦены.Рассчитывается;
    НужныйТипЦен    = ?(ПустоеЗначение(Рассчетная) = 1, ТипЦены, ТипЦены.БазовыйТипЦен);
    
    ЦеныНоменклатуры= СоздатьОбъект("Справочник.Цены");
    ЦеныНоменклатуры.ИспользоватьВладельца(Номенклатура);
    ЦеныНоменклатуры.ВыбратьЭлементы();
    
    Пока ЦеныНоменклатуры.ПолучитьЭлемент()  = 1 Цикл    
        Если ЦеныНоменклатуры.ТипЦен <> НужныйТипЦен Тогда
            Продолжить;
        КонецЕсли;
        
        НайденнаяЦена = ЦеныНоменклатуры.ТекущийЭлемент();
        
        Если ЦеныНоменклатуры.ПометкаУдаления() = 1 Тогда
            Рез = - 1; // Цена есть, но помечена на удаление
            Продолжить;
        Иначе
            Рез = 1; //[+]progadmin, 27.11.2019, НЕТИПОВОЕ, косяк писателей типовых
            Прервать;
        КонецЕсли;
        
    КонецЦикла;      
    
    Если ПустоеЗначение(НайденнаяЦена) = 1 Тогда
        
        // Нет такой цены
        Возврат 0;
    КонецЕсли;
    
    Множитель = ?(Рез=-1,ВозвращатьУдаленнуюЦенаЦены,1); //[+]progadmin, 27.11.2019, НЕТИПОВОЕ
    
    // Заполним все ценовые характериситики
    
    // если не задана единица цены на эту дату, то потом придется обрабатывать случай нулевого коэффициента у  пустой единицы
    ЕдЦены        = НайденнаяЦена.Единица.Получить(ДатаЦены);
    
    Если ПустоеЗначение(Рассчетная) = 1 Тогда
        
        //Если цена не рассчитывается
        ЦенаЦены    = НайденнаяЦена.Цена.Получить(ДатаЦены);
        
        // элемент справочника существует Валюту и Наценку возьмем из него
        ВалЦены        = НайденнаяЦена.Валюта;
        НаценкаЦены    = НайденнаяЦена.Процент;
    Иначе
        
        //Если цена рассчитывается
        БазоваяЦена     = НайденнаяЦена.Цена.Получить(ДатаЦены);
        БазоваяВалюта    = НайденнаяЦена.Валюта;
        
        // Цены у базового типа могут отличаться
        ЦенаЦены    = глПересчет(БазоваяЦена, БазоваяВалюта, ДатаЦены, ТипЦены.Валюта, ДатаЦены);
        ЦенаЦены    = глОкруглить(ЦенаЦены * (100 + ТипЦены.Процент) / 100, ТипЦены.ПорядокОкругления);
        
        // элемент справочника Цены не существует (расчетный). Валюту и Наценку возьмем из типа цены
        ВалЦены        = ТипЦены.Валюта;
        НаценкаЦены    = ТипЦены.Процент;
    КонецЕсли;
    
    ЦенаЦены = ЦенаЦены * Множитель; //[+]progadmin, 27.11.2019, НЕТИПОВОЕ
    Возврат Рез;
КонецФункции // глВернутьЦену()

(27) ага, спсб.
я где-то тоже так делал,

ЦеныНоменклатуры.ИспользоватьВладельца(Номенклатура);
ЦеныНоменклатуры.ВыбратьЭлементыПоРеквизиту(....); //здеся...

в 974 релизе (клиентовском) Сортировка=1 и Отбор=1 (не знаю штатно или нет это)

для ВыбратьПоРеквизиту() достаточно Сортировка=1
Отбор=1 - он для интерактивных отборов работает только.

И раз уже про глВернутьЦену() - то вот тоже еще полезняшка
http://catalog.mista.ru/public/76287/ - ускорение для конструкций типа Цикл ГлВернутьЦену() КОнецЦикла;

(28) Ээээ....
Если ЦеныНоменклатуры.ПометкаУдаления() = 1 Тогда Продолжить;
с учетом твоего ВозвращатьУдаленнуюЦенаЦены должно быть
Если ВозвращатьУдаленнуюЦенаЦены = 1 Тогда Прервать;
ИначеЕсли ЦеныНоменклатуры.ПометкаУдаления() = 1 Тогда Продолжить;

И, наверное, можно еще так сказать:
в спр.Цены - помечать на удаление имеет смысл только если цены надо удалить кардинально с концами. если история нужна, то лучше оставлять цену "живой", но значение цены _на нужную_ (_с нужной даты_) ставить = 0

вот, ух блин, работун страшный напал

(32) не въехал (целый код давай ;-), бошка не варит уже после ночи.
мои исправления вроде все правильно должны дать (может и не оптимально).

(32) Я честно не пнял замысел Злопа в этом кодинке, смысл этого всего
Есть не помеченная на удаления цена(совместно с помеченной) возвращаем не помеченную
нет, возвращаем помеченную но с результатом "-1" далее в коде уже анализируем
Если глВернутьЦену(трататата) = , тут уже варианты 0 -нет такой цены для переанного типацен, 1 есть цена, -1 естьцена но помечена на удаление, вот и вся арифметика

(35) Твои исправления дадут отрицательную цену, вопрос, зачем?

ЦенаЦены = ЦенаЦены * Множитель;//[+]progadmin, 27.11.2019, НЕТИПОВОЕ

(35) Да вот же

Пока ЦеныНоменклатуры.ПолучитьЭлемент()  = 1 Цикл    
        Если ЦеныНоменклатуры.ТипЦен <> НужныйТипЦен Тогда
            Продолжить;
        КонецЕсли;
        
        НайденнаяЦена = ЦеныНоменклатуры.ТекущийЭлемент();
        
        // Если ЦеныНоменклатуры.ПометкаУдаления() = 1 Тогда // ВозвращатьУдаленнуюЦенаЦены  не сработает
        //    Рез = - 1;// Цена есть, но помечена на удаление
        //    Продолжить;
        Если ВозвращатьУдаленнуюЦенаЦены = 1 Тогда
             Прервать;
        ИначеЕсли ЦеныНоменклатуры.ПометкаУдаления() = 1 Тогда
             Продолжить;



(39) я подумаю.

(39) Так вы лишаете себя найти не удаленную цену, нахуя?

а все почему: начал блок производства тихонька впиливать.
Печать техкарт с полным разузлованием (так это называется?) для расчета плановой себестоимости изделия (кузяво получается, из карточки номенклатуры, из комплектации или из документов заявкапокупателя/реализация).

ну и наткнулся... чувствую, что где-то криво...

ВозвращатьУдаленнуюЦенаЦены
Вообще эта врезка нахер не нужна

по хорошему не нужно останавдиваться когда нашел свой тип цен.
но это утормозит вс процедуру.
поэтому на дубли просто забили

(44) Ну если уж получать саму актульную цену из набора одинаковых типов цен для номенклатры, то тут уже через "переодический" кмк оптимальнее лезть

мда... заменил

    //ЦеныНоменклатуры.ВыбратьЭлементы();
    //
    //Пока ЦеныНоменклатуры.ПолучитьЭлемент()  = 1 Цикл    
    //    Если ЦеныНоменклатуры.ТипЦен <> НужныйТипЦен Тогда
    //        Продолжить;
    //    КонецЕсли;
    // -------------
    ЦеныНоменклатуры.ВыбратьЭлементыПоРеквизиту("ТипЦен", НужныйТипЦен,, 0);

и вынес из функции

глПустаяЦена = ПустоеЗначение("Справочник.Цены");
глСпрЦены = СоздатьОбъект("Справочник.Цены");

получил почти 25% ускорения на функции глВернутьЦену, неплохо

(46) ну, это критично на больших массивах вызовов глВернутьЦену, штатно таких глобальных потоковых глвернутьцену - разве что в отчете по опстаткам со столбиком цены.

а так, я давно обрабатывал (без прямых запросов) приличные массивы истории изменения нескольких цен. там использование объекта "Периодический" само по себе дает до 25% выигрыша по скорости

Всё не читал, если туплю - прошу извинить.
Добавлял одну константу и одну ТЗ. ПриНачалеСистемы заполнял ТЗ текущими ценами и устанавливал флажок "брать цены из ТЗ". В 1с++, наверное, можно индексированную ТЗ.

Соответственно для быстрого получения цены смотрел на флаг, если он взведён - брал из ТЗ, это не дёргало БД, т.к. ТЗ была в ОЗУ.

(48) а как актуализировал ТЗ при изменении цен в базе?

(49) Видимо, никак. Либо обработкой ожидания, но это то ещё "гумно" в данном случае...

Извините, отъезжал.

(49) При изменении цен сбрасывал флаг и всё работало типовым образом.

(51), ну... это неинтересно... ;-)