//Модуль объекта Номенклатуры
Процедура ПередЗаписью(Отказ)
	Если не ЭтоГруппа Тогда
		Если Ссылка.Пустая() Тогда
			ДополнительныеСвойства.Вставить("ВнутреннийШтрихКодОтсутствует", Истина);
		иначе
			ДополнительныеСвойства.Вставить("ВнутреннийШтрихКодОтсутствует", НЕ Справочники.Номенклатура.ЕстьВнутреннийШтрихКод(Ссылка));
		КонецЕсли;
	КонецЕсли;
КонецПроцедуры

Процедура ПриЗаписи(Отказ)
	Если не Отказ и ПолучитьЗначениеПараметраСтруктуры(ДополнительныеСвойства, "ВнутреннийШтрихКодОтсутствует", Ложь) Тогда
		Справочники.Номенклатура.СоздатьВнутреннийШтрихКод(Ссылка);
	КонецЕсли;
КонецПроцедуры

//Модуль менеджера номенклатуры
Функция СоздатьВнутреннийШтрихКод(Ссылка) Экспорт
	УстановитьПривилегированныйРежим(Истина);
	МенеджерЗаписи = РегистрыСведений.Штрихкоды.СоздатьМенеджерЗаписи();
	МенеджерЗаписи.Объект = Ссылка;
	МенеджерЗаписи.Штрихкод = СформироватьШтрихкодEAN13Внутренний(Ссылка);
	МенеджерЗаписи.Записать();
	УстановитьПривилегированныйРежим(Ложь);
КонецФункции

Функция ЕстьВнутреннийШтрихКод(Ссылка) Экспорт
	Запрос = Новый Запрос;
	Запрос.УстановитьПараметр("Ссылка", Ссылка);
	Запрос.Текст = 
		"ВЫБРАТЬ
		|	Штрихкоды.Штрихкод КАК Штрихкод
		|ИЗ
		|	РегистрСведений.Штрихкоды КАК Штрихкоды
		|ГДЕ
		|	Штрихкоды.Объект = &Ссылка
		|	И Штрихкоды.ХарактеристикаНоменклатуры = ЗНАЧЕНИЕ(Справочник.ХарактеристикиНоменклатуры.ПустаяСсылка)
		|	И (ВЫРАЗИТЬ(Штрихкоды.Штрихкод КАК СТРОКА(2))) = ""20""
		|	И ДЛИНАСТРОКИ(Штрихкоды.Штрихкод) = 13";
	Возврат НЕ Запрос.Выполнить().Пустой();
КонецФункции

Функция СформироватьШтрихкодEAN13Внутренний(Товар) Экспорт
	
	ДлинаКода = 10;

	НовыйКод = EAN13("20" + СформироватьПроизвольныйКод(10));
	Пока НЕ ПроверкаНовогоШтрихкода(НовыйКод) Цикл
		НовыйКод = EAN13("20" + СформироватьПроизвольныйКод(10));
	КонецЦикла;
	
	Возврат НовыйКод; 
	
КонецФункции // СформироватьШтрихкод()

Функция EAN13(Код)
	ШтрКод = Формат(Число(Код),"ЧН=; ЧВН=; ЧГ=0; ЧЦ="+?(СтрДлина(Код)<8,"7","12"));
	Четн = 0; Нечетн = 0;
	Если СтрДлина(Код)=7 Тогда Итераций = 4; 
	Иначе Итераций = 6; 
	КонецЕсли;
	Для Индекс=1 По Итераций Цикл
		Четн=Четн+Сред(ШтрКод,2*Индекс,1);
		Нечетн=Нечетн+Сред(ШтрКод,2*Индекс-1,1);
	КонецЦикла;
	Если СтрДлина(Код)=7 Тогда Нечетн=Нечетн*3; 
	Иначе Четн=Четн*3;
	КонецЕсли;
	КонтЦифра=10-(Четн+Нечетн)%10;
	Если КонтЦифра=10 Тогда КонтЦифра=0; КонецЕсли;
	Рез=ШтрКод+Строка(КонтЦифра);
	Возврат Рез;
КонецФункции // EAN13()

Функция СформироватьПроизвольныйКод(КоличествоЗнаков = 22)

	Возврат Формат(СлучайноеЧисло(КоличествоЗнаков),"ЧЦ=10; ЧН=; ЧВН=; ЧГ=0");
	
КонецФункции // СформироватьПроизвольныйКод()

Функция ПроверкаНовогоШтрихкода(Штрихкод)

	Запрос = Новый Запрос;
	Запрос.УстановитьПараметр("Штрихкод",Штрихкод);
	Запрос.Текст = 
		"ВЫБРАТЬ
		|	Штрихкоды.Штрихкод КАК Штрихкод
		|ИЗ
		|	РегистрСведений.Штрихкоды КАК Штрихкоды
		|ГДЕ
		|	Штрихкоды.Штрихкод = &Штрихкод";
	Возврат Запрос.Выполнить().Пустой();

КонецФункции // ПроверкаНовогоШтрихкода()

Функция СлучайноеЧисло(Порядок)
	
	Мин = 0;   //минимальное допустимое значение произвольного кода
	Макс = 1;  //максимальное допустимое значение произвольного кода
	Для х = 0 По Порядок - 1 Цикл 
		Макс = Макс * 10; 
	КонецЦикла;
	Макс = Макс-1;
	
	// генерируем GUID и оставляем только цифры
	НовыйУИ = СокрЛП(Новый УникальныйИдентификатор);
	НовыйУИ = СтрЗаменить(НовыйУИ,"-","");
	НовыйУИ = СтрЗаменить(НовыйУИ,"a","");
	НовыйУИ = СтрЗаменить(НовыйУИ,"b","");
	НовыйУИ = СтрЗаменить(НовыйУИ,"c","");
	НовыйУИ = СтрЗаменить(НовыйУИ,"d","");
	НовыйУИ = СтрЗаменить(НовыйУИ,"e","");
	НовыйУИ = СтрЗаменить(НовыйУИ,"f","");
	
	// знаменатель должен иметь такое же количество нулей + 1
	Знаменатель = 10;
	Для н = 2 По (СтрДлина(СтрЗаменить(НовыйУИ,Символы.НПП,""))) Цикл
		Знаменатель = Знаменатель * 10;
	КонецЦикла; 
	
	// получим дробное случайное число в диапазоне от 0 до 1
	Случ = Число(НовыйУИ) / Знаменатель;     
	
	// Преобразуем его в случайное число из заданного интервала, округляем до целого.
	ЧислоИзИнтервала = Мин(Макс(Окр(Мин + (Макс-Мин)*Случ),Мин),Макс);
	Возврат ЧислоИзИнтервала;
	
КонецФункции // СлучайноеЧисло()