БП 3.0 Расширение документа Путевой лист. Не могу убрать проверку заполнения расстояния

Процедура ОбработкаПроверкиЗаполнения(Отказ, ПроверяемыеРеквизиты)

    МассивНепроверяемыхРеквизитов = Новый Массив;

    ВидДокументаТопливнаяКарта = Перечисления.ВидыДокументовПриобретенияГСМ.ТопливнаяКарта;
    ПлательщикНДС = УчетнаяПолитика.ПлательщикНДС(Организация, Дата);

    СтавкиБезНДС = Новый Массив;
    СтавкиБезНДС.Добавить(Перечисления.СтавкиНДС.БезНДС);
    СтавкиБезНДС.Добавить(Перечисления.СтавкиНДС.НДС0);

    Для Каждого ТекущаяСтрока Из Топливо Цикл

        Если ТекущаяСтрока.ВидВходящегоДокумента = ВидДокументаТопливнаяКарта Тогда
            Продолжить;
        КонецЕсли;

        Если ТекущаяСтрока.Сумма = 0 Тогда
            СообщитьОЗаполненииОбязательногоРеквизита("Сумма", ТекущаяСтрока.НомерСтроки, "Топливо", Отказ);
        КонецЕсли;

        Если ПлательщикНДС И СуммаВключаетНДС И Не ЗначениеЗаполнено(ТекущаяСтрока.СтавкаНДС) Тогда
            СообщитьОЗаполненииОбязательногоРеквизита("СтавкаНДС", ТекущаяСтрока.НомерСтроки, "Топливо", Отказ);
        КонецЕсли;

        Если ПлательщикНДС И СуммаВключаетНДС
            И ТекущаяСтрока.СуммаНДС = 0
            И СтавкиБезНДС.Найти(ТекущаяСтрока.СтавкаНДС) = Неопределено Тогда

            СообщитьОЗаполненииОбязательногоРеквизита("СуммаНДС", ТекущаяСтрока.НомерСтроки, "Топливо", Отказ);
        КонецЕсли;

    КонецЦикла;

    Номенклатура = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(ТранспортноеСредство, "Топливо");
    Если Не ЗначениеЗаполнено(Номенклатура) Тогда
        ОбщегоНазначения.СообщитьПользователю(НСтр("ru = 'Не заполнено поле ""Топливо"" в транспортном средстве.'"),,
            "ТранспортноеСредство", "Объект", Отказ);
    КонецЕсли;

    Если Документы.ПутевойЛист.ВодительскоеУдостоверениеФизлица(ФизЛицо, Дата) = Неопределено Тогда
        ТекстОшибки = НСтр("ru = 'Не заполнено водительское удостоверение сотрудника. См. Справочники - Физическое лицо - Все Документы'");
        ОбщегоНазначения.СообщитьПользователю(ТекстОшибки, ФизЛицо, "ФизЛицо", "Объект", Отказ);
    КонецЕсли;

    КоличествоСтрок = Маршрут.Количество();
    Для Каждого ТекущаяСтрока Из Маршрут Цикл

        НомерСтроки = Маршрут.Индекс(ТекущаяСтрока);

        ПроверятьПересечениеПериодов = Истина;
        // Проверка корректности дат в текущей строке
        Если ТекущаяСтрока.ДатаОтправления > ТекущаяСтрока.ДатаВозвращения Тогда

            ШаблонПоляОшибки = ?(День(ТекущаяСтрока.ДатаОтправления) = День(ТекущаяСтрока.ДатаВозвращения),
                "Маршрут[%1].ВозвращениеВремя", "Маршрут[%1].ВозвращениеДата");
            ТекстОшибки = НСтр("ru = 'Дата возвращения из рейса не может быть меньше даты отправления.'");

            ОбщегоНазначения.СообщитьПользователю(ТекстОшибки,, СтрШаблон(ШаблонПоляОшибки, НомерСтроки), "Объект", Отказ);
            ПроверятьПересечениеПериодов = Ложь;

        КонецЕсли;

        ПроверятьПересечениеПоказаний = Истина;
        // Проверка корректности показаний одометра в текущей строке
        Если ТекущаяСтрока.ПоказаниеОдометраДо > ТекущаяСтрока.ПоказаниеОдометраПосле Тогда

            ШаблонПоляОшибки = "Маршрут[%1].ПоказаниеОдометраПосле";
            ТекстОшибки = НСтр("ru = 'Показание одометра при возращении из рейса не может быть меньше показаний одометра при выезде.'");

            ОбщегоНазначения.СообщитьПользователю(ТекстОшибки,, СтрШаблон(ШаблонПоляОшибки, НомерСтроки), "Объект", Отказ);
            ПроверятьПересечениеПоказаний = Ложь;

        КонецЕсли;

        Если Не ПроверятьПересечениеПоказаний И Не ПроверятьПересечениеПериодов Тогда
            Продолжить;
        КонецЕсли;

        Для ИндексСледующейСтроки = НомерСтроки + 1 По КоличествоСтрок - 1 Цикл

            СтрокаСравнения = Маршрут[ИндексСледующейСтроки];

            // Проверка пересечения показаний одометра

            Если ПроверятьПересечениеПериодов И ТекущаяСтрока.ПоказаниеОдометраПосле > СтрокаСравнения.ПоказаниеОдометраДо Тогда

                ШаблонПоляОшибки = "Маршрут[%1].ПоказаниеОдометраДо";

                Если ТекущаяСтрока.ПоказаниеОдометраДо >= СтрокаСравнения.ПоказаниеОдометраПосле Тогда
                    ТекстОшибки = НСтр("ru = 'Показания одометра в строке %1 должны быть больше показаний в строке %2.'");
                Иначе
                    ТекстОшибки = НСтр("ru = 'Показания одометра в строке %1 пересекаются с данными строки %2.'");
                КонецЕсли;

                ОбщегоНазначения.СообщитьПользователю(СтрШаблон(ТекстОшибки, ИндексСледующейСтроки + 1, НомерСтроки + 1),,
                    СтрШаблон(ШаблонПоляОшибки, ИндексСледующейСтроки), "Объект", Отказ);

            КонецЕсли;

            // Проверка даты отправления и возвращения

            Если ПроверятьПересечениеПоказаний И ТекущаяСтрока.ДатаВозвращения > СтрокаСравнения.ДатаОтправления Тогда

                ШаблонПоляОшибки = ?(НачалоДня(ТекущаяСтрока.ДатаОтправления) = НачалоДня(СтрокаСравнения.ДатаОтправления),
                    "Маршрут[%1].ОтправлениеВремя", "Маршрут[%1].ОтправлениеДата");

                Если ТекущаяСтрока.ДатаОтправления >= СтрокаСравнения.ДатаВозвращения Тогда
                    ТекстОшибки = НСтр("ru = 'Отсортируйте строки по периоду. Сейчас период в строке %1 меньше, чем в строке %2.'");
                Иначе
                    ТекстОшибки = НСтр("ru = 'Период рейса в строке %1 пересекается с данными строки %2.'");
                КонецЕсли;

                ОбщегоНазначения.СообщитьПользователю(СтрШаблон(ТекстОшибки, ИндексСледующейСтроки + 1, НомерСтроки + 1),,
                    СтрШаблон(ШаблонПоляОшибки, ИндексСледующейСтроки), "Объект", Отказ);

            КонецЕсли;

        КонецЦикла;

    КонецЦикла;

    РеквизитыЗаСсылками = Документы.ПутевойЛист.РеквизитыЗаСсылками();
    СчетаУчетаВДокументах.ПроверитьЗаполнение(ЭтотОбъект, Отказ, ПроверяемыеРеквизиты, РеквизитыЗаСсылками);
    ПроверкаЗаполненияДокументов.ПроверитьРеквизитыЗаСсылками(ЭтотОбъект, Отказ, ПроверяемыеРеквизиты, РеквизитыЗаСсылками);

КонецПроцедуры