Здравствуйте
надо в запросе 1с получить из подчиненного справочника родителя и из родителя получить доп.реквизит.
доп.реквизит в родителя переходит, тут проблем нет, а вот подчиненный справочник родителя не видит.
вопросов 2:
1) можно ли в принципе это сделать?
2) можно ли это сделать при помощи только скд без пост-обработки?

пример запроса ниже

ВЫБРАТЬ
    НоменклатураДополнительныеРеквизиты.Ссылка КАК Ссылка,
    НоменклатураДополнительныеРеквизиты.Свойство.Имя КАК СвойствоИмя,
    НоменклатураДополнительныеРеквизиты.Значение КАК Значение
ПОМЕСТИТЬ ВТ_Свойства
ИЗ
    Справочник.Номенклатура.ДополнительныеРеквизиты КАК НоменклатураДополнительныеРеквизиты
ГДЕ
    НоменклатураДополнительныеРеквизиты.Свойство.Имя = "ШтукВКоробке"
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    Номенклатура.Ссылка КАК Ссылка,
    Номенклатура.НаименованиеПолное КАК НаименованиеПолное,
    ВТ_Свойства.Ссылка КАК Ссылка1,
    ВТ_Свойства.Значение КАК Значение
ПОМЕСТИТЬ ВТ_Номенклатура
ИЗ
    ВТ_Свойства КАК ВТ_Свойства
        ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Номенклатура КАК Номенклатура
        ПО ВТ_Свойства.Ссылка = Номенклатура.Ссылка
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ХарактеристикиНоменклатуры.Ссылка КАК Ссылка,
    ХарактеристикиНоменклатуры.Наименование КАК Наименование,
    ХарактеристикиНоменклатуры.Владелец КАК Владелец,
    ХарактеристикиНоменклатуры.НомерГТЛ КАК НомерГТЛ,
    ХарактеристикиНоменклатуры.Владелец.Наименование + " " + ХарактеристикиНоменклатуры.Наименование КАК Номенклатура,
    ВТ_Номенклатура.Ссылка КАК Ссылка1,
    ВТ_Номенклатура.Значение КАК Значение
ИЗ
    Справочник.ХарактеристикиНоменклатуры КАК ХарактеристикиНоменклатуры
        ЛЕВОЕ СОЕДИНЕНИЕ ВТ_Номенклатура КАК ВТ_Номенклатура
        ПО ((ВЫРАЗИТЬ(ХарактеристикиНоменклатуры.Владелец КАК Справочник.Номенклатура)) = (ВЫРАЗИТЬ(ВТ_Номенклатура.Ссылка КАК Справочник.Номенклатура)))

Смешались в кучу родители, владельцы, подчиненные

(1) яволь

(2) Ну так разберись в этой куче в твоей голове что ли

(0) У тебя Характеристика номенклатуры скорее всего привязана не к номенклатуре, а к виду номенклатуры, вот и проблема.

А вообще запрос выглядит так:

ВЫБРАТЬ
    ХарактеристикиНоменклатуры.Ссылка КАК Ссылка,
    ХарактеристикиНоменклатуры.Наименование КАК Наименование,
    ХарактеристикиНоменклатуры.Владелец КАК Владелец,
    ХарактеристикиНоменклатуры.Владелец.Наименование + " " + ХарактеристикиНоменклатуры.Наименование КАК Номенклатура,
    НоменклатураДополнительныеРеквизиты.Свойство Как Свойство,
    ЕСТЬNULL(НоменклатураДополнительныеРеквизиты.Значение, 0) КАК Значение
ИЗ
    Справочник.ХарактеристикиНоменклатуры КАК ХарактеристикиНоменклатуры
        ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Номенклатура.ДополнительныеРеквизиты КАК НоменклатураДополнительныеРеквизиты
        ПО (ХарактеристикиНоменклатуры.ВидНоменклатуры = НоменклатураДополнительныеРеквизиты.Ссылка.ВидНоменклатуры
                И НоменклатураДополнительныеРеквизиты.Свойство = &Свойство)

И выводит это

и то и то есть.
и конкретные позиции, что я имел в виду, именно номенклатура, не вид.

вот так вот заработало короче.
всем спасибо за помощь

ВЫБРАТЬ
    ХарактеристикиНоменклатуры.Ссылка КАК Ссылка,
    ХарактеристикиНоменклатуры.Наименование КАК Наименование,
    ХарактеристикиНоменклатуры.Владелец КАК Владелец,
    ХарактеристикиНоменклатуры.Владелец.Наименование + " " + ХарактеристикиНоменклатуры.Наименование КАК Номенклатура,
    НоменклатураДополнительныеРеквизиты.Свойство КАК Свойство,
    ЕСТЬNULL(НоменклатураДополнительныеРеквизиты.Значение, 0) КАК Значение
ИЗ
    Справочник.ХарактеристикиНоменклатуры КАК ХарактеристикиНоменклатуры
        ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Номенклатура.ДополнительныеРеквизиты КАК НоменклатураДополнительныеРеквизиты
        ПО (ХарактеристикиНоменклатуры.Владелец = НоменклатураДополнительныеРеквизиты.Ссылка)
            И (НоменклатураДополнительныеРеквизиты.Свойство.Имя = "ШтукВКоробке")

Количество "ШтукВКоробке" надо задавать в виде коэф-та пересчёта для единицы "Коробка" при базовой единице "Штука".