Коллеги, нужна помощь.
На форме обработки есть поле отбора с типом СтандартныйПериод
Есть РС с измерением Дата. В обработке, для выбора, открываем форму списка РС.
Каким образом можно передать в структуру отбора условие, что дата в РС должна быть внутри СтандратногПериода?

ну как, РегистрСведенийСписок.Отбор.Дата.Установить
так?

хм, стандартный период = интервал

имхо, только в форме списка РС присоздании устанавливать отбор, так получается?

В принципе можно через ПолучитьФорму() менять ее контекст

(0) ОФ/УФ?

(2) получить из стандартного периода дату видимо, думаю это возможно
(5) ну раз "присоздании", значит уф

(6) > значит уф
Указать при открытии формы параметр ФиксированныеНастройки.

все штатно, спасибо за участие
&НаКлиенте
Процедура ОтборСделки(Команда)
    
    ФормаРегистра = ПолучитьФорму("РегистрСведений.МежфирменныеРеализации.ФормаСписка");
    ФормаРегистра.Список.Отбор.Элементы.Очистить();
    
    Если НЕ ОтчетКонечныйЗаказчик.Пустая() Тогда
        ЭлементОтбораСотрудник = ФормаРегистра.Список.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
        ЭлементОтбораСотрудник.ЛевоеЗначение = ФормаРегистра.Список.Отбор.ДоступныеПоляОтбора.Элементы.Найти("Заказчик").Поле;
        ЭлементОтбораСотрудник.ВидСравнения = ВидСравненияКомпоновкиДанных.Равно;
        ЭлементОтбораСотрудник.Использование = Истина;
        ЭлементОтбораСотрудник.ПравоеЗначение = ОтчетКонечныйЗаказчик;
    КонецЕсли;
    
    Если НЕ ОтчетПериод.ДатаНачала = Дата(1,1,1) Тогда
        ЭлементОтбораДатаС = ФормаРегистра.Список.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
        ЭлементОтбораДатаС.ЛевоеЗначение = ФормаРегистра.Список.Отбор.ДоступныеПоляОтбора.Элементы.Найти("Период").Поле;
        ЭлементОтбораДатаС.ВидСравнения = ВидСравненияКомпоновкиДанных.БольшеИлиРавно;
        ЭлементОтбораДатаС.Использование = Истина;
        ЭлементОтбораДатаС.ПравоеЗначение = НачалоДня(ОтчетПериод.ДатаНачала);
    КонецЕсли;    
    
    Если НЕ ОтчетПериод.ДатаОкончания = Дата(1,1,1) Тогда
        ЭлементОтбораДатаПо = ФормаРегистра.Список.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
        ЭлементОтбораДатаПо.ЛевоеЗначение = ФормаРегистра.Список.Отбор.ДоступныеПоляОтбора.Элементы.Найти("Период").Поле;
        ЭлементОтбораДатаПо.ВидСравнения = ВидСравненияКомпоновкиДанных.МеньшеИлиРавно;
        ЭлементОтбораДатаПо.Использование = Истина;
        ЭлементОтбораДатаПо.ПравоеЗначение = КонецДня(ОтчетПериод.ДатаОкончания);
    КонецЕсли;    
    
    ФормаРегистра.Открыть();

КонецПроцедуры

(8)
(7) кстати, вполне годный вариант