Не подскажите : Поставили Документооборот 3.0, задали структуру предприятия, сотрудников...
Как сделать так, чтобы какой-то пользователь (сотрудник) не мог сам создавать задачи на исполнение например  ( по умолчанию всем ставятся полномочия "Пользователь" , их нельзя отключить как я понял , и пользователь через "Совместная работа - Мои процессы" может создать иполнение и послать его хоть директору ) ??
речь идет именно об элементарных процессах, не из документов.

т.е. в более широком смысле можно сделать так, чтобы Иванов мог создавать только исполнения, Петров ознакомленияч и исполнения и т.п.

Административно. Или заниматься дописками.

(1) Административно это значит словесно запретить ? :)
нет возможности без дописок манипуляцией с правами это сделать ?

Нет. Права не регулируют, кто кому может поставить задачу. Любая Зульфия башибузуковна, может поставить гендиру задачу поднять его толстую задницу, и убраться из кабинета на время уборки.

(3) А правильно и я понимаю, что полномочия "Пользователь" - это те минимальные полномочия, которые можно дать сотруднику ? т.е. когда мы создаем нового пользователя. ему по умолчанию ставится "Пользователь" и потом мы можем только добавить ему еще полномочия ( расширить их ) , ну или настраивать ему доступ к документам уже в самих видах документов с помощью ролей, групп и т.п. ?

(3) я в ДО 2.1. в шаблон комплексного процесса добавил _КодПередСтартом реквизит (ну естественно на форме шаблона добавил юзабилити приятный для его заполнения)

и в событии перед записью комплексного процесса выполняется произвольный код из этого реквизита

типа такого:

Подробности

//Код выполняется в подписке на событие ПередЗаписью
//Источник: БизнесПроцессОбъект.КомплексныйПроцесс

Если Источник.Предметы[0].Предмет.ВидДокумента.Наименование = "Договор/Доп.соглашение" Тогда

    СостояниеПредмета = Делопроизводство.ПолучитьПоследнееСостояниеДокумента(Источник.Предметы[0].Предмет);

    Если СостояниеПредмета <> ПредопределенноеЗначение("Перечисление.СостоянияДокументов.Согласован") Тогда
    
        ВызватьИсключение("Запуск процесса ' тут наименование шаблона' невозможен
                        |Договор находится на стадии согласования.");    
        
    КонецЕсли;  
    
КонецЕсли;

а там уже у Источника и предмета хочешь по виду документа проверяй, хочешь по Автору, хоть по значениям доп.реквизитов и сведений...

если Зульфия станет ставить задачу гендиру оторвать жопу от кресла - при попытке Стартовать и закрыть - будет получать окно с ашипкой...

пробовал добавить Обормотку с произвольным кодом в схему процесса в шаблоне комплексного процесса и вызывать исключение, но сцуко это исключение оборачивается и пишет в журнал регистрации. Сам процесс не стартует, но пойди догадайся - что не так?

поэтому сделал по рабоче-крестьянски :) а как правильно?

(5) в комплексном это прокатит. А вот в простом исполнении уже нет. Там некуда код до начала вставлять.

По правильному решается запретом пользователям использовать шаблоны процессов кроме разрешенных. Доработка простая. Вставляется проверка перед процедурой заполнения формы списком шаблонов процессов. А в разрешенных можно вставить блок с кодом проверки полномочий по отдаче распоряжений и т.п. в каком угодно виде.

Общий модуль ПомощникОтправить

&Перед("ДобавитьВДеревоОсновныеВариантыСозданияПроцесса")

Процедура uhc200724_ДобавитьВДеревоОсновныеВариантыСозданияПроцесса(Помощник)
    УстановитьПривилегированныйРежим(Истина);
    
    СписокРазрешенныхШаблонов = Новый СписокЗначений;
    
    СписокВидовДокументов = Новый СписокЗначений;
    
    ФлагЕстьДокументы = Ложь;
    
    Для каждого ОбъектОтправки Из Помощник.ОбъектыОтправки Цикл
        Если ТипЗнч(ОбъектОтправки) = Тип("СправочникСсылка.ВнутренниеДокументы")
            ИЛИ ТипЗнч(ОбъектОтправки) = Тип("СправочникСсылка.ВходящиеДокументы")
            ИЛИ ТипЗнч(ОбъектОтправки) = Тип("СправочникСсылка.ИсходящиеДокументы") Тогда
            ФлагЕстьДокументы = Истина;
            Если СписокВидовДокументов.НайтиПоЗначению(ОбъектОтправки.ВидДокумента) = Неопределено Тогда
                СписокВидовДокументов.Добавить(ОбъектОтправки.ВидДокумента);
            КонецЕсли;
        ИначеЕсли ТипЗнч(ОбъектОтправки) = Тип("СправочникСсылка.Пользователи") Тогда
            Возврат;
        КонецЕсли;
    КонецЦикла;
    
    Попытка
        Если Помощник.РежимРаботы <> "ОтправкаОбъектов" Тогда
            ФлагЕстьДокументы = Ложь;
        КонецЕсли;
    Исключение
        ФлагЕстьДокументы = Ложь;
    КонецПопытки;
    
    Если ФлагЕстьДокументы Тогда
        
        СписокШаблонов = Новый СписокЗначений;
        
        Для каждого ТекущийВариант Из Помощник.ВариантыСозданияПроцессовПоУмолчанию Цикл
            СписокШаблонов.Добавить(ТекущийВариант.Ключ);
        КонецЦикла;
        Для каждого ТекущийВариант Из Помощник.ОбщиеВариантыСозданияПроцессов Цикл
            СписокШаблонов.Добавить(ТекущийВариант.Ключ);
        КонецЦикла;
        Для каждого ТекущийВариант Из Помощник.РекомендуемыеВариантыСозданияПроцессов Цикл
            СписокШаблонов.Добавить(ТекущийВариант.Ключ);
        КонецЦикла;
        Для каждого ТекущийВариант Из Помощник.ДругиеВариантыСозданияПроцессов Цикл
            СписокШаблонов.Добавить(ТекущийВариант.Ключ);
        КонецЦикла;
        
        ТекущийПользователь = Пользователи.ТекущийПользователь();
        
        Запрос = Новый Запрос;
        Запрос.УстановитьПараметр("СписокВидовДокументов", СписокВидовДокументов);
        Запрос.УстановитьПараметр("СписокШаблонов", СписокШаблонов);
        Запрос.УстановитьПараметр("КоличествоВидовДокументов", СписокВидовДокументов.Количество());
        Запрос.УстановитьПараметр("Пользователь", ТекущийПользователь);
        Запрос.УстановитьПараметр("ПолныеПрава", РольДоступна("ПолныеПрава"));
        
        Запрос.Текст =
        "ВЫБРАТЬ РАЗЛИЧНЫЕ
        |    ПЗ.Исполнитель КАК Исполнитель
        |ПОМЕСТИТЬ ТЗИсполнители
        |ИЗ
        |    (ВЫБРАТЬ
        |        Пользователи.Ссылка КАК Исполнитель
        |    ИЗ
        |        Справочник.Пользователи КАК Пользователи
        |    ГДЕ
        |        Пользователи.Ссылка = &Пользователь
        |    
        |    ОБЪЕДИНИТЬ
        |    
        |    ВЫБРАТЬ
        |        СведенияОПользователяхДокументооборот.Подразделение
        |    ИЗ
        |        РегистрСведений.СведенияОПользователяхДокументооборот КАК СведенияОПользователяхДокументооборот
        |    ГДЕ
        |        СведенияОПользователяхДокументооборот.Пользователь = &Пользователь
        |    
        |    ОБЪЕДИНИТЬ
        |    
        |    ВЫБРАТЬ
        |        СоставыГруппПользователей.ГруппаПользователей
        |    ИЗ
        |        РегистрСведений.СоставыГруппПользователей КАК СоставыГруппПользователей
        |    ГДЕ
        |        СоставыГруппПользователей.Пользователь = &Пользователь
        |        И СоставыГруппПользователей.Используется = ИСТИНА
        |    
        |    ОБЪЕДИНИТЬ
        |    
        |    ВЫБРАТЬ
        |        ИсполнителиЗадач.РольИсполнителя
        |    ИЗ
        |        РегистрСведений.ИсполнителиЗадач КАК ИсполнителиЗадач
        |    ГДЕ
        |        ИсполнителиЗадач.Исполнитель = &Пользователь) КАК ПЗ
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |ВЫБРАТЬ РАЗЛИЧНЫЕ
        |    ВидыДокументов.Ссылка КАК ВидДокумента
        |ПОМЕСТИТЬ ТЗВидыДокументов
        |ИЗ
        |    (ВЫБРАТЬ
        |        ВидыВнутреннихДокументов.Ссылка КАК Ссылка
        |    ИЗ
        |        Справочник.ВидыВнутреннихДокументов КАК ВидыВнутреннихДокументов
        |    ГДЕ
        |        ВидыВнутреннихДокументов.Ссылка В(&СписокВидовДокументов)
        |    
        |    ОБЪЕДИНИТЬ ВСЕ
        |    
        |    ВЫБРАТЬ
        |        ВидыВходящихДокументов.Ссылка
        |    ИЗ
        |        Справочник.ВидыВходящихДокументов КАК ВидыВходящихДокументов
        |    ГДЕ
        |        ВидыВходящихДокументов.Ссылка В(&СписокВидовДокументов)
        |    
        |    ОБЪЕДИНИТЬ ВСЕ
        |    
        |    ВЫБРАТЬ
        |        ВидыИсходящихДокументов.Ссылка
        |    ИЗ
        |        Справочник.ВидыИсходящихДокументов КАК ВидыИсходящихДокументов
        |    ГДЕ
        |        ВидыИсходящихДокументов.Ссылка В(&СписокВидовДокументов)) КАК ВидыДокументов
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |ВЫБРАТЬ РАЗЛИЧНЫЕ
        |    Шаблоны.Ссылка КАК ШаблонБизнесПроцесса
        |ПОМЕСТИТЬ ТЗШаблоны
        |ИЗ
        |    (ВЫБРАТЬ
        |        ШаблоныИсполнения.Ссылка КАК Ссылка
        |    ИЗ
        |        Справочник.ШаблоныИсполнения КАК ШаблоныИсполнения
        |    ГДЕ
        |        ШаблоныИсполнения.Ссылка В(&СписокШаблонов)
        |    
        |    ОБЪЕДИНИТЬ ВСЕ
        |    
        |    ВЫБРАТЬ
        |        ШаблоныКомплексныхБизнесПроцессов.Ссылка
        |    ИЗ
        |        Справочник.ШаблоныКомплексныхБизнесПроцессов КАК ШаблоныКомплексныхБизнесПроцессов
        |    ГДЕ
        |        ШаблоныКомплексныхБизнесПроцессов.Ссылка В(&СписокШаблонов)
        |    
        |    ОБЪЕДИНИТЬ ВСЕ
        |    
        |    ВЫБРАТЬ
        |        ШаблоныОзнакомления.Ссылка
        |    ИЗ
        |        Справочник.ШаблоныОзнакомления КАК ШаблоныОзнакомления
        |    ГДЕ
        |        ШаблоныОзнакомления.Ссылка В(&СписокШаблонов)
        |    
        |    ОБЪЕДИНИТЬ ВСЕ
        |    
        |    ВЫБРАТЬ
        |        ШаблоныПоручения.Ссылка
        |    ИЗ
        |        Справочник.ШаблоныПоручения КАК ШаблоныПоручения
        |    ГДЕ
        |        ШаблоныПоручения.Ссылка В(&СписокШаблонов)
        |    
        |    ОБЪЕДИНИТЬ ВСЕ
        |    
        |    ВЫБРАТЬ
        |        ШаблоныПриглашения.Ссылка
        |    ИЗ
        |        Справочник.ШаблоныПриглашения КАК ШаблоныПриглашения
        |    ГДЕ
        |        ШаблоныПриглашения.Ссылка В(&СписокШаблонов)
        |    
        |    ОБЪЕДИНИТЬ ВСЕ
        |    
        |    ВЫБРАТЬ
        |        ШаблоныРассмотрения.Ссылка
        |    ИЗ
        |        Справочник.ШаблоныРассмотрения КАК ШаблоныРассмотрения
        |    ГДЕ
        |        ШаблоныРассмотрения.Ссылка В(&СписокШаблонов)
        |    
        |    ОБЪЕДИНИТЬ ВСЕ
        |    
        |    ВЫБРАТЬ
        |        ШаблоныРегистрации.Ссылка
        |    ИЗ
        |        Справочник.ШаблоныРегистрации КАК ШаблоныРегистрации
        |    ГДЕ
        |        ШаблоныРегистрации.Ссылка В(&СписокШаблонов)
        |    
        |    ОБЪЕДИНИТЬ ВСЕ
        |    
        |    ВЫБРАТЬ
        |        ШаблоныСогласования.Ссылка
        |    ИЗ
        |        Справочник.ШаблоныСогласования КАК ШаблоныСогласования
        |    ГДЕ
        |        ШаблоныСогласования.Ссылка В(&СписокШаблонов)
        |    
        |    ОБЪЕДИНИТЬ ВСЕ
        |    
        |    ВЫБРАТЬ
        |        ШаблоныСоставныхБизнесПроцессов.Ссылка
        |    ИЗ
        |        Справочник.ШаблоныСоставныхБизнесПроцессов КАК ШаблоныСоставныхБизнесПроцессов
        |    ГДЕ
        |        ШаблоныСоставныхБизнесПроцессов.Ссылка В(&СписокШаблонов)
        |    
        |    ОБЪЕДИНИТЬ ВСЕ
        |    
        |    ВЫБРАТЬ
        |        ШаблоныУтверждения.Ссылка
        |    ИЗ
        |        Справочник.ШаблоныУтверждения КАК ШаблоныУтверждения
        |    ГДЕ
        |        ШаблоныУтверждения.Ссылка В(&СписокШаблонов)) КАК Шаблоны
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |ВЫБРАТЬ РАЗЛИЧНЫЕ
        |    ТЗВидыДокументов.ВидДокумента КАК ВидДокумента,
        |    ТЗШаблоны.ШаблонБизнесПроцесса КАК ШаблонБизнесПроцесса
        |ПОМЕСТИТЬ ТЗВидыДокументовШаблоны
        |ИЗ
        |    ТЗВидыДокументов КАК ТЗВидыДокументов,
        |    ТЗШаблоны КАК ТЗШаблоны
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |УНИЧТОЖИТЬ ТЗВидыДокументов
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |УНИЧТОЖИТЬ ТЗШаблоны
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |ВЫБРАТЬ
        |    U200724_ШаблоныБизнесПроцессовДокументов.ВидДокумента КАК ВидДокумента,
        |    U200724_ШаблоныБизнесПроцессовДокументов.ШаблонБизнесПроцесса КАК ШаблонБизнесПроцесса
        |ПОМЕСТИТЬ ТЗВидыДокументовШаблоныДозволенные
        |ИЗ
        |    РегистрСведений.U200724_ШаблоныБизнесПроцессовДокументов КАК U200724_ШаблоныБизнесПроцессовДокументов
        |ГДЕ
        |    U200724_ШаблоныБизнесПроцессовДокументов.ВидДокумента В(&СписокВидовДокументов)
        |    И &ПолныеПрава = ЛОЖЬ
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |ВЫБРАТЬ РАЗЛИЧНЫЕ
        |    ПЗ.ВидДокумента КАК ВидДокумента,
        |    ПЗ.ШаблонБизнесПроцесса КАК ШаблонБизнесПроцесса,
        |    1 КАК Количество
        |ПОМЕСТИТЬ ТЗВидыДокументовШаблоныОтбор
        |ИЗ
        |    (ВЫБРАТЬ
        |        ТЗВидыДокументовШаблоны.ВидДокумента КАК ВидДокумента,
        |        ТЗВидыДокументовШаблоны.ШаблонБизнесПроцесса КАК ШаблонБизнесПроцесса
        |    ИЗ
        |        ТЗВидыДокументовШаблоны КАК ТЗВидыДокументовШаблоны
        |    ГДЕ
        |        НЕ ТЗВидыДокументовШаблоны.ВидДокумента В
        |                    (ВЫБРАТЬ
        |                        ТЗ.ВидДокумента
        |                    ИЗ
        |                        ТЗВидыДокументовШаблоныДозволенные КАК ТЗ)
        |    
        |    ОБЪЕДИНИТЬ ВСЕ
        |    
        |    ВЫБРАТЬ
        |        ТЗВидыДокументовШаблоны.ВидДокумента,
        |        ТЗВидыДокументовШаблоны.ШаблонБизнесПроцесса
        |    ИЗ
        |        ТЗВидыДокументовШаблоны КАК ТЗВидыДокументовШаблоны
        |    ГДЕ
        |        (ТЗВидыДокументовШаблоны.ВидДокумента, ТЗВидыДокументовШаблоны.ШаблонБизнесПроцесса) В
        |                (ВЫБРАТЬ
        |                    ТЗ.ВидДокумента,
        |                    ТЗ.ШаблонБизнесПроцесса
        |                ИЗ
        |                    ТЗВидыДокументовШаблоныДозволенные КАК ТЗ)) КАК ПЗ
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |УНИЧТОЖИТЬ ТЗВидыДокументовШаблоны
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |УНИЧТОЖИТЬ ТЗВидыДокументовШаблоныДозволенные
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |ВЫБРАТЬ
        |    ПЗ.ШаблонБизнесПроцесса КАК ШаблонБизнесПроцесса
        |ПОМЕСТИТЬ ТЗШаблоныОтбор
        |ИЗ
        |    (ВЫБРАТЬ
        |        ТЗВидыДокументовШаблоныОтбор.ШаблонБизнесПроцесса КАК ШаблонБизнесПроцесса,
        |        СУММА(ТЗВидыДокументовШаблоныОтбор.Количество) КАК Количество
        |    ИЗ
        |        ТЗВидыДокументовШаблоныОтбор КАК ТЗВидыДокументовШаблоныОтбор
        |    
        |    СГРУППИРОВАТЬ ПО
        |        ТЗВидыДокументовШаблоныОтбор.ШаблонБизнесПроцесса) КАК ПЗ
        |ГДЕ
        |    ПЗ.Количество = &КоличествоВидовДокументов
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |ВЫБРАТЬ
        |    ТЗВидыДокументовШаблоныОтбор.ВидДокумента КАК ВидДокумента,
        |    ТЗВидыДокументовШаблоныОтбор.ШаблонБизнесПроцесса КАК ШаблонБизнесПроцесса
        |ПОМЕСТИТЬ ТЗВидыДокументовШаблоныРазрешенные1
        |ИЗ
        |    ТЗВидыДокументовШаблоныОтбор КАК ТЗВидыДокументовШаблоныОтбор
        |ГДЕ
        |    ТЗВидыДокументовШаблоныОтбор.ШаблонБизнесПроцесса В
        |            (ВЫБРАТЬ
        |                ТЗ.ШаблонБизнесПроцесса
        |            ИЗ
        |                ТЗШаблоныОтбор КАК ТЗ)
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |УНИЧТОЖИТЬ ТЗВидыДокументовШаблоныОтбор
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |УНИЧТОЖИТЬ ТЗШаблоныОтбор
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |ВЫБРАТЬ РАЗЛИЧНЫЕ
        |    U200724_ДоступностьШаблоновБизнесПроцессовПользователям.ВидДокумента КАК ВидДокумента,
        |    U200724_ДоступностьШаблоновБизнесПроцессовПользователям.ШаблонБизнесПроцесса КАК ШаблонБизнесПроцесса,
        |    ВЫБОР
        |        КОГДА U200724_ДоступностьШаблоновБизнесПроцессовПользователям.Исполнитель ССЫЛКА Справочник.Пользователи
        |            ТОГДА 1
        |        ИНАЧЕ 0
        |    КОНЕЦ КАК Уровень,
        |    U200724_ДоступностьШаблоновБизнесПроцессовПользователям.Доступ КАК Доступ
        |ПОМЕСТИТЬ ТЗВидыДокументовШаблоныДозволенные
        |ИЗ
        |    РегистрСведений.U200724_ДоступностьШаблоновБизнесПроцессовПользователям КАК U200724_ДоступностьШаблоновБизнесПроцессовПользователям
        |ГДЕ
        |    U200724_ДоступностьШаблоновБизнесПроцессовПользователям.Исполнитель В
        |            (ВЫБРАТЬ
        |                ТЗ.Исполнитель
        |            ИЗ
        |                ТЗИсполнители КАК ТЗ)
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |ВЫБРАТЬ
        |    ПЗ.ВидДокумента КАК ВидДокумента,
        |    ПЗ.ШаблонБизнесПроцесса КАК ШаблонБизнесПроцесса,
        |    ПЗ.Уровень КАК Уровень,
        |    ПЗ.Доступ КАК Доступ
        |ПОМЕСТИТЬ ТЗВидыДокументовШаблоныДозволенныеОбъединенные
        |ИЗ
        |    (ВЫБРАТЬ
        |        ТЗВидыДокументовШаблоныДозволенные.ВидДокумента КАК ВидДокумента,
        |        ТЗВидыДокументовШаблоныДозволенные.ШаблонБизнесПроцесса КАК ШаблонБизнесПроцесса,
        |        ТЗВидыДокументовШаблоныДозволенные.Уровень КАК Уровень,
        |        МИНИМУМ(ТЗВидыДокументовШаблоныДозволенные.Доступ) КАК Доступ
        |    ИЗ
        |        ТЗВидыДокументовШаблоныДозволенные КАК ТЗВидыДокументовШаблоныДозволенные
        |    ГДЕ
        |        ТЗВидыДокументовШаблоныДозволенные.Уровень = 0
        |    
        |    СГРУППИРОВАТЬ ПО
        |        ТЗВидыДокументовШаблоныДозволенные.ВидДокумента,
        |        ТЗВидыДокументовШаблоныДозволенные.ШаблонБизнесПроцесса,
        |        ТЗВидыДокументовШаблоныДозволенные.Уровень
        |    
        |    ОБЪЕДИНИТЬ
        |    
        |    ВЫБРАТЬ
        |        ТЗВидыДокументовШаблоныДозволенные.ВидДокумента,
        |        ТЗВидыДокументовШаблоныДозволенные.ШаблонБизнесПроцесса,
        |        ТЗВидыДокументовШаблоныДозволенные.Уровень,
        |        МАКСИМУМ(ТЗВидыДокументовШаблоныДозволенные.Доступ)
        |    ИЗ
        |        ТЗВидыДокументовШаблоныДозволенные КАК ТЗВидыДокументовШаблоныДозволенные
        |    ГДЕ
        |        ТЗВидыДокументовШаблоныДозволенные.Уровень = 1
        |    
        |    СГРУППИРОВАТЬ ПО
        |        ТЗВидыДокументовШаблоныДозволенные.ВидДокумента,
        |        ТЗВидыДокументовШаблоныДозволенные.ШаблонБизнесПроцесса,
        |        ТЗВидыДокументовШаблоныДозволенные.Уровень) КАК ПЗ
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |УНИЧТОЖИТЬ ТЗВидыДокументовШаблоныДозволенные
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |ВЫБРАТЬ
        |    ТЗВидыДокументовШаблоныДозволенныеОбъединенные.ВидДокумента КАК ВидДокумента,
        |    ТЗВидыДокументовШаблоныДозволенныеОбъединенные.ШаблонБизнесПроцесса КАК ШаблонБизнесПроцесса,
        |    МАКСИМУМ(ТЗВидыДокументовШаблоныДозволенныеОбъединенные.Уровень) КАК Уровень
        |ПОМЕСТИТЬ ТЗУровеньМаксимальный
        |ИЗ
        |    ТЗВидыДокументовШаблоныДозволенныеОбъединенные КАК ТЗВидыДокументовШаблоныДозволенныеОбъединенные
        |
        |СГРУППИРОВАТЬ ПО
        |    ТЗВидыДокументовШаблоныДозволенныеОбъединенные.ВидДокумента,
        |    ТЗВидыДокументовШаблоныДозволенныеОбъединенные.ШаблонБизнесПроцесса
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |ВЫБРАТЬ
        |    ТЗВидыДокументовШаблоныДозволенныеОбъединенные.ВидДокумента КАК ВидДокумента,
        |    ТЗВидыДокументовШаблоныДозволенныеОбъединенные.ШаблонБизнесПроцесса КАК ШаблонБизнесПроцесса,
        |    ТЗВидыДокументовШаблоныДозволенныеОбъединенные.Доступ КАК Доступ
        |ПОМЕСТИТЬ ТЗВидыДокументовШаблоныДозволенные
        |ИЗ
        |    ТЗВидыДокументовШаблоныДозволенныеОбъединенные КАК ТЗВидыДокументовШаблоныДозволенныеОбъединенные
        |ГДЕ
        |    (ТЗВидыДокументовШаблоныДозволенныеОбъединенные.ВидДокумента, ТЗВидыДокументовШаблоныДозволенныеОбъединенные.ШаблонБизнесПроцесса, ТЗВидыДокументовШаблоныДозволенныеОбъединенные.Уровень) В
        |            (ВЫБРАТЬ
        |                ТЗ.ВидДокумента,
        |                ТЗ.ШаблонБизнесПроцесса,
        |                ТЗ.Уровень
        |            ИЗ
        |                ТЗУровеньМаксимальный КАК ТЗ)
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |УНИЧТОЖИТЬ ТЗВидыДокументовШаблоныДозволенныеОбъединенные
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |УНИЧТОЖИТЬ ТЗУровеньМаксимальный
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |ВЫБРАТЬ
        |    ПЗ.ВидДокумента КАК ВидДокумента,
        |    ПЗ.ШаблонБизнесПроцесса КАК ШаблонБизнесПроцесса,
        |    МИНИМУМ(ПЗ.Доступ) КАК Доступ
        |ПОМЕСТИТЬ ТЗВидыДокументовШаблоныДоступ
        |ИЗ
        |    (ВЫБРАТЬ
        |        ТЗВидыДокументовШаблоныРазрешенные1.ВидДокумента КАК ВидДокумента,
        |        ТЗВидыДокументовШаблоныРазрешенные1.ШаблонБизнесПроцесса КАК ШаблонБизнесПроцесса,
        |        ИСТИНА КАК Доступ
        |    ИЗ
        |        ТЗВидыДокументовШаблоныРазрешенные1 КАК ТЗВидыДокументовШаблоныРазрешенные1
        |    ГДЕ
        |        НЕ (ТЗВидыДокументовШаблоныРазрешенные1.ВидДокумента, ТЗВидыДокументовШаблоныРазрешенные1.ШаблонБизнесПроцесса) В
        |                    (ВЫБРАТЬ
        |                        ТЗ.ВидДокумента,
        |                        ТЗ.ШаблонБизнесПроцесса
        |                    ИЗ
        |                        ТЗВидыДокументовШаблоныДозволенные КАК ТЗ)
        |    
        |    ОБЪЕДИНИТЬ ВСЕ
        |    
        |    ВЫБРАТЬ
        |        ТЗВидыДокументовШаблоныРазрешенные1.ВидДокумента,
        |        ТЗВидыДокументовШаблоныРазрешенные1.ШаблонБизнесПроцесса,
        |        ТЗВидыДокументовШаблоныДозволенные.Доступ
        |    ИЗ
        |        ТЗВидыДокументовШаблоныРазрешенные1 КАК ТЗВидыДокументовШаблоныРазрешенные1
        |            ВНУТРЕННЕЕ СОЕДИНЕНИЕ ТЗВидыДокументовШаблоныДозволенные КАК ТЗВидыДокументовШаблоныДозволенные
        |            ПО ТЗВидыДокументовШаблоныРазрешенные1.ВидДокумента = ТЗВидыДокументовШаблоныДозволенные.ВидДокумента
        |                И ТЗВидыДокументовШаблоныРазрешенные1.ШаблонБизнесПроцесса = ТЗВидыДокументовШаблоныДозволенные.ШаблонБизнесПроцесса) КАК ПЗ
        |
        |СГРУППИРОВАТЬ ПО
        |    ПЗ.ВидДокумента,
        |    ПЗ.ШаблонБизнесПроцесса
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |УНИЧТОЖИТЬ ТЗВидыДокументовШаблоныРазрешенные1
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |УНИЧТОЖИТЬ ТЗВидыДокументовШаблоныДозволенные
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |ВЫБРАТЬ
        |    ТЗВидыДокументовШаблоныДоступ.ВидДокумента КАК ВидДокумента,
        |    ТЗВидыДокументовШаблоныДоступ.ШаблонБизнесПроцесса КАК ШаблонБизнесПроцесса,
        |    1 КАК Количество
        |ПОМЕСТИТЬ ТЗВидыДокументовШаблоныОтбор
        |ИЗ
        |    ТЗВидыДокументовШаблоныДоступ КАК ТЗВидыДокументовШаблоныДоступ
        |ГДЕ
        |    ТЗВидыДокументовШаблоныДоступ.Доступ = ИСТИНА
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |УНИЧТОЖИТЬ ТЗВидыДокументовШаблоныДоступ
        |;
        |
        |////////////////////////////////////////////////////////////////////////////////
        |ВЫБРАТЬ
        |    ПЗ.ШаблонБизнесПроцесса КАК ШаблонБизнесПроцесса
        |ИЗ
        |    (ВЫБРАТЬ
        |        ТЗВидыДокументовШаблоныОтбор.ШаблонБизнесПроцесса КАК ШаблонБизнесПроцесса,
        |        СУММА(ТЗВидыДокументовШаблоныОтбор.Количество) КАК Количество
        |    ИЗ
        |        ТЗВидыДокументовШаблоныОтбор КАК ТЗВидыДокументовШаблоныОтбор
        |    
        |    СГРУППИРОВАТЬ ПО
        |        ТЗВидыДокументовШаблоныОтбор.ШаблонБизнесПроцесса) КАК ПЗ
        |ГДЕ
        |    ПЗ.Количество = &КоличествоВидовДокументов";
        
        Выборка = Запрос.Выполнить().Выбрать();
        
        Пока Выборка.Следующий() Цикл
            СписокРазрешенныхШаблонов.Добавить(Выборка.ШаблонБизнесПроцесса);
        КонецЦикла;
        
        СписокУдалить = Новый СписокЗначений;
        
        СписокУдалить.Очистить();
        Для каждого ТекущийВариант Из Помощник.ВариантыСозданияПроцессовПоУмолчанию Цикл
            Если СписокРазрешенныхШаблонов.НайтиПоЗначению(ТекущийВариант.Ключ) = Неопределено Тогда
                СписокУдалить.Добавить(ТекущийВариант.Ключ);
            КонецЕсли;
        КонецЦикла;
        Для каждого ЭлементСпискаУдалить Из СписокУдалить Цикл
            Помощник.ВариантыСозданияПроцессовПоУмолчанию.Удалить(ЭлементСпискаУдалить.Значение);
        КонецЦикла;
        
        СписокУдалить.Очистить();
        Для каждого ТекущийВариант Из Помощник.ОбщиеВариантыСозданияПроцессов Цикл
            Если СписокРазрешенныхШаблонов.НайтиПоЗначению(ТекущийВариант.Ключ) = Неопределено Тогда
                СписокУдалить.Добавить(ТекущийВариант.Ключ);
            КонецЕсли;
        КонецЦикла;
        Для каждого ЭлементСпискаУдалить Из СписокУдалить Цикл
            Помощник.ОбщиеВариантыСозданияПроцессов.Удалить(ЭлементСпискаУдалить.Значение);
        КонецЦикла;
        
        СписокУдалить.Очистить();
        Для каждого ТекущийВариант Из Помощник.РекомендуемыеВариантыСозданияПроцессов Цикл
            Если СписокРазрешенныхШаблонов.НайтиПоЗначению(ТекущийВариант.Ключ) = Неопределено Тогда
                СписокУдалить.Добавить(ТекущийВариант.Ключ);
            КонецЕсли;
        КонецЦикла;
        Для каждого ЭлементСпискаУдалить Из СписокУдалить Цикл
            Помощник.РекомендуемыеВариантыСозданияПроцессов.Удалить(ЭлементСпискаУдалить.Значение);
        КонецЦикла;
        
        СписокУдалить.Очистить();
        Для каждого ТекущийВариант Из Помощник.ДругиеВариантыСозданияПроцессов Цикл
            Если СписокРазрешенныхШаблонов.НайтиПоЗначению(ТекущийВариант.Ключ) = Неопределено Тогда
                СписокУдалить.Добавить(ТекущийВариант.Ключ);
            КонецЕсли;
        КонецЦикла;
        Для каждого ЭлементСпискаУдалить Из СписокУдалить Цикл
            Помощник.ДругиеВариантыСозданияПроцессов.Удалить(ЭлементСпискаУдалить.Значение);
        КонецЦикла;
        
    Иначе
    
        СписокУдалить = Новый СписокЗначений;
        
        СписокУдалить.Очистить();
        Для каждого ТекущийВариант Из Помощник.ОбщиеВариантыСозданияПроцессов Цикл
            СписокУдалить.Добавить(ТекущийВариант.Ключ);
        КонецЦикла;
        Для каждого ЭлементСпискаУдалить Из СписокУдалить Цикл
            Помощник.ОбщиеВариантыСозданияПроцессов.Удалить(ЭлементСпискаУдалить.Значение);
        КонецЦикла;
        
        СписокУдалить.Очистить();
        Для каждого ТекущийВариант Из Помощник.РекомендуемыеВариантыСозданияПроцессов Цикл
            СписокУдалить.Добавить(ТекущийВариант.Ключ);
        КонецЦикла;
        Для каждого ЭлементСпискаУдалить Из СписокУдалить Цикл
            Помощник.РекомендуемыеВариантыСозданияПроцессов.Удалить(ЭлементСпискаУдалить.Значение);
        КонецЦикла;
        
        СписокУдалить.Очистить();
        Для каждого ТекущийВариант Из Помощник.ДругиеВариантыСозданияПроцессов Цикл
            СписокУдалить.Добавить(ТекущийВариант.Ключ);
        КонецЦикла;
        Для каждого ЭлементСпискаУдалить Из СписокУдалить Цикл
            Помощник.ДругиеВариантыСозданияПроцессов.Удалить(ЭлементСпискаУдалить.Значение);
        КонецЦикла;
    
    КонецЕсли;
    
    УстановитьПривилегированныйРежим(Ложь);

КонецПроцедуры

(4) Да это minimum minimorum. Расширять права в ДО лучше всего по рабочим группам и ролям.

(6) это походу для ДО2.1

в ДО3 вроде бы только комплексный процесс один

у нас в ДО2.1 все процессы запрещены (программно), кроме комплексного по шаблонам (всяким разным для каждого вида документа штук 20)

(8) Нет, в ДО 3.0 доступны по умолчанию из коробки все типы простых процессов. исполнение, Ознакомление и т.п.

(9) вероятно. я ДО3.0 еще ни разу не видел :)



из документации к последнему релизу ДО2.1 по миграции на ДО3.0

В ДО 2.1 процесс Поручение тоже не доступен, это какое-то реликт от более ранних версий.

7.1. Правила коммуникаций
Правила коммуникаций ограничивают выбор адресатов документов и исполнителей действий в зависимости от ранга и подчиненности инициатора коммуникации и исполнителя. Например, можно запретить рядовым сотрудникам и руководителям среднего звена напрямую направлять документы руководителю компании.

https://its.1c.ru/db/doc30#content:66:hdoc

(12) не нашел в них как запретить именно базовый процесс "Исполнение", который можно стартовать из "Мои процессы". Документы, задачи да, а это нет.