Стоит задача создать отчет по созданным за период контрагентам. Реквизит аля "ДатаСоздания" отсутствует, дополнительных документов при создании элемента справочника не создается.
Вижу два варианта: вычисление даты создания из GUID и ВыгрузитьЖурналРегистрации(). Остановился на втором.

Выгружаю в таблицу значений, всё успешно. Но при попытке передать полученную ТЗ в запрос, выдает ошибку "Тип не может быть выбран в запросе". Пробую типизировать перед передачей в функцию выгрузки - эффект тот же, типизация слетает.

Полный код:

    Фильтр = Новый Структура("ДатаНачала,ДатаОкончания,Событие,Метаданные");
    Фильтр.ДатаНачала = НачалоПериода;
    Фильтр.ДатаОкончания = КонецПериода;
    Фильтр.Событие = "_$Data$_.New";
    Фильтр.Метаданные = Метаданные.Справочники.Контрагенты;
    
    // Попытка типизации
    ТЗ = Новый ТаблицаЗначений;
    ТЗ.Колонки.Добавить("Данные", Новый ОписаниеТипов("СправочникСсылка.Контрагенты"));
    
    ВыгрузитьЖурналРегистрации(ТЗ, Фильтр, "Данные");
    
    Запрос = Новый Запрос;
    Запрос.Текст =
        "ВЫБРАТЬ
        |    ТЗ.Данные КАК Данные
        |ПОМЕСТИТЬ ВТТЗ
        |ИЗ
        |    &ТЗ КАК ТЗ
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |ВЫБРАТЬ
        |    ВТТЗ.Данные КАК Данные
        |ИЗ
        |    ВТТЗ КАК ВТТЗ";

    Запрос.УстановитьПараметр("ТЗ", ТЗ);    
    
    РезультатЗапроса = Запрос.Выполнить().Выгрузить();

Как наиболее эффективно типизировать эту колонку? По задумке, я получаю список созданных за месяц контрагентов, а потом расширяю его необходимыми для отчета данными в запросе.

можно сортировать по ссылке

а, за период, не понял

Запрос = Новый Запрос;
    Запрос.Текст =
        "ВЫБРАТЬ
        |    ВЫРАЗИТЬ(ТЗ.Данные КАК Справочник.Контрагенты)  КАК Данные
        |ПОМЕСТИТЬ ВТТЗ
        |ИЗ
        |    &ТЗ КАК ТЗ

после ВыгрузитьЖурналРегистрации(ТЗ, Фильтр, "Данные") тз ведь перетрется, значит типизировать нужно после
либо 3 да, если отработает

масиивконтров = тз.выгрузитьколонку("Данные")
?

(3) по причине:
{(2, 2)}: Несовместимые типы "ВЫРАЗИТЬ"
<<?>>ВЫРАЗИТЬ(ТЗ.Данные КАК Справочник.Контрагенты) КАК Данные

(6) а что там вообще в колонке "данные"? журнал то текстовый по сути

(7) Записи типа Справочник.Контрагенты: https://pastenow.ru/966a8f8ea92d8af09e22aaaa535f8ed3

(4) после не получится, типизация возможна только при создании или выгрузке

(9) та ну

(7) судя по сп должны быть составного
Данные (Data) - данные, произвольного типа, в зависимости от события

(8) видимо таки тип составной, да с NULL

действительно не выбирает
ну так можно
ВыгрузитьЖурналРегистрации(ТЗ, Фильтр, "Данные");
ТЗ.Колонки.Добавить("Хренанные", Новый ОписаниеТипов("СправочникСсылка.Контрагенты"));
    
Для Каждого Строка Из ТЗ Цикл
        Строка.Хренанные = Строка.Данные;
КонецЦикла;

вцелом если надо определить добавленных за период, то это учитывается фильтром здесь ВыгрузитьЖурналРегистрации(ТЗ, Фильтр, "Данные");

а тип данных эта история ВыгрузитьЖурналРегистрации забавный какой то возвращает, даже не тип, а типок какой то неясный

(14) Это просто пустое описание типов, всё равно что написать Новый ОписаниеТипов("") или Новый ОписаниеТипов(Новый Массив).

(0) может есть версионирование

(15) да, но тип у колонки только на чтение, так что..

(13) Спасибо, вариант с копированием вертелся в голове, но думал может что-то поинтереснее найдется
Задача определения добавленных за период выполнена изначально, к ней вопросов нет, фильтр отрабатывает верно

По итогу просто передал полученную из ВыгрузитьЖурналРегистрации() таблицу значений в СКД. Дополнительные данные получил через точку в настройках группировки СКД (Данные.ИНН...).

Итоговый код:
Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)
    
    СтандартнаяОбработка = Ложь;
    
    СхемаКомпоновкиДанных = ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных");
    Настройки = КомпоновщикНастроек.ПолучитьНастройки();
    ДанныеРасшифровки = Новый ДанныеРасшифровкиКомпоновкиДанных;
    КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;    
    
    НачалоПериода = Настройки.ПараметрыДанных.Элементы.Найти("НачалоПериода").Значение;
    КонецПериода = Настройки.ПараметрыДанных.Элементы.Найти("КонецПериода").Значение;
    
    МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, Настройки, ДанныеРасшифровки);    
    
    // Создаём фильтр для журнала регистрации
    Фильтр = Новый Структура("ДатаНачала,ДатаОкончания,Событие,Метаданные");
    Фильтр.ДатаНачала = НачалоПериода;
    Фильтр.ДатаОкончания = КонецПериода;
    Фильтр.Событие = "_$Data$_.New";
    Фильтр.Метаданные = Метаданные.Справочники.Контрагенты;
    
    // Выгружаем записи журнала в ТЗ: "Дата" - дата создания, "Данные" - элемент справочника "Контрагенты"
    ТЗ = Новый ТаблицаЗначений;
    ВыгрузитьЖурналРегистрации(ТЗ, Фильтр, "Дата,Данные");
    
    // Передаём ТЗ в СКД
    ВнешнийНаборДанных = Новый Структура("ТаблицаЗначений", ТЗ);
    ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
    ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки, ВнешнийНаборДанных, ДанныеРасшифровки);
    
    ДокументРезультат.Очистить();
    
    ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
    ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
    ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);
    
КонецПроцедуры

(16) Нет, версионирование для этого справочника отключено. Да и не до конца представляю, как из данных версионирования вытащить только контргаентов, которые были созданы за период. Журнал регистрации подошел отлично

(0) Нафуя знать когда контрагент создан?
Не проще первые документы где контрагент появился взять?

(21) Плановый отдел отчитывается о количестве новых клиентов за период.
Я предлагал им определить по документам, но в каких-то редких случаях никаких документов не создается, заводится только новый контрагент.
Плюс пришлось бы проверять что это действительно первый документ у данного контрагента. И на первый взгляд, алгоритм не очень бы эффективный получился.

(22) ну так новый элемент в справочнике - еще не клиент. если появился договор, значит началось движение, значит клиент
и потом, могут одного и того же в реальности создавать в базе повторно... в общем методика определения состояния дел на предприятии по созданным в справочнике контрагенте некорректная имхо

+ закончился договор следовательно и поставки, клиент отвалился, потом через год возобновился и т д и т д. определять по элементам справочника это чепуха.

(0) Оффтопик, но

>Реквизит аля "ДатаСоздания" отсутствует
>Вижу два варианта: вычисление даты создания из GUID и ВыгрузитьЖурналРегистрации()

Почему начинаешь с самых сложных: Почему бы просто не создать такой реквизит и не заполнять его? Хотя бы как доп. реквизит.

(25) причем автоматически при записи заполнять если пустой

(26)+ для всех старых контрагентов заполнить по документам или еще как

(26) в договоре есть, это и "пометодичнее" будет

(24) Да, логика странная, согласен. Но они по такому принципу отчитываются уже n лет до моего прихода, причем раньше новые контрагенты вычленялись в отчет ещё более "интересным" методом: по нумерации из справочника. Но потом что-то поломалось

(25) Добавление реквизита - это первое, что пришло в голову. Но в тот момент им требовались данные за прошедший месяц, так что пришлось бы решать вопрос с заполнением дат. Да и по итогу, использование варианта с ВыгрузитьЖурналРегистрации() оказалось довольно простым вариантом

(28) Повторюсь: иногда они заводят только контрагента без проведения каких-либо документов. По какому принципу и зачем - не знаю.

Да и вообще, насколько методично создавать новый реквизит ради одного отчета, который используется раз в месяц?

(31) База треснет? Дата и автор создания объекта иногда нужные вещи и лучше, если они лежат под рукой и доступны не только программисту.

(0)А зачем тебе помещать в запрос ТЗ и потом тут же её выгружать через него? Или там еще какие-то действа с ней планируются? Бери готовую ТЗ и по ней ходи циклом.

(33) Планировались. Потом всё пришло к (19)