Всех приветствую.

Не кидайтесь камнями. Туплю :(

Нужно в запросе получить Максимум(МоментВремени)  у поля Регистратор.
Ограничил разыменование до минимума.

    ВЫБОР
        КОГДА ХозрасчетныйОбороты.Регистратор ССЫЛКА Документ.ПоступлениеТоваровУслуг
            ТОГДА ВЫРАЗИТЬ(ХозрасчетныйОбороты.Регистратор КАК Документ.ПоступлениеТоваровУслуг).Ссылка
        КОГДА ХозрасчетныйОбороты.Регистратор ССЫЛКА Документ.РеализацияТоваровУслуг
            ТОГДА ВЫРАЗИТЬ(ХозрасчетныйОбороты.Регистратор КАК Документ.РеализацияТоваровУслуг).Ссылка
        КОГДА ХозрасчетныйОбороты.Регистратор ССЫЛКА Документ.ПоступлениеНаРасчетныйСчет
            ТОГДА ВЫРАЗИТЬ(ХозрасчетныйОбороты.Регистратор КАК Документ.ПоступлениеНаРасчетныйСчет).Ссылка
        КОГДА ХозрасчетныйОбороты.Регистратор ССЫЛКА Документ.СписаниеСРасчетногоСчета
            ТОГДА ВЫРАЗИТЬ(ХозрасчетныйОбороты.Регистратор КАК Документ.СписаниеСРасчетногоСчета).Ссылка
        КОГДА ХозрасчетныйОбороты.Регистратор ССЫЛКА Документ.КорректировкаРеализации
            ТОГДА ВЫРАЗИТЬ(ХозрасчетныйОбороты.Регистратор КАК Документ.КорректировкаРеализации).Ссылка
        КОГДА ХозрасчетныйОбороты.Регистратор ССЫЛКА Документ.КорректировкаПоступления
            ТОГДА ВЫРАЗИТЬ(ХозрасчетныйОбороты.Регистратор КАК Документ.КорректировкаПоступления).Ссылка
        КОГДА ХозрасчетныйОбороты.Регистратор ССЫЛКА Документ.КорректировкаДолга
            ТОГДА ВЫРАЗИТЬ(ХозрасчетныйОбороты.Регистратор КАК Документ.КорректировкаДолга).Ссылка
        КОГДА ХозрасчетныйОбороты.Регистратор ССЫЛКА Документ.ГТДИмпорт
            ТОГДА ВЫРАЗИТЬ(ХозрасчетныйОбороты.Регистратор КАК Документ.ГТДИмпорт).Ссылка
        КОГДА ХозрасчетныйОбороты.Регистратор ССЫЛКА Документ.ОтчетКомиссионераОПродажах
            ТОГДА ВЫРАЗИТЬ(ХозрасчетныйОбороты.Регистратор КАК Документ.ОтчетКомиссионераОПродажах).Ссылка
        КОГДА ХозрасчетныйОбороты.Регистратор ССЫЛКА Документ.ОтчетКомитентуОПродажах
            ТОГДА ВЫРАЗИТЬ(ХозрасчетныйОбороты.Регистратор КАК Документ.ОтчетКомитентуОПродажах).Ссылка
    КОНЕЦ КАК Регистратор,


Гуглёж не помог

Как максимум получить?)))

попробуй через временную таблицу - сначала получаешь табличку дат у регистраторов (ну можно проверку еще добавить на "йогурт без даты")

а уже в запросе из временной таблицы получай максимум от дат

Упорядочить?

(1) а что со ссылкой делать?

МоментВремени = это дата с точностью до секунды + Ссылка.
Попробовать сначала  получить максимумы по датам регистратора и потом внутреннее соединение по дате и макс. по ссылке.

(4) тебе же максимум по дате нужно получить по регистратору в запросе?

момент времени это момент времени. его потом можно у регистратора узнать

Новый МоментВремени(Документ.Дата, Документ) или Документ.МоментВремени()

(5) Да, в запросе

(4) Получилось.

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ВЫРАЗИТЬ(ХозрасчетныйОбороты.Субконто1 КАК Справочник.Контрагенты) КАК Контрагент,
    ВЫРАЗИТЬ(ХозрасчетныйОбороты.Субконто2 КАК Справочник.ДоговорыКонтрагентов) КАК Договор,
    ВЫБОР
        КОГДА ХозрасчетныйОбороты.Регистратор ССЫЛКА Документ.ПоступлениеТоваровУслуг
            ТОГДА ВЫРАЗИТЬ(ХозрасчетныйОбороты.Регистратор КАК Документ.ПоступлениеТоваровУслуг).Ссылка
        КОГДА ХозрасчетныйОбороты.Регистратор ССЫЛКА Документ.РеализацияТоваровУслуг
            ТОГДА ВЫРАЗИТЬ(ХозрасчетныйОбороты.Регистратор КАК Документ.РеализацияТоваровУслуг).Ссылка
        КОГДА ХозрасчетныйОбороты.Регистратор ССЫЛКА Документ.ПоступлениеНаРасчетныйСчет
            ТОГДА ВЫРАЗИТЬ(ХозрасчетныйОбороты.Регистратор КАК Документ.ПоступлениеНаРасчетныйСчет).Ссылка
        КОГДА ХозрасчетныйОбороты.Регистратор ССЫЛКА Документ.СписаниеСРасчетногоСчета
            ТОГДА ВЫРАЗИТЬ(ХозрасчетныйОбороты.Регистратор КАК Документ.СписаниеСРасчетногоСчета).Ссылка
        КОГДА ХозрасчетныйОбороты.Регистратор ССЫЛКА Документ.КорректировкаРеализации
            ТОГДА ВЫРАЗИТЬ(ХозрасчетныйОбороты.Регистратор КАК Документ.КорректировкаРеализации).Ссылка
        КОГДА ХозрасчетныйОбороты.Регистратор ССЫЛКА Документ.КорректировкаПоступления
            ТОГДА ВЫРАЗИТЬ(ХозрасчетныйОбороты.Регистратор КАК Документ.КорректировкаПоступления).Ссылка
        КОГДА ХозрасчетныйОбороты.Регистратор ССЫЛКА Документ.КорректировкаДолга
            ТОГДА ВЫРАЗИТЬ(ХозрасчетныйОбороты.Регистратор КАК Документ.КорректировкаДолга).Ссылка
        КОГДА ХозрасчетныйОбороты.Регистратор ССЫЛКА Документ.ГТДИмпорт
            ТОГДА ВЫРАЗИТЬ(ХозрасчетныйОбороты.Регистратор КАК Документ.ГТДИмпорт).Ссылка
        КОГДА ХозрасчетныйОбороты.Регистратор ССЫЛКА Документ.ОтчетКомиссионераОПродажах
            ТОГДА ВЫРАЗИТЬ(ХозрасчетныйОбороты.Регистратор КАК Документ.ОтчетКомиссионераОПродажах).Ссылка
        КОГДА ХозрасчетныйОбороты.Регистратор ССЫЛКА Документ.ОтчетКомитентуОПродажах
            ТОГДА ВЫРАЗИТЬ(ХозрасчетныйОбороты.Регистратор КАК Документ.ОтчетКомитентуОПродажах).Ссылка
    КОНЕЦ КАК Регистратор,
    ХозрасчетныйОбороты.Период КАК Период
ПОМЕСТИТЬ ВТ_Периоды__Срегистратором
ИЗ
    РегистрБухгалтерии.Хозрасчетный.Обороты(, &Период, Регистратор, ХозрасчетныйОбороты.Счет В ИЕРАРХИИ (&СписокСчетов) , , , , ) КАК ХозрасчетныйОбороты

ИНДЕКСИРОВАТЬ ПО
    Контрагент,
    Договор
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ВТ_Периоды__Срегистратором.Контрагент КАК Контрагент,
    ВТ_Периоды__Срегистратором.Договор КАК Договор,
    МАКСИМУМ(ВТ_Периоды__Срегистратором.Период) КАК ДатаПоследнейОперации
ПОМЕСТИТЬ ВТ_Периоды
ИЗ
    ВТ_Периоды__Срегистратором КАК ВТ_Периоды__Срегистратором

СГРУППИРОВАТЬ ПО
    ВТ_Периоды__Срегистратором.Контрагент,
    ВТ_Периоды__Срегистратором.Договор
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    МАКСИМУМ(ВТ_Периоды__Срегистратором.Регистратор) КАК Регистратор,
    ВТ_Периоды.ДатаПоследнейОперации КАК ДатаПоследнейОперации,
    ВТ_Периоды__Срегистратором.Контрагент КАК Контрагент,
    ВТ_Периоды__Срегистратором.Договор КАК Договор
ИЗ
    ВТ_Периоды__Срегистратором КАК ВТ_Периоды__Срегистратором
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ_Периоды КАК ВТ_Периоды
        ПО ВТ_Периоды__Срегистратором.Контрагент = ВТ_Периоды.Контрагент
            И ВТ_Периоды__Срегистратором.Договор = ВТ_Периоды.Договор
            И ВТ_Периоды__Срегистратором.Период = ВТ_Периоды.ДатаПоследнейОперации

СГРУППИРОВАТЬ ПО
    ВТ_Периоды__Срегистратором.Контрагент,
    ВТ_Периоды__Срегистратором.Договор,
    ВТ_Периоды.ДатаПоследнейОперации

Всем спасибо за помощь! Тема закрыта.