Загрузка курсов с РБК

Функция ЗагрузитьУзлыXMLвСЗ(Корень, Узлы)

    сзРезультат     = СоздатьОбъект("СписокЗначений");
    ПрефИмениУзла    = "";
    АтрибутыУзла    = Корень.Attributes;
    Если АтрибутыУзла.length <> 0 Тогда
        Для атр = 0 По АтрибутыУзла.length - 1 Цикл
            узелАтрибута    = АтрибутыУзла.item(атр);
            ИмяАтрибута        = узелАтрибута.nodename;
            сзРезультат.ДобавитьЗначение(узелАтрибута.text, ИмяАтрибута);
        КонецЦикла;
    КонецЕсли;
    Для инд = 0 По Узлы.length - 1 Цикл
        узел            = Узлы.item(инд);
        ИмяУзла            = узел.nodename;
        ПодчиненныеУзлы    = узел.childNodes;

        Если ПодчиненныеУзлы.length = 0 Тогда
            Если ИмяУзла = "#text" Тогда
                сзРезультат = узел.text;
            Иначе
                сзРезультат.ДобавитьЗначение(узел.text, ИмяУзла);
            КонецЕсли;
        Иначе
            сзРезультат.ДобавитьЗначение(ЗагрузитьУзлыXMLвСЗ(узел, ПодчиненныеУзлы), ИмяУзла);
        КонецЕсли;
    КонецЦикла;

    Возврат сзРезультат;

КонецФункции // ЗагрузитьУзлыXMLвСЗ

Функция ЗагрузитьXMLвСЗ(текстXML)

    XMLDOM = СоздатьОбъект("Microsoft.XMLDOM");
    XMLDOM.loadXML(текстXML);

    Возврат ЗагрузитьУзлыXMLвСЗ(XMLDOM.DocumentElement, XMLDOM.DocumentElement.childNodes);

КонецФункции // ЗагрузитьXMLвСЗ

Функция ПреобразоватьОтвет(ОтветСервера)
    тзРезультат = глСоздатьТаблицу("Дата,Курс,Кратность");
    сзСтруктураОтвета = ЗагрузитьXMLвСЗ(ОтветСервера);
    Для инд = 1 По сзСтруктураОтвета.РазмерСписка() Цикл
        ИмяУзла = "";
        ЭлементОтвета = сзСтруктураОтвета.ПолучитьЗначение(инд, ИмяУзла);
        Если ИмяУзла <> "Record" Тогда
            Продолжить;
        КонецЕсли;
        тзРезультат.НоваяСтрока();
        тзРезультат.Дата        = Дата(ЭлементОтвета.Получить("Date"));
        тзРезультат.Курс        = Число(СтрЗаменить(ЭлементОтвета.Получить("Value"), ",", "."));
        тзРезультат.Кратность    = Число(СтрЗаменить(ЭлементОтвета.Получить("Nominal"), ",", "."));
    КонецЦикла;
    Возврат тзРезультат;
КонецФункции // ПреобразоватьОтвет

Функция ФорматДаты(дат)
    Возврат СтрЗаменить(Формат(дат,"ДДДММГГГГ"), ".", "/");
КонецФункции // ФорматДаты

Процедура Загрузить(НачальнаяДатаЗагрузки)
    Адрес = "https://www.cbr.ru/scripts/XML_dynamic.asp?date_req1=" + ФорматДаты(НачальнаяДатаЗагрузки) + "&date_req2=" + ФорматДаты(ТекущаяДата()) + "&VAL_NM_RQ=";
    СписокВалют = ЗагрузитьСписокВалют();
    Для индВалюты = 1 По СписокВалют.РазмерСписка() Цикл
        Если СписокВалют.Пометка(индВалюты) = 0 Тогда
            Продолжить;
        КонецЕсли;

        ТекущаяВалюта = СписокВалют.ПолучитьЗначение(индВалюты);
        Сообщить("Загрузка курсов валюты: " + ТекущаяВалюта);

        Если СокрЛП(ТекущаяВалюта.Код) = "978" Тогда
            ТекстЗапроса = Адрес + "R01239";
        ИначеЕсли СокрЛП(ТекущаяВалюта.Код) = "840" Тогда
            ТекстЗапроса = Адрес + "R01235";
        ИначеЕсли СокрЛП(ТекущаяВалюта.Код) = "826" Тогда
            ТекстЗапроса = Адрес + "R01035";
        Иначе
            Сообщить("Не удалось определить идентификатор валюты");
            Продолжить;
        КонецЕсли;
        Сообщить(ТекстЗапроса);

        ОтветСервера    = ПолучитьКакСтроку(ТекстЗапроса);
        тзКурсыВалюты    = ПреобразоватьОтвет(ОтветСервера);

        Курсы = СоздатьОбъект("Периодический");
        Курсы.ИспользоватьОбъект("Курс",ТекущаяВалюта);
        КурсыВнутр = СоздатьОбъект("Периодический");
        КурсыВнутр.ИспользоватьОбъект("КурсВнутренний",ТекущаяВалюта);
        Кратности = СоздатьОбъект("Периодический");
        Кратности.ИспользоватьОбъект("Кратность",ТекущаяВалюта);

        тзКурсыВалюты.ВыбратьСтроки();
        Пока тзКурсыВалюты.ПолучитьСтроку() = 1 Цикл
            Курсы.ВыбратьЗначения(тзКурсыВалюты.Дата,тзКурсыВалюты.Дата);
            Курсы.ПолучитьЗначение();
            Если тзКурсыВалюты.Курс <> Курсы.Значение Тогда
                Если (тзКурсыВалюты.Курс <> Курсы.Значение) и (Курсы.Значение <> 0) Тогда
                    ТекстПисьма = ТекстПисьма + "
                    |" + ТекущаяВалюта + " за " + тзКурсыВалюты.Дата + ": " + Курсы.Значение + " >> " + тзКурсыВалюты.Курс;
                    Продолжить;
                КонецЕсли;
                Курсы.ДатаЗнач = тзКурсыВалюты.Дата;
                Курсы.Значение = тзКурсыВалюты.Курс;
                Курсы.Записать();
                Если тзКурсыВалюты.Дата >= '03.03.2022' Тогда
                    КурсыВнутр.ДатаЗнач = тзКурсыВалюты.Дата;
                    КурсыВнутр.Значение = тзКурсыВалюты.Курс*?(Константа.КоэффициентКурса = 0, 1, Константа.КоэффициентКурса);
                    КурсыВнутр.Записать();
                КонецЕсли;
                Кратности.ДатаЗнач = тзКурсыВалюты.Дата;
                Кратности.Значение = тзКурсыВалюты.Кратность;
                Если ТекущаяВалюта.Кратность.Получить(тзКурсыВалюты.Дата) <> тзКурсыВалюты.Кратность Тогда
                    Кратности.Записать();
                КонецЕсли;
                Сообщить(Строка(тзКурсыВалюты.Дата) + СимволТабуляции + тзКурсыВалюты.Курс + СимволТабуляции + тзКурсыВалюты.Кратность + СимволТабуляции + "загружен","I");
            Иначе
                Сообщить(Строка(тзКурсыВалюты.Дата) + СимволТабуляции + тзКурсыВалюты.Курс + СимволТабуляции + тзКурсыВалюты.Кратность + СимволТабуляции + "не изменился","I");
            КонецЕсли;
        КонецЦикла;
    КонецЦикла;
КонецПроцедуры // Загрузить