Подскажите, если я в Параметры выбора реквизита прописал отбор для открываемой формы, этот отбор в настройках списка не виден? Если поставить свой такой же то ругается о пересекающихся значениях, пришлось автосохранение отключить

(0) Ругается о пересечении когда ты добавил фиксированный отбор, а то то пытается наложить пользовательский отбор на это же поле.
Бахай пользовательский отбор с типом Недоступный, горя знать не будешь

ПользовательскиеНастройки = Новый ПользовательскиеНастройкиКомпоновкиДанных;
    
Отбор = ПользовательскиеНастройки.Элементы.Добавить(Тип("ОтборКомпоновкиДанных"));
Отбор.ИдентификаторПользовательскойНастройки = "dfcece9d-5077-440b-b6b3-45a5cb4538eb";
Отбор.РежимОтображения = РежимОтображенияЭлементаНастройкиКомпоновкиДанных.Авто;
    
ЭлементОтбора = Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
ЭлементОтбора.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("Проведен");
ЭлементОтбора.ВидСравнения = ВидСравненияКомпоновкиДанных.Равно;
ЭлементОтбора.ПравоеЗначение = Истина;
ЭлементОтбора.Использование = Истина;
ЭлементОтбора.РежимОтображения = РежимОтображенияЭлементаНастройкиКомпоновкиДанных.Недоступный;
ЭлементОтбора.ИдентификаторПользовательскойНастройки = Новый УникальныйИдентификатор;

ОткрытьФорму("Документ.ПриобретениеТоваровУслуг.Форма.ФормаВыбора",
        Новый Структура("ЗакрыватьПриВыборе, РежимВыбора, МножественныйВыбор, Отбор, ПользовательскиеНастройки",
            Ложь, Истина, Истина, Новый Структура("Организация, ХозяйственнаяОперация", Объект.Организация, ПолучитьХозОперациюНаСервере()), ПользовательскиеНастройки),
            Элементы.Товары
            , , , ,
            Новый ОписаниеОповещения(
                "ПриЗакрытииФормыПодбора",
                ЭтаФорма,
                "Подбор"),
            РежимОткрытияОкнаФормы.БлокироватьОкноВладельца
    );