Доброго вечера! УТ 11.5 база файловая около 7 гигов, стало заметно что очень долго выводится печатная форма "Установка цен номенклатуры" из одноименного документа, в документе буквально 10ть позиций, а печ. форму на экран выкидывает через 6-8 минут. Куда копать ? У кого есть УТ 11.5 как у вас с этим ?

какая платформа? полные ли права? другие документы тоже долго печатаются?

(1) Крайняя 20-я, права полные. тут не долго печатаются, а очень долго печатная форма формируется.

копать в параметры печати недоступного принтера

(2) "печ. форму на экран выкидывает через 6-8 минут" - такое описание проблемы говорит о том, что она долго формируется. Проверяйте отладчиком слабые места
ТиИ часто делаете? Попробуйте сделать, может дать ускорение

Отладка - Замер производительности для начала.

(4) ТИИ сделал никак не помогло
(5) сделал 99.88% времени выполнение запроса в документе

Ради интереса, открыл копию базы до перехода на 11.5, 11.4 - сделал те же действия - результат получил через пару секунд.

(7)

Тут программист нужен (с)

(6) если вам надо помочь с запросом - мы не поможем ничем, не зная его текст

(9) да во первых, я хотел узнать у кого есть 11.5 что бы проверили этот нюанс, запрос то типовой , если у всех работает быстро - значит у меня что-то с данными

(10) а сама база дорабатывалась у вас?

у меня в практике было, что в БУХ Украины документ один печатался до получаса - если очень много строк в табчасти (более ста). Пришлось типовой запрос править. А если строк до двадцати - вообще никаких проблем

(6) При ТИИ реструктуризацию делали? Возможно еще статистика на сервере SQL не обновляется регламентом.

+(13) Сорян. У вас файловая.
Что выдает cnvdbfl --info <путь к 1CV8.1CD>

+(14) ну еще и chdbfl проверьте

(6) >> 99.88% времени выполнение запроса в документе.

Проверьте скорость печати под пользователем с полными правами, чтобы исключить проблемы RLS.
Проверьте включены ли расчет итогов и текущих итогов у всех нужных регистров. Посмотрите периоды рассчитанных итогов регистров. Попробуйте ограничить этот период последними 2-3 годами.
Проверьте нет ли случайно в каком-нибудь из регистров записей с некорректными датами. Например, пользователь опечатался и ввёл документ с датами 1022 год, 2122 год, 2002, 2202 и т.п.

Ну и на всякий случай. Относительные 99.88% в абсолютных величинах это сколько времени? Может результат формируется за 1 секунду, а вывод на экран печатной формы тормозит из-за каких-то настроек принтера, кеша настроек печатной формы и т.п.
Для чистоты эксперимента можно развернуть копию базы на другом компе и сформировать печатную форму для печати на другом принтере и от имени нового пользователя базы данных с полными правами.

(0) вопрос без данных для анализа.
Собрали бы логи по запросам и блокировкам

А, база файловая..
Замер производительности сделать нужно хотя бы

(18) >> Замер производительности сделать нужно.

Был. В (6): 99.88% времени выполнение запроса в документе.

(11) конфигурация типовая (13) реструризакцию делал (16) тормозит не печать, а 99% монитор производительности показывает вот тут РезультатЗапроса = Запрос.ВыполнитьПакет();

Сам запрос
                Запрос = Новый Запрос(
                "ВЫБРАТЬ
                |    УстановкаЦенНоменклатуры.Ссылка       КАК Ссылка,
                |    УстановкаЦенНоменклатуры.Ссылка.Номер КАК Номер,
                |    УстановкаЦенНоменклатуры.Ссылка.Дата  КАК Дата,
                |    Представление(УстановкаЦенНоменклатуры.Ссылка.Ответственный) КАК ОтветственныйПредставление
                |ИЗ
                |    Документ.УстановкаЦенНоменклатуры КАК УстановкаЦенНоменклатуры
                |ГДЕ
                |    УстановкаЦенНоменклатуры.Ссылка = &УстановкаЦенНоменклатуры
                |;
                |
                |////////////////////////////////////////////////////////////////////////////////
                |ВЫБРАТЬ
                |    Товары.НомерСтроки                       КАК НомерСтроки,
                |    Товары.Номенклатура                      КАК Номенклатура,
                |    Товары.Характеристика                    КАК Характеристика,
                |    Товары.Упаковка                          КАК Упаковка,
                |    Товары.Цена                              КАК Цена,
                |    Товары.ВидЦены                           КАК ВидЦены
                |ПОМЕСТИТЬ ТаблицаДанных
                |ИЗ
                |    Документ.УстановкаЦенНоменклатуры.Товары КАК Товары
                |ГДЕ
                |    Товары.Ссылка = &УстановкаЦенНоменклатуры
                |    И Товары.ВидЦены В (&ВидыЦен)
                |;
                |
                |ВЫБРАТЬ
                |    Товары.НомерСтроки                       КАК НомерСтроки,
                |    Товары.Номенклатура                      КАК Номенклатура,
                |    Товары.Характеристика                    КАК Характеристика,
                |    Товары.Упаковка                          КАК Упаковка,
                |    Товары.Цена                              КАК Цена,
                |    Товары.ВидЦены                           КАК ВидЦены,
                |    
                |    ВЫБОР КОГДА ЦеныНоменклатурыСрезПоследних.Упаковка = Товары.Упаковка ТОГДА
                |        ЦеныНоменклатурыСрезПоследних.Цена
                |    ИНАЧЕ
                |        ЦеныНоменклатурыСрезПоследних.Цена/ЕСТЬNULL(&ТекстЗапросаКоэффициентУпаковки1,1)*ЕСТЬNULL(&ТекстЗапросаКоэффициентУпаковки3,1)
                |    КОНЕЦ КАК ДействующаяЦена,
                |    
                |    ВЫРАЗИТЬ(ВЫБОР КОГДА ЦеныНоменклатурыСрезПоследних.Цена <> 0 ТОГДА 100*(Товары.Цена - ВЫБОР КОГДА ЦеныНоменклатурыСрезПоследних.Упаковка = Товары.Упаковка ТОГДА
                |        ЦеныНоменклатурыСрезПоследних.Цена
                |    ИНАЧЕ
                |        ЦеныНоменклатурыСрезПоследних.Цена/ЕСТЬNULL(&ТекстЗапросаКоэффициентУпаковки1,1)*ЕСТЬNULL(&ТекстЗапросаКоэффициентУпаковки3,1)
                |    КОНЕЦ)/
                |    
                |    ВЫБОР КОГДА ЦеныНоменклатурыСрезПоследних.Упаковка = Товары.Упаковка ТОГДА
                |        ЦеныНоменклатурыСрезПоследних.Цена
                |    ИНАЧЕ
                |        ЦеныНоменклатурыСрезПоследних.Цена/ЕСТЬNULL(&ТекстЗапросаКоэффициентУпаковки1,1)*ЕСТЬNULL(&ТекстЗапросаКоэффициентУпаковки3,1)
                |    КОНЕЦ ИНАЧЕ 0.00 КОНЕЦ КАК Число(10,2)) КАК ПроцентИзменения
                |    
                |ПОМЕСТИТЬ Товары
                |ИЗ
                |    ТаблицаДанных КАК Товары
                |    
                |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры.СрезПоследних(&ДатаСреза, (Номенклатура, Характеристика, ВидЦены) В (ВЫБРАТЬ Т.Номенклатура, Т.Характеристика, Т.ВидЦены ИЗ Документ.УстановкаЦенНоменклатуры.Товары КАК Т)) КАК ЦеныНоменклатурыСрезПоследних
                |
                |        ПО Товары.Номенклатура      = ЦеныНоменклатурыСрезПоследних.Номенклатура
                |            И Товары.Характеристика = ЦеныНоменклатурыСрезПоследних.Характеристика
                |            И Товары.ВидЦены        = ЦеныНоменклатурыСрезПоследних.ВидЦены
                |
                |ГДЕ
                |    (
                |        ВЫБОР
                |            КОГДА Товары.Номенклатура.ИспользованиеХарактеристик <> ЗНАЧЕНИЕ(Перечисление.ВариантыИспользованияХарактеристикНоменклатуры.НеИспользовать)
                |                И Товары.Характеристика = ЗНАЧЕНИЕ(Справочник.ХарактеристикиНоменклатуры.ПустаяСсылка) ТОГДА ЛОЖЬ
                |            ИНАЧЕ ИСТИНА
                |        КОНЕЦ
                |    )
                |;
                |
                |ВЫБРАТЬ РАЗЛИЧНЫЕ
                |    Товары.ВидЦены КАК ВидЦены
                |ИЗ
                |    Товары КАК Товары
                |ГДЕ
                |    Товары.ПроцентИзменения <> 0 ИЛИ &Все
                |УПОРЯДОЧИТЬ ПО
                |    Товары.ВидЦены.РеквизитДопУпорядочивания
                |;
                |
                |ВЫБРАТЬ
                |    Товары.Номенклатура                      КАК Номенклатура,
                |    Товары.Характеристика                    КАК Характеристика,
                |    Товары.Номенклатура.НаименованиеПолное   КАК ПолноеНаименованиеНоменклатуры,
                |    Товары.Характеристика.НаименованиеПолное КАК ПолноеНаименованиеХарактеристики,
                |    Товары.Номенклатура.Код                  КАК Код,
                |    Товары.Номенклатура.Артикул              КАК Артикул,
                |    Товары.Упаковка                          КАК Упаковка,
                |    Товары.Номенклатура.ЕдиницаИзмерения     КАК ЕдиницаИзмерения,
                |    Товары.Цена                              КАК Цена,
                |    Товары.ВидЦены                           КАК ВидЦены,
                |    ЕСТЬNULL(Товары.ДействующаяЦена,0)       КАК СтараяЦена,
                |    Товары.ПроцентИзменения                  КАК ПроцентИзменения
                |    
                |ИЗ
                |    Товары КАК Товары
                |ГДЕ
                |    Товары.ПроцентИзменения <> 0 ИЛИ &Все
                |УПОРЯДОЧИТЬ ПО
                |    Товары.НомерСтроки
                |
                |ИТОГИ ПО
                |    Номенклатура, Характеристика");

(0)

Свежо, оригинально (с). Спасибо, 1С
=========
UT_11_5_7_402

СформироватьПечатнуюФормуУстановкиЦенНоменклатуры(...)

Зеванули "где", исправили уже небось в хотфиксах
===============

ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры.СрезПоследних(&ДатаСреза,
(
Номенклатура, Характеристика, ВидЦены) В (ВЫБРАТЬ Т.Номенклатура, Т.Характеристика, Т.ВидЦены ИЗ Документ.УстановкаЦенНоменклатуры.Товары КАК Т
)

(21) накатил все обновления, ошибка не исправлена

(20) (Номенклатура, Характеристика, ВидЦены) В (ВЫБРАТЬ Т.Номенклатура, Т.Характеристика, Т.ВидЦены ИЗ Документ.УстановкаЦенНоменклатуры.Товары КАК Т)

это что за на..й в параметрах виртуальной таблицы??? Перепиши вот так:

(Номенклатура, Характеристика, ВидЦены) В (ВЫБРАТЬ Т.Номенклатура, Т.Характеристика, Т.ВидЦены ИЗ ТаблицаДанных КАК Т)

Вот рабочий запрос :

                "ВЫБРАТЬ
                |    УстановкаЦенНоменклатуры.Ссылка       КАК Ссылка,
                |    УстановкаЦенНоменклатуры.Ссылка.Номер КАК Номер,
                |    УстановкаЦенНоменклатуры.Ссылка.Дата  КАК Дата,
                |    Представление(УстановкаЦенНоменклатуры.Ссылка.Ответственный) КАК ОтветственныйПредставление
                |ИЗ
                |    Документ.УстановкаЦенНоменклатуры КАК УстановкаЦенНоменклатуры
                |ГДЕ
                |    УстановкаЦенНоменклатуры.Ссылка = &УстановкаЦенНоменклатуры
                |;
                |
                |ВЫБРАТЬ
                |    Товары.НомерСтроки                       КАК НомерСтроки,
                |    Товары.Номенклатура                      КАК Номенклатура,
                |    Товары.Характеристика                    КАК Характеристика,
                |    Товары.Упаковка                          КАК Упаковка,
                |    Товары.Цена                              КАК Цена,
                |    Товары.ВидЦены                           КАК ВидЦены,
                |    
                |    ВЫБОР КОГДА ЦеныНоменклатурыСрезПоследних.Упаковка = Товары.Упаковка ТОГДА
                |        ЦеныНоменклатурыСрезПоследних.Цена
                |    ИНАЧЕ
                |        ЦеныНоменклатурыСрезПоследних.Цена/ЕСТЬNULL(&ТекстЗапросаКоэффициентУпаковки1,1)*ЕСТЬNULL(&ТекстЗапросаКоэффициентУпаковки3,1)
                |    КОНЕЦ КАК ДействующаяЦена,
                |    
                |    ВЫРАЗИТЬ(ВЫБОР КОГДА ЦеныНоменклатурыСрезПоследних.Цена <> 0 ТОГДА 100*(Товары.Цена - ВЫБОР КОГДА ЦеныНоменклатурыСрезПоследних.Упаковка = Товары.Упаковка ТОГДА
                |        ЦеныНоменклатурыСрезПоследних.Цена
                |    ИНАЧЕ
                |        ЦеныНоменклатурыСрезПоследних.Цена/ЕСТЬNULL(&ТекстЗапросаКоэффициентУпаковки1,1)*ЕСТЬNULL(&ТекстЗапросаКоэффициентУпаковки3,1)
                |    КОНЕЦ)/
                |    
                |    ВЫБОР КОГДА ЦеныНоменклатурыСрезПоследних.Упаковка = Товары.Упаковка ТОГДА
                |        ЦеныНоменклатурыСрезПоследних.Цена
                |    ИНАЧЕ
                |        ЦеныНоменклатурыСрезПоследних.Цена/ЕСТЬNULL(&ТекстЗапросаКоэффициентУпаковки1,1)*ЕСТЬNULL(&ТекстЗапросаКоэффициентУпаковки3,1)
                |    КОНЕЦ ИНАЧЕ 0.00 КОНЕЦ КАК Число(10,2)) КАК ПроцентИзменения
                |    
                |ПОМЕСТИТЬ Товары
                |ИЗ
                |    Документ.УстановкаЦенНоменклатуры.Товары КАК Товары
                |    
                |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры.СрезПоследних(&ДатаСреза, (Номенклатура, Характеристика, ВидЦены) В (ВЫБРАТЬ Т.Номенклатура, Т.Характеристика, Т.ВидЦены ИЗ Документ.УстановкаЦенНоменклатуры.Товары КАК Т ГДЕ Т.Ссылка = &УстановкаЦенНоменклатуры И Т.ВидЦены В (&ВидыЦен))) КАК ЦеныНоменклатурыСрезПоследних
                |
                |        ПО Товары.Номенклатура      = ЦеныНоменклатурыСрезПоследних.Номенклатура
                |            И Товары.Характеристика = ЦеныНоменклатурыСрезПоследних.Характеристика
                |            И Товары.ВидЦены        = ЦеныНоменклатурыСрезПоследних.ВидЦены
                |
                |ГДЕ
                |    Товары.Ссылка = &УстановкаЦенНоменклатуры
                |    И Товары.ВидЦены В (&ВидыЦен)
                |    И (
                |        ВЫБОР
                |            КОГДА Товары.Номенклатура.ИспользованиеХарактеристик <> ЗНАЧЕНИЕ(Перечисление.ВариантыИспользованияХарактеристикНоменклатуры.НеИспользовать)
                |                И Товары.Характеристика = ЗНАЧЕНИЕ(Справочник.ХарактеристикиНоменклатуры.ПустаяСсылка) ТОГДА ЛОЖЬ
                |            ИНАЧЕ ИСТИНА
                |        КОНЕЦ
                |    )
                |;
                |
                |ВЫБРАТЬ РАЗЛИЧНЫЕ
                |    Товары.ВидЦены КАК ВидЦены
                |ИЗ
                |    Товары КАК Товары
                |ГДЕ
                |    Товары.ВидЦены В (&ВидыЦен)
                |    И Товары.ПроцентИзменения <> 0 ИЛИ &Все
                |УПОРЯДОЧИТЬ ПО
                |    Товары.ВидЦены.РеквизитДопУпорядочивания
                |;
                |
                |ВЫБРАТЬ
                |    Товары.Номенклатура                      КАК Номенклатура,
                |    Товары.Характеристика                    КАК Характеристика,
                |    Товары.Номенклатура.НаименованиеПолное   КАК ПолноеНаименованиеНоменклатуры,
                |    Товары.Характеристика.НаименованиеПолное КАК ПолноеНаименованиеХарактеристики,
                |    Товары.Номенклатура.Код                  КАК Код,
                |    Товары.Номенклатура.Артикул              КАК Артикул,
                |    Товары.Упаковка                          КАК Упаковка,
                |    Товары.Номенклатура.ЕдиницаИзмерения     КАК ЕдиницаИзмерения,
                |    Товары.Цена                              КАК Цена,
                |    Товары.ВидЦены                           КАК ВидЦены,
                |    ЕСТЬNULL(Товары.ДействующаяЦена,0)       КАК СтараяЦена,
                |    Товары.ПроцентИзменения                  КАК ПроцентИзменения
                |    
                |ИЗ
                |    Товары КАК Товары
                |ГДЕ
                |    Товары.ПроцентИзменения <> 0 ИЛИ &Все
                |УПОРЯДОЧИТЬ ПО
                |    Товары.НомерСтроки
                |
                |ИТОГИ ПО
                |    Номенклатура, Характеристика");

(24) тут уже более-менее. И всё-равно так дико тормозит?

(25) нет, это работает нормально, пару секунд

(0)

Вот почитаешь такие темы и мысли в голову лезут:
- сначала переход на УТ 11.5, потом в отпуск
или
- сначала в отпуск, а потом переход

P.S.
Есть конечно вариант "пока буду в отпуске, перейдут без меня", но я уже слишком взрослый, чтобы в такое верить.

(27) лучше сначала в отпуск и после перехода снова в отпуск

Была у меня когда-то проблема с выводом печформ торг-12 и сф в ерп. Вывод длился до 10 минут. Вылечилось ТиИ

ПОМЕСТИТЬ Товары
                |ИЗ
                |    ТаблицаДанных КАК Товары
                |    
                |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры.СрезПоследних(&ДатаСреза, (Номенклатура, Характеристика, ВидЦены) В (ВЫБРАТЬ Т.Номенклатура, Т.Характеристика, Т.ВидЦены ИЗ Документ.УстановкаЦенНоменклатуры.Товары КАК Т)) КАК ЦеныНоменклатурыСрезПоследних
                |
                |        ПО Товары.Номенклатура      = ЦеныНоменклатурыСрезПоследних.Номенклатура
                |            И Товары.Характеристика = ЦеныНоменклатурыСрезПоследних.Характеристика
                |            И Товары.ВидЦены        = ЦеныНоменклатурыСрезПоследних.ВидЦены
////////////////////////////////
Если убрать отбор, наложенный на РегистрСведений.ЦеныНоменклатуры.СрезПоследних по полям, по которым делается объединение, будет еще быстрее. Те торможения, что я описывал выше в (12) как раз из-за этого и были

(0) монитор производительности предлагали уже?

Зокладко