Доброго дня. Столкнулся с таким случаем:
Конфигурацию ERP. После закрытия июня, увидели в нем такую картинку по счету 44.02, пример Дт 1000 Кт 1000 Сальдо -400, хотя должен быть 0.
Начал анализировать, на 1ое июня конечное сальдо идет 600, хотя по расчетам идет 1000.
Сделал запрос через консоль, данные верные на 1 июня, но на 2 июня сальдо на начало опять с разницей в 400, а оборота, который эту разницу создает нет.
В итоге подумал, что проблема на итогах, сделал ТиИ - не помогло. Написал в 1С, они сказали обновится до последнего релиза(кто бы сомневался).
Сейчас обновляю на копии, но думаю проблему это не решит. Бухгалтера говорят, что в регл отчетности все корректно, проблему видно только в оборотке и карточке счета.
Может сталкивался кто, как решали?

Надо посмотреть непосредственно регистры бухгалтерии, может там какая-то глючная строчка попадется

(1) Я к ним и делал запрос, но нет такой строки.

(0) возможно по какой то аналитике и/или субконто оно есть, а в общем по счету - нету,
повертеть карточку счета, анализ счета - в режиме 1с предприятие

ТиИ не предлгать? На копии, разумеется, сначала

(4) грит сделал уже

давай скрины уже

(0) Было такое только в Бухгалтерии 3.0 и по валютным счетам.
Вот это помогло мне. Суть в NULL в таблицах при перепроведении доков за большие периоды.

&НаСервере
Процедура ИсправитьНаСервере()

    ОбщегоНазначенияКлиентСервер.СообщитьПользователю("Начало испраления -->"); //сообщение пользователю

    Запрос = Новый Запрос;
    Запрос.Текст =
        "ВЫБРАТЬ
        |    ВложенныйЗапрос.Регистратор КАК Регистратор,
        |    Представление(ВложенныйЗапрос.Регистратор) КАК СтрокаРегистратор
        |ИЗ
        |    (ВЫБРАТЬ
        |        ХозрасчетныйДвиженияССубконто.Регистратор КАК Регистратор
        |    ИЗ
        |        РегистрБухгалтерии.Хозрасчетный.ДвиженияССубконто(
        |                ,
        |                ,
        |                ПодразделениеДт = ЗНАЧЕНИЕ(Справочник.ПодразделенияОрганизаций.ПустаяСсылка)
        |                    И СчетДт <> ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПустаяСсылка)
        |                    И НЕ СчетДт.УчетПоПодразделениям,
        |                ,
        |                ) КАК ХозрасчетныйДвиженияССубконто
        |    
        |    СГРУППИРОВАТЬ ПО
        |        ХозрасчетныйДвиженияССубконто.Регистратор
        |    
        |    ОБЪЕДИНИТЬ ВСЕ
        |    
        |    ВЫБРАТЬ
        |        ХозрасчетныйДвиженияССубконто.Регистратор
        |    ИЗ
        |        РегистрБухгалтерии.Хозрасчетный.ДвиженияССубконто(
        |                ,
        |                ,
        |                ПодразделениеКт = ЗНАЧЕНИЕ(Справочник.ПодразделенияОрганизаций.ПустаяСсылка)
        |                    И СчетКт <> ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПустаяСсылка)
        |                    И НЕ СчетКт.УчетПоПодразделениям,
        |                ,
        |                ) КАК ХозрасчетныйДвиженияССубконто
        |    
        |    СГРУППИРОВАТЬ ПО
        |        ХозрасчетныйДвиженияССубконто.Регистратор
        |    
        |    ОБЪЕДИНИТЬ ВСЕ
        |    
        |    ВЫБРАТЬ
        |        ХозрасчетныйДвиженияССубконто.Регистратор
        |    ИЗ
        |        РегистрБухгалтерии.Хозрасчетный.ДвиженияССубконто(
        |                ,
        |                ,
        |                ВалютаДт = ЗНАЧЕНИЕ(Справочник.Валюты.ПустаяСсылка)
        |                    И СчетДт <> ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПустаяСсылка)
        |                    И НЕ СчетДт.Валютный,
        |                ,
        |                ) КАК ХозрасчетныйДвиженияССубконто
        |    
        |    СГРУППИРОВАТЬ ПО
        |        ХозрасчетныйДвиженияССубконто.Регистратор
        |    
        |    ОБЪЕДИНИТЬ ВСЕ
        |    
        |    ВЫБРАТЬ
        |        ХозрасчетныйДвиженияССубконто.Регистратор
        |    ИЗ
        |        РегистрБухгалтерии.Хозрасчетный.ДвиженияССубконто(
        |                ,
        |                ,
        |                ВалютаКт = ЗНАЧЕНИЕ(Справочник.Валюты.ПустаяСсылка)
        |                    И СчетКт <> ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПустаяСсылка)
        |                    И НЕ СчетКт.Валютный,
        |                ,
        |                ) КАК ХозрасчетныйДвиженияССубконто
        |    
        |    СГРУППИРОВАТЬ ПО
        |        ХозрасчетныйДвиженияССубконто.Регистратор) КАК ВложенныйЗапрос
        |
        |СГРУППИРОВАТЬ ПО
        |    ВложенныйЗапрос.Регистратор";
    РезультатЗапроса = Запрос.Выполнить();
    ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();
    
    Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
        
        Набор = РегистрыБухгалтерии.Хозрасчетный.СоздатьНаборЗаписей();
        
        ОбщегоНазначенияКлиентСервер.СообщитьПользователю(ВыборкаДетальныеЗаписи.СтрокаРегистратор + " // - исправлено"); //сообщение пользователю

        Набор.Отбор.Регистратор.Установить(ВыборкаДетальныеЗаписи.Регистратор);
        Набор.Прочитать();
        
        Модифицирован = Ложь;
        
        Для Каждого ЗаписьНабора Из Набор Цикл
            
            Если НЕ (ЗначениеЗаполнено(ЗаписьНабора.СчетДт) И ЗаписьНабора.СчетДт.Валютный) Тогда
                ЗаписьНабора.ВалютаДт = NULL;
            КонецЕсли;
            Если НЕ (ЗначениеЗаполнено(ЗаписьНабора.СчетКт) И ЗаписьНабора.СчетКт.Валютный) Тогда
                ЗаписьНабора.ВалютаКт = NULL;
            КонецЕсли;
            
            Если НЕ (ЗначениеЗаполнено(ЗаписьНабора.СчетДт) И ЗаписьНабора.СчетДт.УчетПоПодразделениям) Тогда
                ЗаписьНабора.ПодразделениеДт = NULL;
            КонецЕсли;
            Если НЕ (ЗначениеЗаполнено(ЗаписьНабора.СчетКт) И ЗаписьНабора.СчетКт.УчетПоПодразделениям) Тогда
                ЗаписьНабора.ПодразделениеКт = NULL;
            КонецЕсли;
            
        КонецЦикла;
        
        Набор.ОбменДанными.Загрузка = Истина;
        Набор.Записать();
        
    КонецЦикла;    
    
    ОбщегоНазначенияКлиентСервер.СообщитьПользователю("<-- Конец исправления"); //сообщение пользователю
    
КонецПроцедуры