структура Подключение
	знч Сервер: Строка
	знч ПользовательКластера: Строка
	знч ПарольКластера: Строка
	знч ИмяБазы: Строка
	знч ПользовательБазы: Строка
	знч ПарольПользователяБазы: Строка
	знч ОтправитьПисьмо: Булево
;

метод Скрипт()

	знч ИмяБазы: Строка = "Рабочая" // здесь указываем строку из ::::подключения:::: (ниже), для проверки поменять на Дев10 или добавить свою

	знч ПодключениеКРабочей: Подключение = новый Подключение(
		"sqlserv1","<здесь пользователь кластера>","<здесь пароль кластера>", "UT2013", "<здесь пользователь базы>", 
		"<здесь пароль базы>", Истина)

	знч ПодключениеКДев10: Подключение = новый Подключение	(
		"dbs","","","dev_Zakirov_10","Закиров Дамир Тагирович", 
		"<здесь пароль базы>", Ложь)

	пер Подключения: Соответствие<Строка, Подключение>
	
	Подключения.Вставить("Рабочая", ПодключениеКРабочей) // ::::подключения::::
	Подключения.Вставить("Дев10", ПодключениеКДев10)

	ЗаблокироватьБазу(Подключения[ИмяБазы])

	если Подключения[ИмяБазы].ОтправитьПисьмо
		ОтправитьПисьмо(Подключения[ИмяБазы])
		;
;

метод ЗаблокироватьБазу(Параметры: Подключение)

	знч АдмС = новый АдминистрированиеСервераV8(Параметры.Сервер, 1545)
	знч Кластеры = АдмС.ПолучитьКластеры()
	для Кластер из Кластеры
		Кластер.ВыполнитьАутентификацию(Параметры.ПользовательКластера, Параметры.ПарольКластера)
		знч Базы = Кластер.ПолучитьИнфобазы()
		для База из Базы
			если База.Имя == Параметры.ИмяБазы
				пер Инфобаза = База.ВыполнитьАутентификацию(Параметры.ПользовательБазы, Параметры.ПарольПользователяБазы)
				ВключитьБлокировку(Инфобаза)
			;
		;
		прервать
	;
;

метод ВключитьБлокировку(Инфобаза: ИнфобазаV8)

	знч ЧасовойПояс = новый ЧасовойПояс("UTC+3")

	Инфобаза.ВремяНачалаБлокировки = ДатаВремя.Сейчас().НачалоДня().ДобавитьМинуты(570).ВМомент(ЧасовойПояс)
	Инфобаза.ВремяОкончанияБлокировки = ДатаВремя.Сейчас().НачалоДня().ДобавитьМинуты(630).ВМомент(ЧасовойПояс)

	Инфобаза.ВключенаБлокировкаНачалаСеансов = Истина
	Инфобаза.Записать()
;


метод ОтправитьПисьмо(Параметры: Подключение) 

	знч Отправитель = "[email protected]"
	знч Получатели = "[email protected]"
	знч Тема = "Обновление 1С УТ с 9.30 до 9.35"

	знч ФайлШаблона = новый Файл(".\\inside\\Обновление в 9.30.html")
	знч ЧтениеТекста = ФайлШаблона.ОткрытьПотокЧтения()
	пер ТекстПисьма = ЧтениеТекста.ПрочитатьКакСтроку(Кодировка.Koi8r)

	пер Лого = новый Файл(".\\inside\\bwell.png")
	исп ПотокЛого = Лого.ОткрытьПотокЧтения()

	пер Письмо = новый Письмо(Отправитель, Получатели, Тема)
	Письмо.УстановитьЗаголовок("Content-Type", "text/html")
	пер Вложение = Письмо.ПриложитьДанные(ПотокЛого, "bwell.png", "image/png", (новый Ууид()).ВСтроку(), Истина)
	ТекстПисьма = ТекстПисьма.Заменить("{ИдентификаторВложения}", Вложение.Ид)
	Письмо.УстановитьТекстКакСтроку(ТекстПисьма, ВидТекстаПисьма.Html)

	пер Аутентификация = новый АутентификацияПочтыПоПаролю("[email protected]", "<здесь пароль на почтовый ящик>")
	пер ПараметрыПодключения = новый ПараметрыПодключенияSmtp("mail.am.local", 465, Аутентификация)

	КлиентSmtp.Отправить(ПараметрыПодключения, Письмо)
	Консоль.Записать(Параметры)

;