ERP 2.5: Ошибка "Включение учета себестоимости" по этапу производства при закрытии месяца

(19) // Выбираем документы, у которых есть движения по оперативным регистрам, но нет движений по учету себестоимости.
// Используются данные следующих оперативных регистров:
//    - Товары организаций
//        кроме таможенных деклараций с нулевыми суммами пошлины и НДС
//        кроме перемещений товаров в статусе "Отгружено"
//        кроме сборок товаров в статусе "В работе"
//++ Локализация
//        кроме уведомлений об остатках и ввозах прослеживаемых товаров (документы не делают движения по учету себестоимости)
//-- Локализация
//    - Товары организаций к передаче
//    - Товары переданные переработчику
//    - Товары полученные от переработчика
//    - Товары к оформлению таможенных деклараций (движения "Приход)
//    - Материалы и работы в производстве (учитываются работы при партионном учете версии 2.2,
//        при партионном учете 2.1 не используется одновременно с онлайн движениями по регистру "Себестоимость товаров")
//        исключаются движения у документов "Маршрутный лист производства", "Списание затрат на выпуск", "Распределение материалов и работ",
//        используемых для производства 2.1, т.к. эти документы не делают онлайн движений по регистру "Себестоимость товаров"
//        одновременно с регистром "Материалы и работы в производстве".
// Дополнительно к оперативным регистрам выбираем данные непосредственно из документов (у этих документов нет оперативных регистров):
//    - Отчет давальцу
//    - Заявление о ввозе товаров из ЕАЭС с заполненной суммой НДС
//    - Ввод остатков с выключенным флажком "ОУ"
// Исключения:
//    - Для движений себестоимости по разделу учета "Незавершенное производство" нет соответствующих оперативных регистров.
//        Но этот раздел учета всегда корреспондирует с другими разделами, которые имеют соответствующие оперативные регистры.
//        Поэтому движения по разделу "Незавершенное производстве" не проверяем. Они будут переформированы одновременно с другими движениями.
//    - Движения документов "Заявление о ввозе товаров из ЕАЭС" по себестоимости не имеют соответствующих оперативных регистров.
//        Проверяем данные в табличной части документов
//    - Движения документов "Распределение материалов и работ" при распределении материалов по правилу
//    - Движения документов "Исправление развернутого сальдо товаров организаций" если в движениях не меняется вид запасов.
//         У таких документов не будет движений по регистру "Себестоимость товаров".
//    - Документы корректировки регистров. У таких документов могут быть движения только по оперативным регистрам.
//    - Документы ввода начальных остатков, у которых снят флажок "Себестоимость" (у таких документов нет движений по учету себестоимости)
//
// Возвращаемое значение:
//    Строка - текст запроса
//
Функция ТекстЗапросаВключениеУчетаСебестоимости() Экспорт
    Возврат "
        // Выбираем таможенные декларации на импорт, в которых указаны нулевые суммы таможенной пошлины и НДС.
        |ВЫБРАТЬ РАЗЛИЧНЫЕ
        |    ДД.Ссылка,
        |    Строки.АналитикаУчетаНоменклатуры
        |ПОМЕСТИТЬ ДекларацииСНулевымиСуммами
        |ИЗ
        |    Документ.ТаможеннаяДекларацияИмпорт КАК ДД
        |    ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.ТаможеннаяДекларацияИмпорт.Товары КАК Строки
        |        ПО Строки.Ссылка = ДД.Ссылка
        |ГДЕ
        |    ДД.Дата МЕЖДУ &НачалоПериода И &КонецПериода
        |    И ДД.Организация В (&МассивОрганизаций)
        |    И ДД.Проведен
        |    И Строки.СуммаПошлины = 0
        |    И Строки.СуммаНДС = 0
        |    И ДД.Статус = ЗНАЧЕНИЕ(Перечисление.СтатусыТаможенныхДеклараций.ВыпущеноСТаможни)
        |
        |ОБЪЕДИНИТЬ ВСЕ
        |
        // Если в аналитике учета номенклатуры место хранения отличается от склада,
        // то подберем аналитику учета номенклатуры, соответствующую складу.
        |ВЫБРАТЬ РАЗЛИЧНЫЕ
        |    ДД.Ссылка,
        |    Аналитика.КлючАналитики КАК АналитикаУчетаНоменклатуры
        |ИЗ
        |    Документ.ТаможеннаяДекларацияИмпорт КАК ДД
        |    ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.ТаможеннаяДекларацияИмпорт.Товары КАК Строки
        |        ПО Строки.Ссылка = ДД.Ссылка
        |    ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.АналитикаУчетаНоменклатуры КАК Аналитика
        |        ПО Аналитика.Номенклатура = Строки.Номенклатура
        |        И Аналитика.Характеристика = Строки.Характеристика
        |        И Аналитика.Серия = Строки.Серия
        |        И Аналитика.МестоХранения = Строки.Склад
        |        И (ВЫБОР КОГДА &УчитыватьСебестоимостьТоваровПоНазначениям
        |            ТОГДА Аналитика.Назначение = Строки.Назначение
        |            ИНАЧЕ Аналитика.Назначение = ЗНАЧЕНИЕ(Справочник.Назначения.ПустаяСсылка) КОНЕЦ)
        |ГДЕ
        |    ДД.Дата МЕЖДУ &НачалоПериода И &КонецПериода
        |    И ДД.Организация В (&МассивОрганизаций)
        |    И ДД.Проведен
        |    И Строки.СуммаПошлины = 0
        |    И Строки.СуммаНДС = 0
        |    И ДД.Статус = ЗНАЧЕНИЕ(Перечисление.СтатусыТаможенныхДеклараций.ВыпущеноСТаможни)
        |;
        // Выбираем документы, у которых есть движения по оперативным регистрам.
        |ВЫБРАТЬ РАЗЛИЧНЫЕ
        |    Товары.Регистратор КАК Регистратор,
        |    Товары.Организация КАК Организация
        |ПОМЕСТИТЬ ДокументыСДвижениями
        |ИЗ (
        |    ВЫБРАТЬ РАЗЛИЧНЫЕ
        |        ТоварыОрганизаций.Регистратор КАК Регистратор,
        |        ТоварыОрганизаций.Организация КАК Организация
        |    ИЗ
        |        РегистрНакопления.ТоварыОрганизаций КАК ТоварыОрганизаций
        // Исключаем таможенные декларации с нулевыми суммами пошлины и НДС
        |        ЛЕВОЕ СОЕДИНЕНИЕ ДекларацииСНулевымиСуммами КАК Декларации
        |            ПО Декларации.Ссылка = ТоварыОрганизаций.Регистратор
        |            И Декларации.АналитикаУчетаНоменклатуры = ТоварыОрганизаций.АналитикаУчетаНоменклатуры
        |            И ТИПЗНАЧЕНИЯ(ТоварыОрганизаций.Регистратор) = ТИП(Документ.ТаможеннаяДекларацияИмпорт)
        // Исключаем перемещения товаров в статусе "Отгружено"
        |        ЛЕВОЕ СОЕДИНЕНИЕ Документ.ПеремещениеТоваров КАК Перемещение
        |            ПО Перемещение.Ссылка = ТоварыОрганизаций.Регистратор
        |            И Перемещение.Статус = ЗНАЧЕНИЕ(Перечисление.СтатусыПеремещенийТоваров.Отгружено)
        // Исключаем сторно перемещения товаров в статусе "Отгружено"
        |        ЛЕВОЕ СОЕДИНЕНИЕ Документ.Сторно КАК СторноПеремещенияТоваров
        |            ПО СторноПеремещенияТоваров.Ссылка = ТоварыОрганизаций.Регистратор
        |            И СторноПеремещенияТоваров.СторнируемыйДокумент ССЫЛКА Документ.ПеремещениеТоваров
        |            И ВЫРАЗИТЬ(СторноПеремещенияТоваров.СторнируемыйДокумент КАК Документ.ПеремещениеТоваров).Статус = ЗНАЧЕНИЕ(Перечисление.СтатусыПеремещенийТоваров.Отгружено)
        // Исключаем сборки товаров в статусе "В работе"
        |        ЛЕВОЕ СОЕДИНЕНИЕ Документ.СборкаТоваров КАК Сборка
        |            ПО Сборка.Ссылка = ТоварыОрганизаций.Регистратор
        |            И Сборка.Статус = ЗНАЧЕНИЕ(Перечисление.СтатусыСборокТоваров.ВРаботе)
        |    ГДЕ
        |        &ИспользоватьУчетСебестоимости
        |        И ТоварыОрганизаций.Период МЕЖДУ &НачалоПериода И &КонецПериода
        |        И ТоварыОрганизаций.Организация В(&МассивОрганизаций)
        |        И (ТоварыОрганизаций.ОрганизацияОтгрузки = ЗНАЧЕНИЕ(Справочник.Организации.ПустаяСсылка)
        |            ИЛИ ТоварыОрганизаций.ОрганизацияОтгрузки = ТоварыОрганизаций.Организация)
        |        И ТИПЗНАЧЕНИЯ(ТоварыОрганизаций.Регистратор) <> ТИП(Документ.КорректировкаРегистров)
        // Исключаем движения документов производства 2.2, для которых нет онлайн движений по регистру "Себестоимость товаров"
        |        И ТоварыОрганизаций.ХозяйственнаяОперация <> ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.РаспределениеРасходовНаПартииПроизводства)
        // Исключаем движения документов "Исправление развернутого сальдо товаров организаций" и "Корректировка назначения товаров",
        // если в движениях не меняется вид запасов. У таких документов не будет движений по регистру "Себестоимость товаров".
        |        И НЕ (
        |            ТоварыОрганизаций.ХозяйственнаяОперация = ЗНАЧЕНИЕ(Перечисление.ХозяйственныеОперации.КорректировкаОбособленногоУчета)
        |            И ТоварыОрганизаций.ВидЗапасов = ТоварыОрганизаций.КорВидЗапасов)
        // Исключаем таможенные декларации с нулевыми суммами пошлины и НДС
        |        И Декларации.Ссылка ЕСТЬ NULL
        // Исключаем вводы остатков с выключенным учетом себестоимости
        |        И ЕСТЬNULL(ВЫРАЗИТЬ(ТоварыОрганизаций.Регистратор КАК Документ.ВводОстатков).ОтражатьСебестоимость, ИСТИНА)
        |        И ЕСТЬNULL(ВЫРАЗИТЬ(ТоварыОрганизаций.Регистратор КАК Документ.ВводОстатковТоваров).ОтражатьСебестоимость, ИСТИНА)
        // Исключаем перемещения товаров в статусе "Отгружено"
        |        И Перемещение.Ссылка ЕСТЬ NULL
        // Исключаем сторно перемещения товаров в статусе "Отгружено"
        |        И СторноПеремещенияТоваров.Ссылка ЕСТЬ NULL
        // Исключаем сборки товаров в статусе "В работе"
        |        И Сборка.Ссылка ЕСТЬ NULL
        //++ Локализация
        // Исключаем уведомления об остатках и ввозах прослеживаемых товаров (документы не делают движений по учету себестоимости)
        |        И ТИПЗНАЧЕНИЯ(ТоварыОрганизаций.Регистратор) <> ТИП(Документ.УведомлениеОбОстаткахПрослеживаемыхТоваров)
        |        И ТИПЗНАЧЕНИЯ(ТоварыОрганизаций.Регистратор) <> ТИП(Документ.УведомлениеОВвозеПрослеживаемыхТоваров)
        //-- Локализация
        |
        |    ОБЪЕДИНИТЬ ВСЕ
        |
        |    ВЫБРАТЬ РАЗЛИЧНЫЕ
        |        ТоварыОрганизацийКПередаче.Регистратор КАК Регистратор,
        |        ТоварыОрганизацийКПередаче.ВидЗапасовПродавца.Организация КАК Организация
        |    ИЗ
        |        РегистрНакопления.ТоварыОрганизацийКПередаче КАК ТоварыОрганизацийКПередаче
        |    ГДЕ
        |        &ИспользоватьУчетСебестоимости
        |        И ТоварыОрганизацийКПередаче.Период МЕЖДУ &НачалоПериода И &КонецПериода
        |        И ТоварыОрганизацийКПередаче.ВидЗапасовПродавца.Организация В(&МассивОрганизаций)
        |        И ТИПЗНАЧЕНИЯ(ТоварыОрганизацийКПередаче.Регистратор) <> ТИП(Документ.КорректировкаРегистров)
        |
        //++ НЕ УТ
        |    ОБЪЕДИНИТЬ ВСЕ
        |
        |    ВЫБРАТЬ РАЗЛИЧНЫЕ
        |        ТоварыПереданныеПереработчику.Регистратор КАК Регистратор,
        |        ТоварыПереданныеПереработчику.ВидЗапасов.Организация КАК Организация
        |    ИЗ
        |        РегистрНакопления.ТоварыПереданныеПереработчику КАК ТоварыПереданныеПереработчику
        |    ГДЕ
        |        &ИспользоватьУчетСебестоимости
        |        И ТоварыПереданныеПереработчику.Период МЕЖДУ &НачалоПериода И &КонецПериода
        |        И ТоварыПереданныеПереработчику.ВидЗапасов.Организация В(&МассивОрганизаций)
        |        И ТИПЗНАЧЕНИЯ(ТоварыПереданныеПереработчику.Регистратор) <> ТИП(Документ.КорректировкаРегистров)
        // Исключаем вводы остатков с выключенным учетом себестоимости
        |        И ЕСТЬNULL(ВЫРАЗИТЬ(ТоварыПереданныеПереработчику.Регистратор КАК Документ.ВводОстатков).ОтражатьСебестоимость, ИСТИНА)
        |        И ЕСТЬNULL(ВЫРАЗИТЬ(ТоварыПереданныеПереработчику.Регистратор КАК Документ.ВводОстатковТоваров).ОтражатьСебестоимость, ИСТИНА)
        |
        |    ОБЪЕДИНИТЬ ВСЕ
        |
        |    ВЫБРАТЬ РАЗЛИЧНЫЕ
        |        ТоварыПолученныеОтПереработчика.Регистратор КАК Регистратор,
        |        ТоварыПолученныеОтПереработчика.Организация КАК Организация
        |    ИЗ
        |        РегистрНакопления.ТоварыПолученныеОтПереработчика КАК ТоварыПолученныеОтПереработчика
        |    ГДЕ
        |        &ИспользоватьУчетСебестоимости
        |        И ТоварыПолученныеОтПереработчика.Период МЕЖДУ &НачалоПериода И &КонецПериода
        |        И ТоварыПолученныеОтПереработчика.Организация В(&МассивОрганизаций)
        |        И ТИПЗНАЧЕНИЯ(ТоварыПолученныеОтПереработчика.Регистратор) <> ТИП(Документ.КорректировкаРегистров)
        //-- НЕ УТ
        |
        |    ОБЪЕДИНИТЬ ВСЕ
        |
        |    ВЫБРАТЬ РАЗЛИЧНЫЕ
        |        ТоварыКОформлениюДокументовИмпорта.Регистратор КАК Регистратор,
        |        ТоварыКОформлениюДокументовИмпорта.Организация КАК Организация
        |    ИЗ
        |        РегистрНакопления.ТоварыКОформлениюДокументовИмпорта КАК ТоварыКОформлениюДокументовИмпорта
        |    ГДЕ
        |        &ИспользоватьУчетСебестоимости
        |        И ТоварыКОформлениюДокументовИмпорта.Период МЕЖДУ &НачалоПериода И &КонецПериода
        |        И ТоварыКОформлениюДокументовИмпорта.Организация В(&МассивОрганизаций)
        |        И ТоварыКОформлениюДокументовИмпорта.ВидДвижения = ЗНАЧЕНИЕ(ВидДвиженияНакопления.Приход)
        |        И ТИПЗНАЧЕНИЯ(ТоварыКОформлениюДокументовИмпорта.Регистратор) <> ТИП(Документ.КорректировкаРегистров)
        |        И ТоварыКОформлениюДокументовИмпорта.ТипДокументаИмпорта = &ТипДокументаИмпорта
        |
        |    ОБЪЕДИНИТЬ ВСЕ
        |
        |    ВЫБРАТЬ РАЗЛИЧНЫЕ
        |        МатериалыИРаботыВПроизводстве.Регистратор КАК Регистратор,
        |        МатериалыИРаботыВПроизводстве.Организация КАК Организация
        |    ИЗ
        |        РегистрНакопления.МатериалыИРаботыВПроизводстве КАК МатериалыИРаботыВПроизводстве
        |    ГДЕ
        |        &ИспользоватьУчетСебестоимости
        |        И МатериалыИРаботыВПроизводстве.Период МЕЖДУ &НачалоПериода И &КонецПериода
        |        И МатериалыИРаботыВПроизводстве.Организация В(&МассивОрганизаций)
        |        И МатериалыИРаботыВПроизводстве.Количество <> 0
        |        И НЕ ТИПЗНАЧЕНИЯ(МатериалыИРаботыВПроизводстве.Регистратор) В (
        |            ТИП(Документ.КорректировкаРегистров),
        |            ТИП(Документ.РасчетСебестоимостиТоваров))
        // Исключаем вводы остатков с выключенным учетом себестоимости
        |        И ЕСТЬNULL(ВЫРАЗИТЬ(МатериалыИРаботыВПроизводстве.Регистратор КАК Документ.ВводОстатков).ОтражатьСебестоимость, ИСТИНА)
        |        И ЕСТЬNULL(ВЫРАЗИТЬ(МатериалыИРаботыВПроизводстве.Регистратор КАК Документ.ВводОстатковТоваров).ОтражатьСебестоимость, ИСТИНА)
        //++ НЕ УТ

        // Кроме документов "Распределение материалов и работ". Они делают движения по регистру "Материалы и работы в производстве",
        // но не всегда имеют движения по регистру "Себестоимость товаров".
        |        И ТИПЗНАЧЕНИЯ(МатериалыИРаботыВПроизводстве.Регистратор) <> ТИП(Документ.РаспределениеПроизводственныхЗатрат)
        //++ Устарело_Производство21
        // При использовании производства 2.1 документы "Маршрутный лист производства", "Списание затрат на выпуск" и "Распределение материалов и работ"
        // не имеют онлайн движений по регистру "Себестоимость товаров".
        |        И ТИПЗНАЧЕНИЯ(МатериалыИРаботыВПроизводстве.Регистратор) <> ТИП(Документ.СписаниеЗатратНаВыпуск)
        //++ НЕ УТКА
        |        И ТИПЗНАЧЕНИЯ(МатериалыИРаботыВПроизводстве.Регистратор) <> ТИП(Документ.МаршрутныйЛистПроизводства)
        //-- НЕ УТКА

        //-- Устарело_Производство21

        //-- НЕ УТ
        |
        //++ НЕ УТКА
        |    ОБЪЕДИНИТЬ ВСЕ
        |
        |    ВЫБРАТЬ РАЗЛИЧНЫЕ
        |        ОтчетДавальцу.Ссылка КАК Регистратор,
        |        ОтчетДавальцу.Организация КАК Организация
        |    ИЗ
        |        Документ.ОтчетДавальцу КАК ОтчетДавальцу
        |    ГДЕ
        |        &ИспользоватьУчетСебестоимости
        |        И ОтчетДавальцу.Дата МЕЖДУ &НачалоПериода И &КонецПериода
        |        И ОтчетДавальцу.Организация В(&МассивОрганизаций)
        |        И ОтчетДавальцу.Проведен
        //-- НЕ УТКА
        |
        //++ Локализация
        |    ОБЪЕДИНИТЬ ВСЕ
        |
        |    ВЫБРАТЬ РАЗЛИЧНЫЕ
        |        ЗаявлениеОВвозеТовары.Ссылка КАК Регистратор,
        |        ЗаявлениеОВвозеТовары.Ссылка.Организация КАК Организация
        |    ИЗ
        |        Документ.ЗаявлениеОВвозеТоваров.Товары КАК ЗаявлениеОВвозеТовары
        |    ГДЕ
        |        &ИспользоватьУчетСебестоимости
        |        И ЗаявлениеОВвозеТовары.Ссылка.Дата МЕЖДУ &НачалоПериода И &КонецПериода
        |        И ЗаявлениеОВвозеТовары.Ссылка.Организация В(&МассивОрганизаций)
        |        И ЗаявлениеОВвозеТовары.Ссылка.Проведен
        |        И ЗаявлениеОВвозеТовары.СуммаНДС <> 0
        //-- Локализация
        |
        |    ОБЪЕДИНИТЬ ВСЕ
        |
        |    ВЫБРАТЬ РАЗЛИЧНЫЕ
        |        ВводОстатков.Ссылка КАК Регистратор,
        |        ВводОстатков.Ссылка.Организация КАК Организация
        |    ИЗ
        |        Документ.ВводОстатков.Товары КАК ВводОстатков
        |    ГДЕ
        |        &ИспользоватьУчетСебестоимости
        |        И ВводОстатков.Ссылка.ОтражатьСебестоимость
        |        И НЕ ВводОстатков.Ссылка.ОтражатьВОперативномУчете
        |        И ВводОстатков.Ссылка.Дата МЕЖДУ &НачалоПериода И &КонецПериода
        |        И ВводОстатков.Ссылка.Организация В(&МассивОрганизаций)
        |        И ВводОстатков.Ссылка.Проведен
        |
        |    ОБЪЕДИНИТЬ ВСЕ
        |
        |    ВЫБРАТЬ РАЗЛИЧНЫЕ
        |        ВводОстатков.Ссылка КАК Регистратор,
        |        ВводОстатков.Ссылка.Организация КАК Организация
        |    ИЗ
        |        Документ.ВводОстатковТоваров.Товары КАК ВводОстатков
        |    ГДЕ
        |        &ИспользоватьУчетСебестоимости
        |        И ВводОстатков.Ссылка.ОтражатьСебестоимость
        |        И НЕ ВводОстатков.Ссылка.ОтражатьВОперативномУчете
        |        И ВводОстатков.Ссылка.Дата МЕЖДУ &НачалоПериода И &КонецПериода
        |        И ВводОстатков.Ссылка.Организация В(&МассивОрганизаций)
        |        И ВводОстатков.Ссылка.Проведен
        |    ) КАК Товары
        |ИНДЕКСИРОВАТЬ ПО
        |    Регистратор,
        |    Организация
        |;
        // Выбираем документы, у которых есть движения по себестоимости.
        |ВЫБРАТЬ РАЗЛИЧНЫЕ
        |    СебестоимостьТоваров.Регистратор КАК Регистратор,
        |    СебестоимостьТоваров.Организация КАК Организация
        |
        |ПОМЕСТИТЬ ЕстьДвиженияСебестоимости
        |ИЗ
        |    РегистрНакопления.СебестоимостьТоваров КАК СебестоимостьТоваров
        |    ВНУТРЕННЕЕ СОЕДИНЕНИЕ ДокументыСДвижениями КАК ДокументыСДвижениями
        |        ПО ДокументыСДвижениями.Регистратор = СебестоимостьТоваров.Регистратор
        |        И ДокументыСДвижениями.Организация = СебестоимостьТоваров.Организация
        |ГДЕ
        |    &ИспользоватьУчетСебестоимости
        |    И СебестоимостьТоваров.Период МЕЖДУ &НачалоПериода И &КонецПериода
        |    И СебестоимостьТоваров.Организация В(&МассивОрганизаций)
        |    И НЕ СебестоимостьТоваров.РасчетСебестоимости
        |    И НЕ СебестоимостьТоваров.РасчетПартий
        |ИНДЕКСИРОВАТЬ ПО
        |    Регистратор,
        |    Организация
        |;
        //Выбираем документы, у которых есть движения по оперативным регистрам, но нет движений по учету себестоимости.
        |ВЫБРАТЬ РАЗЛИЧНЫЕ
        |    ""СебестоимостьТоваров""            КАК ИмяРегистра,
        |    ДокументыСДвижениями.Регистратор    КАК Ссылка,
        |    ДокументыСДвижениями.Организация    КАК Организация,
        |    1                                    КАК КодОшибки
        |ПОМЕСТИТЬ ВТРегистраторыСНекорректнымиДвижениями
        |ИЗ
        |    ДокументыСДвижениями КАК ДокументыСДвижениями
        |
        |    ЛЕВОЕ СОЕДИНЕНИЕ ЕстьДвиженияСебестоимости КАК ЕстьДвиженияСебестоимости
        |        ПО ЕстьДвиженияСебестоимости.Регистратор = ДокументыСДвижениями.Регистратор
        |        И ЕстьДвиженияСебестоимости.Организация = ДокументыСДвижениями.Организация
        |ГДЕ
        |    &ИспользоватьУчетСебестоимости
        |    И ЕстьДвиженияСебестоимости.Регистратор ЕСТЬ NULL
        |;
        |УНИЧТОЖИТЬ ДекларацииСНулевымиСуммами;
        |УНИЧТОЖИТЬ ДокументыСДвижениями;
        |УНИЧТОЖИТЬ ЕстьДвиженияСебестоимости
        |";
КонецФункции