v7: Форматирование JSON данных в 1с 7.7

Мне хватало этого (нарыто на просторах сети давно) для небольших размеров json

Процедура СкриптКонтролИнит(scriptCtrl)
    scriptCtrl =  СоздатьОбъект("MSScriptControl.ScriptControl");
    scriptCtrl.Language="jscript";
    код = "
    |
    | function parseJSON(strJSON) {
    |  var tmpFunc = (new Function('return('+strJSON+');'))();
    |  return(tmpFunc);
    | }
    |
    | // Получить элемент массива
    | function aGet(Array, index) {
    |  return(Array[index]);
    | }
    |
    | // Получить ключ пары по индексу
    | function oKey(Obj, index) {
    |  var size = 0, key;
    |  for (key in Obj) {
    |   if (size == index) break;
    |   if (Obj.hasOwnProperty(key)) size++;
    |  }
    |  return(key);
    | }
    |
    | // Получить значение пары по ключу
    | function oValueByKey(Obj, key) {
    |  return(Obj[key]);
    | }
    |
    | //Получить количество пар в объекте
    | Object.size = function(obj) {
    |  var size = 0, key;
    |  for (key in obj) {
    |   if (obj.hasOwnProperty(key)) size++;
    |  }
    |  return(size);
    | }
    |
    | //Получить размер объекта (количество пар в нём)
    | function oSize(Obj) {
    |  return(Object.size(Obj));
    | }
    |
    | // Получить тип объекта (number, string, object, array)
    | function eType(Element) {
    |  if (Element instanceof Array) {
    |    return(""array"");
    |  } else if (Object.prototype.toString.call(Element) === '[object Array]') {
    |    return(""array"");
    |  } else {
    |   return(typeof(Element));
    |  }
    | }
    |";
    scriptCtrl.AddCode(код);
КонецПроцедуры
//======================================================================
// для парсинга JSON (взято из сети)
Функция jsonВСписок(obj)
    Если ПустоеЗначение(scriptCtrl)=1 тогда
        СкриптКонтролИнит(scriptCtrl);
    КонецЕсли;
    РезультатРазбора = СоздатьОбъект("СписокЗначений");
    //Сообщить(scriptCtrl.run("oSize", obj));               //Размер объекта (количество пар ключ-значение)
    //Сообщить(scriptCtrl.run("oKey", obj, 1));             //Ключ пары с номером 1
    //Сообщить(scriptCtrl.run("oValueByKey", obj, "id"));   //Получить значение объекта по ключу
    //Сообщить(scriptCtrl.run("aGet", obj.products, 0).id); //Получить Элемент массива с индексом 0
    //Сообщить(scriptCtrl.run("eType", obj.products));      //Получить тип объекта, даже если он - массив

    сп = СоздатьОбъект("СписокЗначений");
    ТипОбъекта = scriptCtrl.run("eType", obj);
    Если ТипОбъекта = "object" Тогда
        Для н=0 По scriptCtrl.run("oSize", obj)-1 Цикл
            Ключ = scriptCtrl.run("oKey", obj, н);
            Значение = scriptCtrl.run("oValueByKey", obj, Ключ);
            ТипЗнач = scriptCtrl.run("eType", Значение);
            Если Найти("number, string", ТипЗнач) > 0 Тогда
                сп.ДобавитьЗначение(Значение, Ключ);
            ИначеЕсли Найти("object, array", ТипЗнач) > 0 Тогда
                сп.ДобавитьЗначение(jsonВСписок(Значение), Ключ);
            КонецЕсли;
        КонецЦикла;
    ИначеЕсли ТипОбъекта = "array" Тогда
        Для н=0 По obj.length-1 Цикл
            Значение = scriptCtrl.run("aGet", obj, н);
            ТипЗнач = scriptCtrl.run("eType", Значение);
            Если Найти("number, string", ТипЗнач) > 0 Тогда
                сп.ДобавитьЗначение(Значение, СокрЛП(Строка(н)));
            ИначеЕсли Найти("object, array", ТипЗнач) > 0 Тогда
                сп.ДобавитьЗначение(jsonВСписок(Значение), СокрЛП(Строка(н)));
            КонецЕсли;
        КонецЦикла;
    КонецЕсли;
    Возврат сп;
КонецФункции //jsonВСписок(obj)
//======================================================================
// для парсинга JSON (взято из сети)
//Возвращаемое значение можно разбирать с помощью стандартной функции
//Получить(<Имя поля>)
// для типа переменной "Список значений", или стандартной же функции
//ПолучитьЗначение(<НомерПоля>[,<Ключ>])
Функция ПреобразоватьJSONВДревовидныйСписок(Знач Стр)
    Если ПустоеЗначение(scriptCtrl)=1 тогда
        СкриптКонтролИнит(scriptCtrl);
    КонецЕсли;
    Рез = scriptCtrl.run("parseJSON", стр );
    сп = jsonВСписок(Рез);
    Возврат сп;
КонецФункции //
//======================================================================
//из древовидной структуры выгружает данные в линейный список по пути через точку
// список - древовидный список
// РезСписок - линейный список
// Путь - служебный, для рекурсии
Функция ПреобразоватьДревовидныйСписокВЛинейный(Список,РезСписок,Путь = "")
    Представление = "";
    Рзд = ".";
    Для НомПП=1 По Список.РазмерСписка() Цикл
        Значение = Список.ПолучитьЗначение(НомПП, Представление);
        Если ТипЗначения(Значение) = 100 Тогда //если список значений - пишем путь через разделитель
            Путь = ?(Путь = "",Представление,Путь+Рзд+Представление);
            ПреобразоватьДревовидныйСписокВЛинейный(Значение, РезСписок, Путь);
            Путь = ?(Найти(Путь,Рзд)>0,Лев(Путь,СтрДлина(Путь)-СтрДлина(Рзд+Представление)),СтрЗаменить(Путь,Представление,""));
            Продолжить;
        КонецЕсли;
        ПутьВСписок = ?(Путь = "",Представление,Путь+Рзд+Представление);
        РезСписок.ДобавитьЗначение(Значение,ПутьВСписок);
        //Сообщить(ПутьВСписок + " : " + Значение + ", Тип:"+СокрЛП(ТипЗначения(Значение)));
    КонецЦикла;
    Возврат 0;
КонецФункции // ПреобразоватьДревовидныйСписокВЛинейный
//======================================================================
//Функция для конвертации JSON в линейный список.
//На входе строка в текущей системной кодировке
//Возвращает список значений
Функция РазборJSON(Знач Стр)
    спДревовидный = СоздатьОбъект("СписокЗначений");
    спЛинейный = СоздатьОбъект("СписокЗначений");
    спДревовидный = ПреобразоватьJSONВДревовидныйСписок(Стр);
    ПреобразоватьДревовидныйСписокВЛинейный(спДревовидный,спЛинейный);
    Возврат спЛинейный;
КонецФункции // РазборJSON